//+------------------------------------------------------------------+
//| Demo_iTriX.mq5 |
//| Copyright 2000-2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "L'indicateur montre comment il faut recevoir les données"
#property description "des tampons d'indicateur pour l'indicateur technique iTriX."
#property description "Le symbole et le temps trame sur lequel l'indicateur est calculé,"
#property description "sont spécifiés par les paramètres symbol et period."
#property description "Le moyen de la création du handle est spécifié par le paramètre 'type' (le type de la fonction)."
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots 1
//--- la construction iTriX
#property indicator_label1 "iTriX"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//+------------------------------------------------------------------+
//| L'énumération des moyens de la création du handle |
//+------------------------------------------------------------------+
enum Creation
{
Call_iTriX, // utiliser iTriX
Call_IndicatorCreate // utiliser IndicatorCreate
};
//--- les paramètres d'entrée
input Creation type=Call_iTriX; // le type de la fonction
input int ma_period=14; // la période
input ENUM_APPLIED_PRICE applied_price=PRICE_CLOSE; // le type du prix
input string symbol=" "; // le symbole
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // le temps trame
//--- le tampon d'indicateur
double iTriXBuffer[];
//--- la variable pour stocker le handle de l'indicateur iTriX
int handle;
//--- la variable pour le stockage
string name=symbol;
//---le nom de l'indicateur sur le graphique
string short_name;
//--- stockerons le nombre de valeurs dans l'indicateur Triple Exponential Moving Averages Oscillator
int bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- le rattachement du tableau au tampon d'indicateur
SetIndexBuffer(0,iTriXBuffer,INDICATOR_DATA);
//--- définissons avec le symbole sur lequel l'indicateur est construit
name=symbol;
//--- supprimons les espaces de la gauche et de la droite
StringTrimRight(name);
StringTrimLeft(name);
//--- si la longueur de la chaîne name est nulle après cela
if(StringLen(name)==0)
{
//--- prenons le symbole du graphique, où on a lancé l'indicateur
name=_Symbol;
}
//--- créons le handle de l'indicateur
if(type==Call_iTriX)
handle=iTriX(name,period,ma_period,applied_price);
else
{
//--- remplirons la structure par les valeurs des paramètres de l'indicateur
MqlParam pars[2];
//--- la période
pars[0].type=TYPE_INT;
pars[0].integer_value=ma_period;
//--- le type du prix
pars[1].type=TYPE_INT;
pars[1].integer_value=applied_price;
handle=IndicatorCreate(name,period,IND_TRIX,2,pars);
}
//--- si on n'a pas réussi à créer le handle
if(handle==INVALID_HANDLE)
{
//--- informons sur l'échec et déduisons le numéro de l'erreur
PrintFormat("On n'a pas réussi à créer le handle de l'indicateur iTriX pour la paire %s/%s, le code de l'erreur %d",
name,
EnumToString(period),
GetLastError());
//--- le travail de l'indicateur est terminé avant terme
return(INIT_FAILED);
}
//--- montrons sur quelle paire le symbole/temps trame l'indicateur Triple Exponential Moving Averages Oscillator a été calculé
short_name=StringFormat("iTriX(%s/%s, %d, %s)",name,EnumToString(period),
ma_period,EnumToString(applied_price));
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- l'exécution normale de l'initialisation de l'indicateur
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- le nombre de valeurs copiées de l'indicateur iTriX
int values_to_copy;
//--- apprenons le nombre de valeurs calculées dans l'indicateur
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() a rendu %d, le code de l'erreur %d",calculated,GetLastError());
return(0);
}
//--- si c'est un premier lancement des calculs de notre indicateur ou a changé le nombre de valeurs dans l'indicateur iTriX
//--- ou s'il est nécessaire de calculer l'indicateur pour deux ou plus de barres (cela signifie que quelque chose a changé dans l'histoire)
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- si le tableau iTriXBuffer est plus grand, que les valeurs dans l'indicateur iTriX sur la paire symbol/period, copions pas tout
//--- autrement copions moins que la taille des tampons d'indicateur
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- signifie que notre indicateur est calculé non pour la première fois et dès le moment du dernier appel OnCalculate())
//--- pour le calcul a été ajouté pas plus d'une barre
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- remplissons le tableau par les valeurs de l'indicateur Triple Exponential Moving Averages Oscillator
//--- si FillArrayFromBuffer a rendu false, cela signifie que les données ne sont pas prêts - terminons le travail
if(!FillArrayFromBuffer(iTriXBuffer,handle,values_to_copy)) return(0);
//--- formerons le message
string comm=StringFormat("%s ==> a été mise à jour des valeurs de l'indicateur %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- déduisons le message de service sur le graphique
Comment(comm);
//--- retiendrons le nombre de valeurs dans l'indicateur Triple Exponential Moving Averages Oscillator
bars_calculated=calculated;
//--- rendons la valeur prev_calculated pour un appel suivant
return(rates_total);
}
//+------------------------------------------------------------------+
//| Remplissons le tampon d'indicateur de l'indicateur iTriX |
//+------------------------------------------------------------------+
bool FillArrayFromBuffer(double &trix_buffer[], // le tampon d'indicateur des valeurs Triple Exponential Moving Averages Oscillator
int ind_handle, // le handle de l'indicateur iTriX
int amount // le nombre de valeurs copiées
)
{
//--- oblitérons le code de l'erreur
ResetLastError();
//--- remplissons la partie du tableau iTriXBuffer par les valeurs du tampon d'indicateur sous l'index 0
if(CopyBuffer(ind_handle,0,0,amount,trix_buffer)<0)
{
//--- si le copiage n'a pas réussi, annonçons le code de l'erreur
PrintFormat("On n'a pas réussi à copier les données de l'indicateur iTriX, le code de l'erreur %d",GetLastError());
//--- terminerons avec le résultat nul - cela signifie que l'indicateur sera considéré comme non calculé
return(false);
}
//--- tout a réussi
return(true);
}
//+------------------------------------------------------------------+
//| Indicator deinitialization function |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- effaçons le graphique à la suppression de l'indicateur
Comment("");
}
|