SingleTesterCache - bibliothèque pour MetaTrader 5

Cette bibliothèque vous permet de lire/écrire des fichiers tst - MT5-Tester single pass format.

Quelques variantes d'utilisation

#include <fxsaber\SingleTesterCache\SingleTesterCache.mqh> // Données de la passe unique du testeur.

void OnStart()
{  
  SINGLETESTERCACHE SingleTesterCache; // Création d'un objet de cache pour les testeurs.
  
  SingleTesterCache.Set(); // Mettez-y l'histoire réelle de l'offre.
  
// ..\NMQL5\NFiles/Test.tst.
  Print(SingleTesterCache.Save("Test.tst")); // L'écrire dans un fichier qui peut être importé dans le testeur.
}

Ce script rassemble l'historique des transactions sur compte réel au format tst. Il est importé dans le testeur comme suit.

Il en résulte quelque chose comme ceci.

Les solutions DLL ne peuvent pas être placées dans la base de données, c'est pourquoi vous trouverez ci-dessous le code source d'un autre script, qui n'est pas inclus dans la livraison de la base de données.

#include <fxsaber\SingleTesterCache\SingleTesterCache.mqh> // Données de la passe unique du testeur.

#include <Graphics\Graphic.mqh>
#include <fxsaber\MultiTester\MTTester.mqh> // https://www.mql5.com/fr/code/26132

#define  MIN_WIDTH 10

// Création d'un graphique.
string GraphPlot( const double &Y1[], const double &Y2[],
                  int Width = 0, int Height = 0, const ENUM_CURVE_TYPE Type = CURVE_NONE,
                  const string CurveName1 = NULL, const string CurveName2 = NULL, string ObjName = NULL )
{
  Width = Width ? Width : (int)::ChartGetInteger(0, CHART_WIDTH_IN_PIXELS);
  Height = Height ? Height : (int)::ChartGetInteger(0, CHART_HEIGHT_IN_PIXELS);
  ObjName = (ObjName == NULL) ? __FUNCTION__ : ObjName;

  CGraphic Graphic;

  const bool Res = (::ObjectFind(0, ObjName) >= 0) ? Graphic.Attach(0, ObjName) : Graphic.Create(0, ObjName, 0, 0, 0, Width, Height);

  if (Res)
  {
    const int Size1 = ::ArraySize(Y1);
    const int Size2 = ::ArraySize(Y2);

    Graphic.CurveAdd(Y1, ((Type == CURVE_NONE) && Size1) ? ((Width / Size1 < MIN_WIDTH) ? CURVE_LINES : CURVE_POINTS_AND_LINES) : Type, CurveName1);
    Graphic.CurveAdd(Y2, ((Type == CURVE_NONE) && Size2) ? ((Width / Size2 < MIN_WIDTH) ? CURVE_LINES : CURVE_POINTS_AND_LINES) : Type, CurveName2);

    Graphic.CurvePlotAll();
    Graphic.Update();
  }

  return (Res ? Graphic.ChartObjectName() : NULL);
}

void OnStart()
{  
  uchar Bytes2[];
  
  if (MTTESTER::GetLastTstCache(Bytes2) != -1) // S'il était possible de lire le dernier enregistrement de cache d'une seule exécution
  {
    const SINGLETESTERCACHE SingleTesterCache(Bytes2); // L'introduire dans l'objet correspondant.

    SingleTesterCache.SaveSet(NULL, true, "Created by " + __FILE__); // Sauvegarder le fichier set avec les détails.
    
    double Balance[];
    double Equity[];
  
    // Imprimer le tableau des soldes et des capitaux propres.
    if (SingleTesterCache.GetBalance(Balance) && SingleTesterCache.GetEquity(Equity))
      GraphPlot(Balance, Equity, 1200, 500, CURVE_NONE, "Balance", "Equity");
      
    Print(SingleTesterCache.Header.ToString());  // Sortie de l'en-tête d'une seule passe.
    Print(SingleTesterCache.Summary.ToString()); // Statistica.
    Print(SingleTesterCache.Inputs);             // Paramètres d'entrée.
  }
}

Ce script récupère automatiquement les données de la dernière passe simple et les restitue, y compris un graphique d'équilibre/équité.

Remerciements.

Merci aux développeurs d'avoir créé les caches Tester et de m'avoir aidé à décompresser leurs formats.