Preguntas de los principiantes MQL4 MT4 MetaTrader 4

Valeriy Yastremskiy 2020.09.20 13:12 #2131

Aleksandr Martynov:

UPS, creo que lo he encontrado:

Según la documentación:

Si se llama a un indicador personalizado utilizando la funcióniCustom(), este indicador se ejecuta en el hilo del programa que lo llama. Las funciones de la biblioteca (importadas) también funcionan en el hilo del programa que llama.

En general, para MQL4 no importa donde se coloquen los cálculos, porque los recursos serán asignados para el único hilo del programa y los indicadores utilizados por él.

En este caso, es aconsejable, si es posible, transferir el código del indicador al Asesor Experto y optimizar el número de valores calculados por la profundidad de la matriz y el número de "buffers", aunque no se trata de los algoritmos recursivos - todavía es más fácil de leer en el indicador, porque el programa ha indexado automáticamente buffers para los datos de precios sólo ...

La cuestión está en la comodidad de leer y editar el código, por lo que mt4 es monohilo en una ventana. Para mí es más fácil llevar la parte de cálculo de un indicador a un Asesor Experto. Pero no siempre es bueno. El código resulta largo, mientras que inludes o iQuest es lo mismo. Si quieres acelerar, entonces mt5. mt4 no es lo suficientemente rápido, a juzgar por los participantes del foro.

PostMessageA(Parent(), WM_COMMAND, 33042, 0); Cualquier pregunta de los Algoritmos, métodos de solución,

Aleksandr Martynov 2020.09.20 18:27 #2132

Valeriy Yastremskiy:

La cuestión es lo fácil que es leer y editar el código, y tal como está, mt4 es de un solo hilo en una ventana. Me parece más fácil meter la parte de cálculo de un indicador en un EA. Pero no siempre es bueno. El código resulta largo, mientras que inludes o iQuest es lo mismo. Si quieres acelerar, pasa a mt5. mt4 es más lento, a juzgar por los comentarios del foro.

Si quieres acelerar, entonces es mt5, pero mt4 sale perdiendo, a juzgar por los comentarios del foro. Así que fórmulas simples como el promedio, el zigzag, y no cualquier tipo. El 5 es bueno, por supuesto, pero no todo el mundo lo proporciona todavía y hay que aprenderlo

Mt4 Fin de soporte. Predicción del futuro con EURUSD - Tendencias, previsiones

Valeriy Yastremskiy 2020.09.20 21:51 #2133

Aleksandr Martynov:

la gestión de los búferes de cálculo en el EA será más cara que el indicador... Así que fórmulas sencillas como el promedio, el zigzag y no todas. El 5 es bueno, por supuesto, pero no todo el mundo tiene acceso a él.

Pero para hacerlo hay que quitar el código de la lógica del indicador, lo que no siempre es fácil.

Alexander Kovalev 2020.09.21 09:42 #2134

¿Qué seguridad tiene dar el EA y los registros del terminal a un desarrollador a petición suya? ¿Puede hacer algo a mi cuenta o a mi ordenador?

Vitaly Muzichenko 2020.09.21 10:11 #2135

Alexander Kovalev:

¿Qué seguridad tiene entregar los registros del EA y del terminal al desarrollador a petición suya? ¿Puede hacer algo a mi cuenta o a mi ordenador?

Sí, y también sacar todas las joyas de oro de la casa del ataúd

Alexander Korovkin 2020.09.21 10:15 #2136

Amigos míos, por favor, aconséjenme en qué me estoy equivocando (por favor, no me maten, llevo 3 días trabajando en MQL4).

Estoy tratando de abrir una orden de VENTA del mercado a un precio con sangría de puntos Delta (60) del valor colocado anteriormente (que tomo al abrir una orden anterior).

Sin embargo, el script abre una nueva orden al mismo tiempo que la orden anterior, al precio actual, sin esperar a la condición apropiada (una caída de precio de 60 puntos). Sé que he llegado a algún sitio, pero todavía no entiendo dónde está.

Se lo agradecería mucho.

Cualquier pregunta de novato, Errores, fallos, preguntas Cualquier pregunta de los

Dmitrii Solovei 2020.09.21 17:30 #2137

¡¡¡Ayuda!!!

No puedo averiguar dónde está mi problema. El EA requiere volúmenes EMA. He utilizado iMAonArray.

Pero el cálculo no es similar al real.

Aquí está el código:

***

Archivos adjuntos:

FastStoneEditor1.jpg 199 kb

Наджибулло Хабибов 2020.09.23 09:22 #2138

Aleksandr Martynov:
Buena pregunta, tengo un coche y algo traquetea en él, ¿qué tornillo apretar? ¿Tienes idea de cuántos consejos son posibles y al final todos son inútiles porque hay que apretar la tuerca...

Sólo hay un código en el estudio y no hay otra manera.

Mira la razón por la que no se abre para el oro ?

***

Документация по MQL5: Дата и время / TimeCurrent

www.mql5.com

Возвращает последнее известное время сервера, время прихода последней котировки по одному из выбранных в "Обзоре рынка" символов. В обработчике OnTick() данная функция вернет время пришедшего обрабатываемого тика. В других случаях (например, вызов в обработчиках OnInit(), OnDeinit(), OnTimer() и так далее) это –...

Vladimir Karputov 2020.09.23 09:46 #2139

Наджибулло Хабибов:

Mira la razón por la que no se abre en oro ?

***

Inserte el códigocorrectamente: utilice el botón

o, alternativamente, adjunte el archivo utilizando el botón

MQL5.community - Памятка пользователя

www.mql5.com

Теперь вы можете не только читать статьи и скачивать программы на языке MQL5, но и участвовать в обсуждении интересующих вас тем на Форуме, оставлять комментарии к статьям и опубликованным кодам. Кроме того, вы можете не только выкладывать собственные разработки в Code Base, но и публиковать Статьи, за которые мы предлагаем вознаграждение...

Наджибулло Хабибов 2020.09.23 11:54 #2140

Наджибулло Хабибов:

Mira la razón por la que no se abre en oro ?

***

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double KLot       = 1;        // умножение лота
extern double MaxLot     = 5;        // максимальный лот
extern double Profit     = 0;        // Профит в валюте
extern int StopLoss      = 0;        // Стоп Лось
extern int TakeProfit    = 0;        // ТейкПрофит
extern int BULevel       = 0;        // уровень БУ
extern int BUPoint       = 30;       // пункты БУ
extern int TrailingStop  = 0;        // трал
extern int StartHour     = 0;        // час начала торговли
extern int StartMin      = 30;       // минута начала торговли
extern int EndHour       = 23;       // час окончания торговли
extern int EndMin        = 30;       // минута окончания торговли
extern int Reverse       = 0;        // 1-реверс
extern int CloseSig      = 0;        // 1-закрытие по сигналу
extern int Slip          = 30;       // реквот
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int Magic         = 123;      // магик

extern string IndName    = "Aroow";
extern int SignalPeriod  = 9;

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
bool TimeSession(int aStartHour,int aStartMinute,int aStopHour,int aStopMinute,datetime aTimeCur)
  {
//--- время начала сессии
   int StartTime=3600*aStartHour+60*aStartMinute;
//--- время окончания сессии
   int StopTime=3600*aStopHour+60*aStopMinute;
//--- текущее время в секундах от начала дня
   aTimeCur=aTimeCur%86400;
   if(StopTime<StartTime)
     {
      //--- переход через полночь
      if(aTimeCur>=StartTime || aTimeCur<StopTime)
        {
         return(true);
        }
     }
   else
     {
      //--- внутри одного дня
      if(aTimeCur>=StartTime && aTimeCur<StopTime)
        {
         return(true);
        }
     }
   return(false);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)
         sl=NormalizeDouble(price+StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price-TakeProfit*_Point,_Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)
         sl=NormalizeDouble(price-StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price+TakeProfit*_Point,_Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,_Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2)
               count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;
   
   if(CountTrades()>0)
     {
      lot=NormalizeDouble(lot*MathPow(KLot,CountTrades()),2);
     }
   if(lot>MaxLot)
      lot=Lots;
   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Trailing()
  {
   bool mod;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(Bid-OrderOpenPrice()>TrailingStop*_Point)
                 {
                  if(OrderStopLoss()<Bid-TrailingStop*_Point)
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Bid-TrailingStop*_Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if((OrderOpenPrice()-Ask)>TrailingStop*_Point)
                 {
                  if((OrderStopLoss()>(Ask+TrailingStop*_Point)) || (OrderStopLoss()==0))
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Ask+TrailingStop*_Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void BU()
  {
   bool m;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(OrderOpenPrice()<=(Bid-(BULevel+BUPoint)*_Point) && OrderOpenPrice()>OrderStopLoss())
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()+BUPoint*_Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if(OrderOpenPrice()>=(Ask+(BULevel+BUPoint)*_Point) && (OrderOpenPrice()<OrderStopLoss() || OrderStopLoss()==0))
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()-BUPoint*_Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,_Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,_Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double AllProfit(int ot=-1)
  {
   double pr=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }

            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }
           }
        }
     }
   return(pr);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double blu = iCustom(NULL,0,IndName,SignalPeriod,4,Shift);
   double red = iCustom(NULL,0,IndName,SignalPeriod,5,Shift);
   double blu2 = iCustom(NULL,0,IndName,SignalPeriod,4,Shift+1);
   double red2 = iCustom(NULL,0,IndName,SignalPeriod,5,Shift+1);

   bool buy = blu<1000 && red2<1000;
   bool sell = red<1000 && blu2<1000;

   if(Reverse>0)
     {
      buy = red<1000 && blu2<1000;
      sell = blu<1000 && red2<1000;
     }

   if(BULevel>0)
      BU();
   if(TrailingStop>0)
      Trailing();
   if(AllProfit()>Profit && Profit>0)
      CloseAll();

   if(TimeSession(StartHour,StartMin,EndHour,EndMin,TimeCurrent()) && t!=Time[0])
     {
      if(buy)
        {
         PutOrder(0,Ask);
        }
      if(sell)
        {
         PutOrder(1,Bid);
        }
      t=Time[0];
     }

   if(CountTrades()>0 && CloseSig>0)
     {
      if(sell)
        {
         CloseAll(0);
        }
      if(buy)
        {
         CloseAll(1);
        }
     }

   Comment("\n blu: ",blu,
           "\n red: ",red,
           "\n All Profit: ",AllProfit());
  }
//+------------------------------------------------------------------+

Preguntas de los principiantes MQL4 MT4 MetaTrader 4 - página 214