//+------------------------------------------------------------------+
//| CustomSymbolSetSessionQuote.mq5 |
//| Copyright 2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#define CUSTOM_SYMBOL_NAME Symbol()+".C" // nombre del símbolo personalizado
#define CUSTOM_SYMBOL_PATH "Forex" // nombre del grupo en el que se creará el símbolo
#define CUSTOM_SYMBOL_ORIGIN Symbol() // nombre del símbolo a partir del cual se creará el símbolo personalizado
#define SESSION_0_FROM D'1970.01.01 00:15:00' // hora de comienzo de la sesión 0
#define SESSION_0_TO D'1970.01.01 11:59:00' // hora de finalización de la sesión 0
#define SESSION_1_FROM D'1970.01.01 12:15:00' // hora de comienzo de la sesión 1
#define SESSION_1_TO D'1970.01.01 23:59:00' // hora de finalización de la sesión 1
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- obtenemos el código de error al crear un símbolo personalizado
int create=CreateCustomSymbol(CUSTOM_SYMBOL_NAME, CUSTOM_SYMBOL_PATH, CUSTOM_SYMBOL_ORIGIN);
//--- si el código de error no es 0 (el símbolo se ha creado con éxito) y no es 5304 (símbolo ya creado), salimos.
if(create!=0 && create!=5304)
return;
//--- imprimimos el encabezado con el símbolo básico y el índice de sesión y
//--- en un ciclo por los días de la semana de lunes a viernes, imprimimos en el registro las horas de inicio y fin de cada sesión de cotización
for(int session=0; session<2; session++)
{
PrintFormat("Quote session %d of '%s' symbol from which the custom '%s' was created", session, CUSTOM_SYMBOL_ORIGIN, CUSTOM_SYMBOL_NAME);
for(int day_of_week=MONDAY; day_of_week<SATURDAY; day_of_week++)
SymbolInfoSessionQuotePrint(CUSTOM_SYMBOL_ORIGIN, (ENUM_DAY_OF_WEEK)day_of_week, session);
}
//--- en un ciclo por las dos sesiones
bool res=true;
for(int session=0; session<2; session++)
{
datetime from = SESSION_0_FROM;
datetime to = SESSION_0_TO;
if(session>0)
{
from = SESSION_1_FROM;
to = SESSION_1_TO;
}
//--- para el símbolo personalizado para cada día de la semana establecemos la hora de las sesiones de cotización
ResetLastError();
for(int day_of_week=MONDAY; day_of_week<SATURDAY; day_of_week++)
res &=CustomSymbolSetSessionQuote(CUSTOM_SYMBOL_NAME, (ENUM_DAY_OF_WEEK)day_of_week, session, from, to);
}
//--- si se ha producido un error al configurar alguna de las sesiones, mostraremos un mensaje en el registro
if(!res)
Print("CustomSymbolSetSessionQuote() failed. Error ", GetLastError());
//--- imprimimos el encabezado con el símbolo personalizado y el índice de sesión y
//--- en un ciclo por los días de la semana de lunes a viernes, imprimimos en el registro las horas de inicio y fin de cada sesión de cotización
for(int session=0; session<2; session++)
{
PrintFormat("Quote session %d of custom symbol '%s' based on '%s'", session, CUSTOM_SYMBOL_NAME, CUSTOM_SYMBOL_ORIGIN);
for(int day_of_week=MONDAY; day_of_week<SATURDAY; day_of_week++)
SymbolInfoSessionQuotePrint(CUSTOM_SYMBOL_NAME, (ENUM_DAY_OF_WEEK)day_of_week, session);
}
//--- mostramos en el gráfico en el comentario la pista sobre las teclas de finalización del script
Comment(StringFormat("Press 'Esc' to exit or 'Del' to delete the '%s' symbol and exit", CUSTOM_SYMBOL_NAME));
//--- en un ciclo infinito esperamos que Esc o Del para la salida
while(!IsStopped() && TerminalInfoInteger(TERMINAL_KEYSTATE_ESCAPE)==0)
{
Sleep(16);
//--- pulsando Del, eliminaremos el símbolo personalizado creado
if(TerminalInfoInteger(TERMINAL_KEYSTATE_DELETE)<0)
{
if(DeleteCustomSymbol(CUSTOM_SYMBOL_NAME))
PrintFormat("Custom symbol '%s' deleted successfully", CUSTOM_SYMBOL_NAME);
break;
}
}
//--- antes de la salida, limpiamos el gráfico
Comment("");
/*
resultado:
Quote session 0 of 'EURUSD' symbol from which the custom 'EURUSD.C' was created
- Monday 00:15 - 23:55
- Tuesday 00:15 - 23:55
- Wednesday 00:15 - 23:55
- Thursday 00:15 - 23:55
- Friday 00:15 - 23:55
Quote session 1 of 'EURUSD' symbol from which the custom 'EURUSD.C' was created
- Monday Session not set
- Tuesday Session not set
- Wednesday Session not set
- Thursday Session not set
- Friday Session not set
Quote session 0 of custom symbol 'EURUSD.C' based on 'EURUSD'
- Monday 00:15 - 11:59
- Tuesday 00:15 - 11:59
- Wednesday 00:15 - 11:59
- Thursday 00:15 - 11:59
- Friday 00:15 - 11:59
Quote session 1 of custom symbol 'EURUSD.C' based on 'EURUSD'
- Monday 12:15 - 23:59
- Tuesday 12:15 - 23:59
- Wednesday 12:15 - 23:59
- Thursday 12:15 - 23:59
- Friday 12:15 - 23:59
*/
}
//+------------------------------------------------------------------+
//| Crea un símbolo personalizado, devuelve el código de error |
//+------------------------------------------------------------------+
int CreateCustomSymbol(const string symbol_name, const string symbol_path, const string symbol_origin=NULL)
{
//--- determinamos el nombre del símbolo a partir del cual se creará uno personalizado
string origin=(symbol_origin==NULL ? Symbol() : symbol_origin);
//--- si no hemos podido crear el símbolo personalizado, y no se trata de un error 5304, informaremos sobre ello en el registro
ResetLastError();
int error=0;
if(!CustomSymbolCreate(symbol_name, symbol_path, origin))
{
error=GetLastError();
if(error!=5304)
PrintFormat("CustomSymbolCreate(%s, %s, %s) failed. Error %d", symbol_name, symbol_path, origin, error);
}
//--- con éxito
return(error);
}
//+------------------------------------------------------------------+
//| Elimina el símbolo personalizado |
//+------------------------------------------------------------------+
bool DeleteCustomSymbol(const string symbol_name)
{
//--- ocultamos el símbolo de la ventana de Observación de mercado
ResetLastError();
if(!SymbolSelect(symbol_name, false))
{
PrintFormat("SymbolSelect(%s, false) failed. Error %d", GetLastError());
return(false);
}
//--- si no se ha podido eliminar el símbolo personalizado, informaremos de ello en el registro y retornaremos false
ResetLastError();
if(!CustomSymbolDelete(symbol_name))
{
PrintFormat("CustomSymbolDelete(%s) failed. Error %d", symbol_name, GetLastError());
return(false);
}
//--- con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Mostramos en el registro la hora de inicio y finalización de |
//| la sesión de cotización para los símbolos y días indicados |
//+------------------------------------------------------------------+
void SymbolInfoSessionQuotePrint(const string symbol, const ENUM_DAY_OF_WEEK day_of_week, const uint session_index)
{
//--- declaramos las variables para registrar el inicio y el final de la sesión de cotización
datetime date_from; // hora de inicio de la sesión
datetime date_to; // hora de finalización de la sesión
//--- creamos el nombre del día de la semana a partir de una constante de enumeración
string week_day=EnumToString(day_of_week);
if(week_day.Lower())
week_day.SetChar(0, ushort(week_day.GetChar(0)-32));
//--- obtenemos los datos de la sesión de cotización
if(!SymbolInfoSessionQuote(symbol, day_of_week, session_index, date_from, date_to))
{
int err=GetLastError();
string message=(err==4307 ? StringFormat("- %-10s Session not set", week_day) :
StringFormat("SymbolInfoSessionQuote(%s, %s, session %d) failed. Error %d", symbol, week_day, session_index, GetLastError()));
Print(message);
return;
}
//--- mostramos en el registro los datos de la sesión de cotización
PrintFormat("- %-10s %s - %s", week_day, TimeToString(date_from, TIME_MINUTES), TimeToString(date_to, TIME_MINUTES));
}
|