Ein Unter-Workshop zum Ausfüllen der FAQ (häufig gestellte Fragen). Helfen wir den Kameraden! - Seite 13

Neuer Kommentar
 
Was ist der Unterschied zwischen Instant Execution und Market Execution?

(Integer ): Mit Instant Executuion kann eine Order mit einem voreingestellten Stop-Loss und Take-Profit geöffnet werden, die Slippage in Pips eingestellt werden, die es ermöglicht, eine Order zu öffnen, wenn der Kurs zum Zeitpunkt der Ausführung durch den Broker vom Wunschkurs des Händlers abweicht. Bei der Marktausführung ist es nicht möglich, eine Order mit einem vorher festgelegten Stop Loss und/oder Take Profit zu eröffnen, es gibt keinen Parameter für den Slippage. Der Auftrag wird zu jedem zum Zeitpunkt der Ausführung durch den Makler verfügbaren Kurs eröffnet. Ein Stop-Loss und/oder Take-Profit kann unmittelbar nach der Eröffnung des Auftrags gesetzt werden. Die meisten Handelsplätze arbeiten im Modus "Sofortige Ausführung". Nicht so viele Handelsplätze arbeiten im Marktausführungsmodus.
 
Immer mehr Maklerunternehmen stellen auf Market Execution um. Bald werden die von Integer gegebenen Informationen irrelevant werden.
 
joo:
Immer mehr Maklerunternehmen stellen auf Market Execution um. Bald werden die von Integer gegebenen Informationen irrelevant werden.

Es handelt sich lediglich um Informationen über die beiden Modi.

und das ist genau das, was im letzten Absatz der FAQ steht - ein Trend! https://www.mql5.com/ru/forum/131853/page3#464977

-------

Übrigens, wie ist das Glossar der Begriffe, ist der Patient eher lebendig?

Dateien:
mql4_10.zip  419 kb
 
sergeev:

1. und der letzte Absatz in den FAQ sagt genau das - Trend! https://www.mql5.com/ru/forum/131853/page3#464977

-------

2) Übrigens, wie ist das Glossar der Begriffe, ist der Patient eher lebendig?

1. Ich habe den letzten Absatz in der FAQ auf dem Link nicht gesehen und nur auf den Beitrag von granit77 reagiert.

2. Ich habe den Abschnitt gelesen, in dem ich meine eigene Hilfe angeboten habe. Aber es ist so vollständig, wie man es sich nur wünschen kann. Es gibt praktisch nichts mehr hinzuzufügen. Ich hätte es früher melden sollen - ich bedaure, dies nicht getan zu haben.

Dennoch kann der Abschnitt Abkürzungen von Begriffen enthalten, die von Programmierern und Händlern verwendet werden. Ich habe gerade eine neue Stelle angetreten und habe jetzt sehr wenig Freizeit, kaum genug, um wenigstens mein eigenes Projekt weiterzuführen. Deshalb werde ich nach und nach "auf einen Zettel" schreiben, und wenn ich mehr davon angesammelt habe, werde ich es dem Abschnitt hinzufügen. ALLES KLAR?

 
joo:

ok
 

Frage: Abrufen eines Arrays von "eigenen" Aufträgen

Antwort: Unter dem Gesichtspunkt der Code-Optimierung ist dies der günstigste Ansatz: Zuerst führen wir die "Revision" der "freundlichen" (d.h. Aufträge mit der angegebenen MagicNumber()) Aufträge durch, erstellen ein Array von Tickets mit allen Informationen zu jedem Ticket und führen dann alle anderen Überprüfungen (zum Schließen und Ändern von Positionen) mit demselben Array von Tickets durch.
Beispiel #1. Sammeln von Informationen über Tickets für ein Währungspaar.
// Сначала объявляем массив в глобальных переменных
double gda_Tickets[30][10]; // массив для хранения информации о "своих" ордерах:
       // gda_Tickets[][0] - Ticket
       // gda_Tickets[][1] - Type
       // gda_Tickets[][2] - Lots
       // gda_Tickets[][3] - Open Price
       // gda_Tickets[][4] - OrderProfit
       // gda_Tickets[][5] - Stop Loss
       // gda_Tickets[][6] - Take Profit
       // gda_Tickets[][7] - Open Time
       // gda_Tickets[][8] - MagicNumber
       // gda_Tickets[][9] - Expiration Time
// Не забываем о счётчике ордеров (он нам ещё понадобится)
int   gi_cnt_Tickets;
// сама функция
void fMyTickets (double& ar_Tickets[][10], int fi_Magic = -1)
{
    int li_cnt = 0; // счетчик заполнения
    int li_total = OrdersTotal();
//----
    for (int li_int = li_total - 1; li_int >= 0; li_int--)
    {
        if (OrderSelect (li_int, SELECT_BY_POS))
        {
            //---- проверка на Symbol
            if (OrderSymbol() != Symbol()) 
            {continue;}
            //---- проверка MagicNumber
            if (OrderMagicNumber() != fi_Magic
            && fi_Magic >= 0) // предусматриваем возможность контролтровать любой Magic
            {continue;}
            //---- заполняем массив
            ar_Tickets[li_cnt][0] = OrderTicket();
            ar_Tickets[li_cnt][1] = OrderType();
            ar_Tickets[li_cnt][2] = OrderLots();
            ar_Tickets[li_cnt][3] = OrderOpenPrice();
            ar_Tickets[li_cnt][4] = OrderProfit() + OrderSwap() + OrderCommission();
            ar_Tickets[li_cnt][5] = OrderStopLoss();
            ar_Tickets[li_cnt][6] = OrderTakeProfit();
            ar_Tickets[li_cnt][7] = OrderOpenTime();
            ar_Tickets[li_cnt][8] = OrderMagicNumber();
            ar_Tickets[li_cnt][9] = OrderExpiration();
            //---- увеличим счётчик заполненных тикетов
            li_cnt++;
        }
    }   
    gi_cnt_Tickets = li_cnt;
//----
    return;   
}

Wenn Sie möchten, können Sie diese Funktion als int deklarieren und die Anzahl der "eigenen Bestellungen" zurückgeben lassen.

gi_cnt_Tickets = fMyTickets (gda_Tickets, Magic);

Wenn unser EA mehrwährungsfähig ist.
Beispiel #2. Sammeln von Ticketinformationen für verschiedene Währungspaare.

Um in diesem Fall nach "freundlichen" Symbolen zu suchen, benötigen wir eine weitere kleine Funktion:

//IIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIII+
//|  UNI:      Получаем номер элемента в массиве string                               |
//IIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIIII+
int fGetNumElementInArray_STR (string sArray[], string Element)
{
//----
    for (int l_int = 0; l_int < ArraySize (sArray); l_int++)
    {
        if (sArray[l_int] == Element)
        {return (l_int);}
    }
//---- 
    return (-1);
}

und unsere Funktion wird diese Form haben:

// В глобальных переменных объявляем ещё одина массив, теперь с символами с которыми работает наш мультивалютный советник
string gsa_Symbols[];
// Для использования его в советнике, нужно предварительно задать его размер и заполнить символами
// (как это сделать - отдельная тема)
// сама функция
int fMyTickets (string ar_Symbol[],        // заполненный массив рабочих символов
                 double& ar_Tickets[][11], // массив тикетов (для заполнения)
                 int fi_Magic = -1)        // MagicNumber
{
    int NUM_Symbol, li_cnt = 0; // счетчик заполнения
    int li_total = OrdersTotal();
    string ls_Sym;
//----
    for (int li_int = li_total - 1; li_int >= 0; li_int--)
    {
        if (OrderSelect (li_int, SELECT_BY_POS))
        {
            ls_Sym = OrderSymbol();
            //---- Определяем номер символа в массиве (фильтр по Symbol)
            NUM_Symbol = fGetNumElementInArray_STR (ar_Symbols, ls_Sym);
            //---- Если ордер не "свой" - пропускаем
            if (NUM_Symbol < 0)
            {continue;}
            //---- проверка MagicNumber
            if (OrderMagicNumber() != fi_Magic)
            {continue;}
            //---- заполняем массив
            ar_Tickets[li_cnt][0] = OrderTicket();
            ar_Tickets[li_cnt][1] = OrderType();
            ar_Tickets[li_cnt][2] = OrderLots();
            ar_Tickets[li_cnt][3] = OrderOpenPrice();
            ar_Tickets[li_cnt][4] = OrderProfit() + OrderSwap() + OrderCommission();
            ar_Tickets[li_cnt][5] = OrderStopLoss();
            ar_Tickets[li_cnt][6] = OrderTakeProfit();
            ar_Tickets[li_cnt][7] = OrderOpenTime();
            ar_Tickets[li_cnt][8] = OrderMagicNumber();
            ar_Tickets[li_cnt][9] = OrderExpiration();
            //---- для дальнейших вычислений не лишним будет запомнить номер индекса символа в массиве символов
            //---- но для этого не забудьте увеличить размер массива тикетов при его объявлении gda_Tickets[30][11]
            ar_Tickets[li_cnt][10] = NUM_Symbol;
            //---- увеличим счётчик заполненных тикетов
            li_cnt++;
        }
    }   
//----
    return (li_cnt);   
}
 

Frage: Abrufen eines Arrays von "eigenen" Bestellscheinen

Antwort: (Fortsetzung)

Kein Wunder, wenn Sie möchten, dass Ihr EA zusätzliche Statistiken über seine Arbeit hat, z.B.: der maximale Drawdown, der Gesamtgewinn, usw. Damit Sie den Server nicht mit zusätzlichen Anfragen "belästigen" müssen, empfehlen wir Ihnen, unsere Funktion zu erweitern (entschuldigen Sie das Wortspiel). In diesem Fall könnte die Funktion wie folgt aussehen

Variante 1 für einen Monocurrency EA:

// Объявляем массив в глобальных переменных
double gda_Tickets[30][10]; // массив для хранения информации о "своих" ордерах:
       // gda_Tickets[][0] - Ticket
       // gda_Tickets[][1] - Type
       // gda_Tickets[][2] - Lots
       // gda_Tickets[][3] - Open Price
       // gda_Tickets[][4] - Order Profit
       // gda_Tickets[][5] - Stop Loss
       // gda_Tickets[][6] - Take Profit
       // gda_Tickets[][7] - Open Time
       // gda_Tickets[][8] - MagicNumber
       // gda_Tickets[][9] - Expiration Time
// Добавляем массив для сбора ститистики
double gda_AddInfo[5]; // массив для хранения дополнительной информации по работе советника
       // gda_AddInfo[0] - количество соих ордеров (всех)
       // gda_AddInfo[1] - количество своих рыночных ордеров
       // gda_AddInfo[2] - общий размер открытых рыночных лотов
       // gda_AddInfo[3] - общий профит по открытым позициям
       // gda_AddInfo[4] - максимальная просадка по открытым позициям
void fMyTickets (double& ar_Tickets[][10], // массив тикетов (для заполнения)
                 double& ar_Info[],        // массив для заполнения дополнительной информацией
                 int fi_Magic = -1)        // MagicNumber
{
    int li_cnt = 0; // счетчик заполнения
    int li_total = OrdersTotal();
    double tmp_Loss;
//----
    tmp_Loss = ar_Info[4];
    //---- Обнуляем заполняемый массив перед использованием
    ArrayInitialize (ar_Info, 0.0);
    for (int li_int = li_total - 1; li_int >= 0; li_int--)
    {
        if (OrderSelect (li_int, SELECT_BY_POS))
        {
            //---- проверка на Symbol
            if (OrderSymbol() != Symbol()) 
            {continue;}
            //---- проверка MagicNumber
            if (OrderMagicNumber() != fi_Magic
            && fi_Magic >= 0) // предусматриваем возможность контролтровать любой Magic
            {continue;}
            //---- заполняем массив
            ar_Tickets[li_cnt][0] = OrderTicket();
            ar_Tickets[li_cnt][1] = OrderType();
            ar_Tickets[li_cnt][2] = OrderLots();
            ar_Tickets[li_cnt][3] = OrderOpenPrice();
            ar_Tickets[li_cnt][4] = OrderProfit() + OrderSwap() + OrderCommission();
            ar_Tickets[li_cnt][5] = OrderStopLoss();
            ar_Tickets[li_cnt][6] = OrderTakeProfit();
            ar_Tickets[li_cnt][7] = OrderOpenTime();
            ar_Tickets[li_cnt][8] = OrderMagicNumber();
            ar_Tickets[li_cnt][9] = OrderExpiration();
            //---- увеличим счётчик заполненных тикетов
            li_cnt++;
            //---- заполняем массив дополнительной информацией
            ar_Info[0]++;
            if (OrderType() < 2)
            {
                ar_Info[1]++;
                ar_Info[2] += OrderLots();
                ar_Info[3] += OrderProfit() + OrderSwap() + OrderCommission();
            }
        }
    }   
    //---- Учитываем максимальную просадку
    ar_Info[4] = MathMin (ar_Info[3], tmp_Loss);
//----
    return;   
}

Variante #2 für Mehrfachwährungen:

// В глобальных переменных объявляем массив, с символами, с которыми работает наш мультивалютный советник
string gsa_Symbols[];
// Массив с дополниетельной информацией должен быть 2-ух мерным
// 1-ый индекс - это номер символа в массиве символов gsa_Symbols[]
// Не забудьте перед его использованием задать ему размер в первом измерении равный количеству используемых символов
// ArrayResize (gda_AddInfo, ArraySize (gsa_Symbols));
double gda_AddInfo[][5]; // массив для хранения дополнительной информации по работе советника
       // gda_AddInfo[][0] - количество соих ордеров (всех)
       // gda_AddInfo[][1] - количество своих рыночных ордеров
       // gda_AddInfo[][2] - общий размер открытых рыночных лотов
       // gda_AddInfo[][3] - общий профит по открытым позициям
       // gda_AddInfo[][4] - максимальная просадка по открытым позициям
// Для использования его в советнике, нужно предварительно задать его размер и заполнить символами
// (как это сделать - отдельная тема)

void fMyTickets (string ar_Symbol[],      // заполненный массив рабочих символов
                double& ar_Tickets[][11], // массив тикетов (для заполнения)
                double& ar_Info[][5],     // массив для заполнения дополнительной информацией
                int fi_Magic)             // MagicNumber
{
    int NUM_Symbol, li_cnt = 0, li_Range = ArraySize (ar_Symbol); // счетчик заполнения
    int li_total = OrdersTotal();
    string ls_Sym;
    double tmp_Loss[];
//----
    //---- Инициализируем временный массив для хранения сведений о максимальной просадке
    ArrayResize (tmp_Loss, li_Range);
    //---- Сохраняем в него эти сведения
    for (int li_int = 0; li_int < li_Range; li_int++)
    {tmp_Loss[li_int] = ar_Info[li_int][4];}
    //---- Обнуляем используемый массив
    ArrayInitialize (ar_Info, 0.0);
    for (int li_int = li_total - 1; li_int >= 0; li_int--)
    {
        if (OrderSelect (li_int, SELECT_BY_POS))
        {
            ls_Sym = OrderSymbol();
            //---- Определяем номер символа в массиве (фильтр по Symbol)
            NUM_Symbol = fGetNumElementInArray_STR (ar_Symbols, ls_Sym);
            //---- Если ордер не "свой" - пропускаем
            if (NUM_Symbol < 0)
            {continue;}
            //---- проверка MagicNumber
            if (OrderMagicNumber() != fi_Magic
            && fi_Magic >= 0) // предусматриваем возможность контролтровать любой Magic
            {continue;}
            //---- заполняем массив
            ar_Tickets[li_cnt][0] = OrderTicket();
            ar_Tickets[li_cnt][1] = OrderType();
            ar_Tickets[li_cnt][2] = OrderLots();
            ar_Tickets[li_cnt][3] = OrderOpenPrice();
            ar_Tickets[li_cnt][4] = OrderProfit() + OrderSwap() + OrderCommission();
            ar_Tickets[li_cnt][5] = OrderStopLoss();
            ar_Tickets[li_cnt][6] = OrderTakeProfit();
            ar_Tickets[li_cnt][7] = OrderOpenTime();
            ar_Tickets[li_cnt][8] = OrderMagicNumber();
            ar_Tickets[li_cnt][9] = OrderExpiration();
            ar_Tickets[li_cnt][10] = NUM_Symbol;
            //---- увеличим счётчик заполненных тикетов
            li_cnt++;
            //---- заполняем массив дополнительной информацией
            ar_Info[NUM_Symbol][0]++;
            if (OrderType() < 2)
            {
                ar_Info[NUM_Symbol][1]++;
                ar_Info[NUM_Symbol][2] += OrderLots();
                ar_Info[NUM_Symbol][3] += OrderProfit() + OrderSwap() + OrderCommission();
                ar_Info[NUM_Symbol][4] = MathMin (tmp_Loss[NUM_Symbol], ar_Info[NUM_Symbol][3]);
            }
        }
    }   
//----
    return;   
}

In den obigen Beispielen zur Erfassung von Fahrscheininformationen sind diese Informationen in den allermeisten Fällen ausreichend. Aber in komplexeren Systemen verbietet Ihnen niemand, Informationen über sie in einem Array von Tickets zu speichern, zum Beispiel, wenn virtuelle Stopps in Ihrem Expert Advisor implementiert sind:

double gda_Tickets[30][12]; // массив для хранения информации о "своих" ордерах:
       // gda_Tickets[][0] - Ticket
       // gda_Tickets[][1] - Type
       // gda_Tickets[][2] - Lots
       // gda_Tickets[][3] - Open Price
       // gda_Tickets[][4] - Order Profit
       // gda_Tickets[][5] - Stop Loss
       // gda_Tickets[][6] - Take Profit
       // gda_Tickets[][7] - Open Time
       // gda_Tickets[][8] - MagicNumber
       // gda_Tickets[][9] - Expiration Time
       // gda_Tickets[][10] - Virtual SL
       // gda_Tickets[][11] - Virtual TP

Im Allgemeinen sind Sie hier nur durch Ihre Fantasie / Ihren Fanatismus und Ihr MQL4-Wissen eingeschränkt.

 

TarasBY

Um den Server nicht unnötig mit Anfragen zu "belästigen"...

Der Server wird beim Abholen der Bestellungen nicht gestört. Die Ideologie des Sammelns von Auftragsinformationen in einem Array ist UG. Dies sollte auf keinen Fall in den FAQ stehen.
 
TheXpert:
Der Server wird beim Abholen der Bestellungen nicht gestört. Die Ideologie des Sammelns von Auftragsinformationen in einem Array -- UG. Dies ist in den FAQ in keiner Weise erlaubt.

Eine andere Option vorschlagen. für die Notwendigkeit, mit "eigenen" Aufträgen zu arbeiten
 
Ich würde das nicht empfehlen. In den meisten Fällen ist eine Reihe von Fahrkarten gar nicht erforderlich. Und es ist imho richtig, immer die aktuellsten Informationen beim Terminal zu erfragen.
1...67891011121314151617181920...24
Neuer Kommentar