Ich schreibe kostenlos einen Ratgeber - Seite 161

[Radmir Serebrennikov]

Wer kann einen Indikator auf 2 Strahlen mit einer Bindung an den aktuellen Preis schreiben?

Generell gilt: In einem bestimmten Abstand zum Kurs (Bid und Ask) befinden sich zwei horizontale Strahlen - einer unten, der andere oben. Der Abstand kann in den Indikatoreinstellungen festgelegt werden. Ich danke Ihnen!

[Vladimir Karputov]

Radmir Serebrennikov #:

Hallo zusammen, wer kann einen Indikator auf 2 Strahlen mit Bindung an den aktuellen Preis schreiben?

Generell gilt: In einem bestimmten Abstand zum Preis (Bid und Ask) befinden sich zwei horizontale Strahlen - einer unten, der andere oben. Der Abstand kann in den Indikatoreinstellungen festgelegt werden. Ich danke Ihnen!

Code: Dynamisch hoch und niedrig

Abbildung 1: Dynamisches Hoch und Tief

[Radmir Serebrennikov]

Vladimir Karputov #:

Code: Dynamisch hoch und niedrig

Abb. 1: Dynamisches Hoch und Tief

ICH DANKE IHNEN VIELMALS!!!

[xi43blck]

Kann jemand einen Scriptor in mt5 schreiben, der nach dem Ausführen eine Liste der verfügbaren Instrumente mit bdb bar gibt? Bdb bar, ist es auch Umkehrung, mit einem Minimum unter dem vorherigen und Schließen in der oberen 30% und umgekehrt, über und Schließen in der unteren 30%. Es gibt etwa 3 Tausend Instrumente.

[And05]

Salud! Es ist ein Bedarf entstanden, mit Daten aus einer Datei zu handeln. Im Wesentlichen ein Bot, der ein Paar aus einer Datei nimmt, die Richtung, berechnet das Los-Risiko... Ich habe gesucht und nichts Ähnliches gefunden, haben Sie etwas Ähnliches?

[Namiq Acalov]

Hallo. Ein frohes neues Jahr für Sie! Bitte helfen Sie mir, Befehle in MQL5 hinzuzufügen, um alle Kaufpositionen bei signal="buy" zu schließen. Und umgekehrt, alle Kaufpositionen werden bei signal="sell" geschlossen. Ich danke Ihnen im Voraus.

[Vladimir Karputov]

Namiq Acalov #:

Hallo. Ein frohes neues Jahr für Sie! Bitte helfen Sie mir, Befehle in MQL5 hinzuzufügen, um alle Kaufpositionen bei signal="buy" zu schließen. Und umgekehrt, alle Kaufpositionen werden bei signal="sell" geschlossen. Ich danke Ihnen im Voraus.

Verwenden Sie den ArtikelAlmost a constructor, um einen EA zu erstellen- Sie müssen den Parameter'InpCloseOpposite' auf'true' setzen

input group             "Additional features"

*** 
input bool                 InpCloseOpposite        = true;          // Positions: Close opposite

*** 

[Namiq Acalov]

Vladimir Karputov #:

Verwenden Sie den ArtikelAlmost constructor, um einen EA zu erstellen- Sie müssen den Parameter'InpCloseOpposite' auf'true' setzen

Danke, Vladimir. Ich lese es gerade

[Grigory Zakordonsky]

Guten Abend, liebe Experten. Wie lässt sich die Losgröße der ersten Bestellung im Raster ermitteln?

Meine Frage ist, wie man den maximalen Drawdown-Wert für das Infopanel festlegen kann (der Drawdown selbst wird berechnet, ist aber variabel; wie kann man den maximalen Wert herausbekommen).

Ich bekomme ein gutes Feedback, ich versuche MQL4 mit Beispielen und bin bei diesen beiden Positionen durch Versuch und Irrtum hängen geblieben (

[SanAlex]

Namiq Acalov #:

Hallo. Ein frohes neues Jahr für Sie! Bitte helfen Sie mir, Befehle in MQL5 hinzuzufügen, um alle Kaufpositionen bei signal="buy" zu schließen. Und umgekehrt, alle Kaufpositionen werden bei signal="sell" geschlossen. Ich danke Ihnen im Voraus.

Die Funktion ist dem Codevon Vladimir Karputov entnommen

//+------------------------------------------------------------------+
//|                                                ClosePosition.mq5 |
//|                                  Copyright 2021, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2021, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
//---
#define    InpMagic  0
//---
#include <Trade\Trade.mqh>
#include <Trade\SymbolInfo.mqh>
#include <Trade\PositionInfo.mqh>
#include <Trade\AccountInfo.mqh>
//---
CTrade            m_trade;                      // trading object
CSymbolInfo       m_symbol;                     // symbol info object
CPositionInfo     m_position;                   // trade position object
CAccountInfo      m_account;                    // account info wrapper
//---
input double InpLots          =0.1; // Lots
input int    InpTakeProfit    =50;  // Take Profit (in pips)
//---
double            m_adjusted_point;             // point value adjusted for 3 or 5 points
double            m_take_profit=0.0;
//---
string m_name[]= {"Buy","Sell","CloseBuy","CloseSell"};
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- initialize common information
   m_symbol.Name(Symbol());                  // symbol
   m_trade.SetExpertMagicNumber(InpMagic); // magic
   m_trade.SetMarginMode();
   m_trade.SetTypeFillingBySymbol(Symbol());
//--- tuning for 3 or 5 digits
   int digits_adjust=1;
   if(m_symbol.Digits()==3 || m_symbol.Digits()==5)
      digits_adjust=10;
   m_adjusted_point=m_symbol.Point()*digits_adjust;
//--- set default deviation for trading in adjusted points
   m_take_profit     =InpTakeProfit*m_adjusted_point;
//--- set default deviation for trading in adjusted points
   m_trade.SetDeviationInPoints(3*digits_adjust);
//---
   int u=15;
   for(int y=0; y<ArraySize(m_name); y++)
     {
      ButtonCreate(m_name[y],5,u,170,15,8);
      u=u+17;
     }
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   for(int y=0; y<ArraySize(m_name); y++)
     {
      ObjectDelete(0,Symbol()+m_name[y]);
     }
//---
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   if(!RefreshRates())
      return;
   if(ObjectGetInteger(0,Symbol()+"Buy",OBJPROP_STATE)!=0)
     {
      ObjectSetInteger(0,Symbol()+"Buy",OBJPROP_STATE,0);
      double priceAsk=m_symbol.Ask();
      double tpAsk   =m_symbol.Bid()+m_take_profit;
      //--- check for free money
      if(m_account.FreeMarginCheck(Symbol(),ORDER_TYPE_BUY,InpLots,priceAsk)<0.0)
         printf("We have no money. Free Margin = %f",m_account.FreeMargin());
      else
        {
         //--- open position
         if(m_trade.PositionOpen(Symbol(),ORDER_TYPE_BUY,InpLots,priceAsk,0.0,tpAsk))
            printf("Position by %s to be opened",Symbol());
         else
           {
            printf("Error opening BUY position by %s : '%s'",Symbol(),m_trade.ResultComment());
            printf("Open parameters : price=%f,TP=%f",priceAsk,tpAsk);
           }
        }
     }
   if(ObjectGetInteger(0,Symbol()+"Sell",OBJPROP_STATE)!=0)
     {
      ObjectSetInteger(0,Symbol()+"Sell",OBJPROP_STATE,0);
      double priceBid=m_symbol.Bid();
      double tpBid   =m_symbol.Ask()-m_take_profit;
      //--- check for free money
      if(m_account.FreeMarginCheck(Symbol(),ORDER_TYPE_SELL,InpLots,priceBid)<0.0)
         printf("We have no money. Free Margin = %f",m_account.FreeMargin());
      else
        {
         //--- open position
         if(m_trade.PositionOpen(Symbol(),ORDER_TYPE_SELL,InpLots,priceBid,0.0,tpBid))
            printf("Position by %s to be opened",Symbol());
         else
           {
            printf("Error opening SELL position by %s : '%s'",Symbol(),m_trade.ResultComment());
            printf("Open parameters : price=%f,TP=%f",priceBid,tpBid);
           }
        }
     }
   if(ObjectGetInteger(0,Symbol()+"CloseBuy",OBJPROP_STATE)!=0)
     {
      ObjectSetInteger(0,Symbol()+"CloseBuy",OBJPROP_STATE,0);
      ClosePositions(POSITION_TYPE_BUY);
     }
   if(ObjectGetInteger(0,Symbol()+"CloseSell",OBJPROP_STATE)!=0)
     {
      ObjectSetInteger(0,Symbol()+"CloseSell",OBJPROP_STATE,0);
      ClosePositions(POSITION_TYPE_SELL);
     }
  }
//+------------------------------------------------------------------+
//| Refreshes the symbol quotes data                                 |
//+------------------------------------------------------------------+
bool RefreshRates(void)
  {
//--- refresh rates
   if(!m_symbol.RefreshRates())
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: ","RefreshRates error");
      return(false);
     }
//--- protection against the return value of "zero"
   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: ","Ask == 0.0 OR Bid == 0.0");
      return(false);
     }
//---
   return(true);
  }
//+------------------------------------------------------------------+
//| Close positions                                                  |
//+------------------------------------------------------------------+
void ClosePositions(const ENUM_POSITION_TYPE pos_type)
  {
   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of current positions
      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)
            if(m_position.PositionType()==pos_type)
              {
               if(m_position.PositionType()==POSITION_TYPE_BUY)
                 {
                  if(!m_trade.PositionClose(m_position.Ticket())) // close a position by the specified m_symbol
                     Print(__FILE__," ",__FUNCTION__,", ERROR: ","BUY PositionClose ",m_position.Ticket(),", ",m_trade.ResultRetcodeDescription());
                 }
               if(m_position.PositionType()==POSITION_TYPE_SELL)
                 {
                  if(!m_trade.PositionClose(m_position.Ticket())) // close a position by the specified m_symbol
                     Print(__FILE__," ",__FUNCTION__,", ERROR: ","SELL PositionClose ",m_position.Ticket(),", ",m_trade.ResultRetcodeDescription());
                 }
              }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void ButtonCreate(string name,int Xdist,int Ydist,int Xsize,int Ysize,int FONTSIZE=12)
  {
   if(ObjectFind(0,Symbol()+name)<0)
      ObjectCreate(0,Symbol()+name,OBJ_BUTTON,0,100,100);
   ObjectSetInteger(0,Symbol()+name,OBJPROP_COLOR,clrWhite);
   ObjectSetInteger(0,Symbol()+name,OBJPROP_BGCOLOR,clrDimGray);
   ObjectSetInteger(0,Symbol()+name,OBJPROP_XDISTANCE,Xdist);
   ObjectSetInteger(0,Symbol()+name,OBJPROP_YDISTANCE,Ydist);
   ObjectSetInteger(0,Symbol()+name,OBJPROP_XSIZE,Xsize);
   ObjectSetInteger(0,Symbol()+name,OBJPROP_YSIZE,Ysize);
   ObjectSetString(0,Symbol()+name,OBJPROP_FONT,"Sans Serif");
   ObjectSetString(0,Symbol()+name,OBJPROP_TEXT,name);
   ObjectSetInteger(0,Symbol()+name,OBJPROP_FONTSIZE,FONTSIZE);
   ObjectSetInteger(0,Symbol()+name,OBJPROP_SELECTABLE,false);
  }
//+------------------------------------------------------------------+