//+------------------------------------------------------------------+
//| Demo_iForce.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "Der Indikator zeigt, wie Daten erhalten werden sollen"
#property description "Indikator-Puffer für den technischen Indikator iForce."
#property description "Symbol und Zeitrahmen, in denen der Indikator berechnet wird,"
#property description "sind durch die Parameter symbol und period angegeben."
#property description "Erstellungsweise des Handles ist durch den 'type' Parameter (Typ der Funktion) angegeben."
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots 1
//--- iForce bauen
#property indicator_label1 "iForce"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrLightSeaGreen
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//+------------------------------------------------------------------+
//| Enumeration der Erstellungsweisen des Handles |
//+------------------------------------------------------------------+
enum Creation
{
Call_iForce, // iForce verwenden
Call_IndicatorCreate // IndicatorCreate verwenden
};
//--- Eingabeparameter
input Creation type=Call_iForce; // Funktionstyp
input int ma_period=13; // MA Periode
input ENUM_MA_METHOD ma_method=MODE_SMA; // Art der Glättung
input ENUM_APPLIED_VOLUME applied_volume=VOLUME_TICK; // Volumentyp
input string symbol=" "; // Symbol
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // Zeitrahmen
//--- Indicator-Puffer
double iForceBuffer[];
//--- Eine Variable um Handle des Indikators Art der Glättung zu speichern
int handle;
//--- Variable für Speicherung
string name=symbol;
//--- Name des Indikators auf dem Chart
string short_name;
//--- die Anzahl der Werte im Indikator Force gespeichert wird
int bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- Bindung von Array zum Indikator-Puffer
SetIndexBuffer(0,iForceBuffer,INDICATOR_DATA);
//--- das Symbol, auf das der Indikator gebaut wird, definieren
name=symbol;
//--- Leerzeichen aus dem linken und rechten löschen
StringTrimRight(name);
StringTrimLeft(name);
//--- Wenn nach diesem die Länge des String name ist Null
if(StringLen(name)==0)
{
//--- das Symbol aus dem Chart, auf dem der Indikator läuft, nehmen
name=_Symbol;
}
//--- Erstellen ein Handel des Indikators
if(type==Call_iForce)
handle=iForce(name,period,ma_period,ma_method,applied_volume);
else
{
//--- die Struktur mit Werten von Indikatorparametern ausfüllen
MqlParam pars[3];
//--- MA Periode
pars[0].type=TYPE_INT;
pars[0].integer_value=ma_period;
//--- Art der Glättung
pars[1].type=TYPE_INT;
pars[1].integer_value=ma_method;
//--- Volumentyp
pars[2].type=TYPE_INT;
pars[2].integer_value=applied_volume;
//--- Preistyp
handle=IndicatorCreate(name,period,IND_FORCE,3,pars);
}
//--- Wenn Handle konnte nicht erstellt werden
if(handle==INVALID_HANDLE)
{
//--- darüber schreiben und Nummer des Fehlers anzeigen
PrintFormat("Handle des Indikators iForce für das Paar %s/%s konnte nicht erstellt werden. Fehlercode ist %d",
name,
EnumToString(period),
GetLastError());
//--- Arbeit des Indikators ist früher geendet
return(INIT_FAILED);
}
//--- Das Paar von Symbol/Zeitrahmen, auf deren Force berechnet war, anzeigen
short_name=StringFormat("iForce(%s/%s, %d, %s, %s)",name,EnumToString(period),
ma_period,EnumToString(ma_method),EnumToString(applied_volume));
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- normale Initialisierung des Indikators
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- Anzahl der Werte des Indikators iForce zu kopieren
int values_to_copy;
//--- Anzahl der berechneten Werte im Indikator finden
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() hat %d zurückgegeben, Fehlercode ist %d",calculated,GetLastError());
return(0);
}
//--- wenn dies der erste Start der Berechnung des Indikators ist oder die Anzahl der Werte im Indikator iForce geändert hat
//--- oder wenn Sie brauchen den Indikator für zwei oder mehr Balken (was bedeutet, dass etwas in der Geschichte verändert hat) zu berechnen
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- wenn Array iForceBuffer größer als die Anzahl der Werte in iForce auf symbol/period ist, dann kopieren wir nicht alles
//--- sonst kopieren wir weniger als Größe der Indikator-Puffer
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- dann ist unser Indikator nicht das erste Mal berechnet, und seit dem letzten Aufruf von OnCalculate())
//--- nicht mehr als ein Balken für die Berechnung hinzugefügt war
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- Das Array iForceBuffer mit den Werten aus dem Indikator Force ausfüllen
//--- Wenn FillArrayFromBuffer false zurückgegeben hat, dann die Daten nicht bereit sind - das Werk vollenden
if(!FillArrayFromBuffer(iForceBuffer,handle,values_to_copy)) return(0);
//--- Nachricht bilden
string comm=StringFormat("%s ==> Aktualisierte Werte im Indikator %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- Hilfsnachrichtung auf dem Chart anzeigen
Comment(comm);
//--- die Anzahl der Werte im Indikator Force speichern
bars_calculated=calculated;
//--- den Wert prev_calculated für den nächsten Anruf zurückgeben
return(rates_total);
}
//+------------------------------------------------------------------+
//| Indikator-Puffer aus dem Indikator iForce ausfüllen |
//+------------------------------------------------------------------+
bool FillArrayFromBuffer(double &values[], // Indikator-Puffer der Werte von Force Index
int ind_handle, // Handle des Indikators iForce
int amount // Anzahl der Werte, die kopiert werden
)
{
//--- Fehlercode rücksetzen
ResetLastError();
//--- Teil des Arrays iForceBuffer mit Werten auf Indikator-Puffer mit Index 0 ausfüllen
if(CopyBuffer(ind_handle,0,0,amount,values)<0)
{
//--- wenn die Kopie fehlschlägt, Fehlercode anzeigen
PrintFormat("Daten konnte nicht aus dem Indikator iForce kopiert werden, Fehlercode ist %d",GetLastError());
//--- Beenden mit Null-Ergebnis - dies bedeutet, dass der Indikator nicht berechnet wird
return(false);
}
//--- Alles gelang
return(true);
}
//+------------------------------------------------------------------+
//| Indicator deinitialization function |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- Das Chart nach der Löschung des Indikators leeren
Comment("");
}
|