MQL5 Wizard - Handelssignale der Kerzenformationen Morning/Evening Stars + RSI - Experte für den MetaTrader 5

Mit dem MQL5 Wizard können Trader nun Expert Advisor Codes automatisch generieren, die auf den Klassen von Handelssignalen, Positions Tracking und Money Management basieren. Neben den Klassen von Handelssignalen aus der Standardbibliothek können Sie Ihre eigenen Handelssysteme erstellen und testen, dafür brauchen Sie lediglich ein Modul für Handelssignale zu schreiben.

Das Buch "The Strategies of the Best Traders in the World" (in Russisch) beschreibt Indikatoren und Handelsstrategien für die technische Analyse unter Verwendung des MetaStock Softwarepaketes. Neben den konventionellen Handelssignalen befasst sich dieses Buch auch mit denen, die auf einer kombinierten Anwendung von Umkehrkerzenformationen mit der Bestätigung durch Stochastic, CCI, MFI und RSI basieren.

Die Verwendung von Umkehrkerzenformationen, zusammen mit Signalen von Oszillatoren, reduziert die Anzahl der falschen Signale und erhöht die Effizienz des Handelssystems.

In dieser Beschreibung betrachten wir die Ergebnisse der Anwendung der Modelle Morning Star (Morgenstern) und Evening Star (Abendstern) in der Kombination mit Signalen des RSI Indikators (die Kerzenformationen Morning Doji Star und Evening Doji Star funktionieren ähnlich).

1. Die Muster "Morning Star" und "Evening Star" und deren Erkennung

1.1. Muster "Morning Star" (Morgenstern)

Das Muster "Morning Star" besteht aus drei Kerzen und erscheint in einem Abwärtstrend (Abb. 1). Nach einer langen schwarzen Kerze kommt eine Kerze mit einem kleinen Körper (die Farbe des Körpers ist unbedeutend), der sich mit dem Körper der schwarzen Kerze nicht überschneidet. Der kleine Körper der zweiten Kerze weist auf den Wechsel von einem Abwärtstrend zur Ausgewogenheit zwischen Bullen und Bären hin.

Die dritte Kerze dieses Musters ist eine bullische Kerze, deren Körper sich nicht mit dem Körper der zweiten Kerze kreuzt, und deren Schlusskurs innerhalb des Körpers der ersten (bärischen) Kerze liegt. Auf der Abb. 1 können Sie auch die resultierende Kerze dieses Modells sehen.

Wenn die zweite Kerze des Morgensterns Doji ist, wird dieses Modell als "Morning Doji Star" (Morgenstern Doji) bezeichnet.

Abbildung 1. Kerzenformation "Morning Star" und "Morning Doji Star"

Die Erkennung dieser Modelle ist in den Methoden CheckPatternMorningStar() und CheckPatternMorningDoji der Klasse CCandlePattern umgesetzt:

//+------------------------------------------------------------------+
//| Überprüfung der Kerzenformation "Morning Star"                   |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternMorningStar()
  {
//--- Morning Star - prüft ob das Modell "Morgenstern" gebildet wird
   if((Open(3)-Close(3)>AvgBody(1))             && // eine bärische Kerze, ihr Körper ist überdurchschnittlich lang
      (MathAbs(Close(2)-Open(2))<AvgBody(1)*0.5) && // der Körper der zweiten Kerze ist klein (kleiner als die Hälfte der durchschnittlichen Körpergröße) 
      (Close(2)<Close(3))                       && // der Schlusskurs der zweiten Kerze liegt unterhalb des Schlusskurses der ersten Kerze
      (Open(2)<Open(3))                         && // der Eröffnungskurs der zweiten Kerze liegt unterhalb des Eröffnungskurses der ersten Kerze 
      (Close(1)>MidOpenClose(3)))                  // der Schlusskurs der letzten Kerze liegt oberhalb des Mittelpunkts der ersten (bärischen) Kerze 
      return(true);
//---
   return(false);
  }
//+------------------------------------------------------------------+
//| Überprüfung der Kerzenformation "Morning Doji Star"              |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternMorningDoji()
  {
//--- Morning Doji Star - prüft ob das Modell "Morgenstern Doji" gebildet wird
   if((Open(3)-Close(3)>AvgBody(1)) && // eine bärische Kerze, ihr Körper ist überdurchschnittlich lang  
      (AvgBody(2)<AvgBody(1)*0.1)   && // der Körper der zweiten Kerze Doji (kleiner als ein Zehntel der durchschnittlichen Größe)
      (Close(2)<Close(3))           && // der Schlusskurs der zweiten Kerze liegt unterhalb des Schlusskurses der ersten Kerze 
      (Open(2)<Open(3))             && // der Eröffnungskurs der zweiten Kerze liegt unterhalb des Eröffnungskurses der ersten Kerze 
      (Open(1)>Close(2))            && // Gap nach oben auf der letzten Kerze
      (Close(1)>Close(2)))             // der Schlusskurs der letzten Kerze liegt oberhalb des Schlusskurses der zweiten Kerze  
      return(true);
//---
   return(false);
  }

1.2. Muster "Evening Star" (Abendstern)

Das Muster "Abendstern" besteht auch aus drei Kerzen und wird in einem Aufwärtstrend gebildet (Abb. 2). Nach einer langen weißen Kerze kommt eine Kerze mit einem kleinen Körper (die Farbe ist unbedeutend), der sich mit dem Körper der weißen Kerze nicht überschneidet. Der kleine Körper der zweiten Kerze weist auf den Wechsel von einem Aufwärtstrend zur Ausgewogenheit zwischen Bullen und Bären hin.

Die dritte Kerze dieses Modells ist eine schwarze Kerze, deren Körper sich nicht mit dem Körper der zweiten Kerze kreuzt, und deren Schlusskurs innerhalb des Körpers der ersten (bullischen) Kerze liegt. Auf der Abb. 2 ist die resultierende Kerze dieses Modells zu sehen.

Wenn die zweite Kerze des Abendsterns eine Doji Kerze ist, dann wird dieses Modell als "Evening Doji Star" (Abendstern Doji) bezeichnet.

Abbildung 2. Kerzenformation "Evening Star" und "Evening Doji Star"

Methoden zur Erkennung der Modelle "Evening Star" und "Evening Doji Star":

//+------------------------------------------------------------------+
//| Überprüfung der Kerzenformation "Evening Star"                   |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternEveningStar()
  {
//--- Evening Star - überprüft ob das Modell "Abendstern" gebildet wird
   if((Close(3)-Open(3)>AvgBody(1))             && // eine bullische Kerze, ihr Körper ist überdurchschnittlich lang
      (MathAbs(Close(2)-Open(2))<AvgBody(1)*0.5) && // der Körper der zweiten Kerze ist klein (kleiner als die Hälfte der durchschnittlichen Körpergröße der Kerze)
      (Close(2)>Close(3))                       && // der Schlusskurs der zweiten Kerze liegt oberhalb des Schlusskurses der ersten Kerze
      (Open(2)>Open(3))                         && // der Eröffnungskurs der zweiten Kerze liegt oberhalb des Eröffnungskurses der ersten Kerze
      (Close(1)<MidOpenClose(3)))                  // der Schlusskurs der letzten Kerze liegt unterhalb des Mittelpunktes der ersten (bullischen) Kerze 
      return(true);
//---
   return(false);
  }
//+------------------------------------------------------------------+
//| Überprüfung der Kerzenformation "Evening Doji Star"              |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternEveningDoji()
  {
//--- Evening Doji Star  - überprüft, ob das Muster "Evening Doji Star" gebildet wird
   if((Close(3)-Open(3)>AvgBody(1)) && // eine bullische Kerze, ihr Körper ist überdurchschnittlich lang
      (AvgBody(2)<AvgBody(1)*0.1)   && // die zweite Kerze ist eine Doji Kerze (ihr Körper ist kleiner als ein Zehntel der durchschnittlichen Länge) 
      (Close(2)>Close(3))           && // der Schlusskurs der zweiten Kerze liegt oberhalb des Schlusskurses der ersten Kerze 
      (Open(2)>Open(3))             && // der Eröffnungskurs der zweiten Kerze liegt oberhalb des Eröffnungskurses der ersten Kerze  
      (Open(1)<Close(2))            && // Gap nach unten auf der letzten Kerze
      (Close(1)<Close(2)))             // der Schlusskurs der letzten Kerze liegt unterhalb des Schlusskurses der zweiten Kerze 
      return(true);
//---
   return(false);
  }

2. Handelssignale in der Kombination mit dem RSI Indikator

Die Einstiegssignale müssen durch den RSI Indikator bestätigt werden. Der Wert von RSI muss unterhalb des Levels 40 für Long- und oberhalb des Levels 60 für Short-Positionen liegen.

Die Ausstiegssignale werden gebildet, wenn RSI den gegensätzlichen Level erreicht (70 für Long- und 30 für Short-Positionen) oder wenn er beim Erreichen des Levels 30 oder 70 die Umkehr für jeweils Long oder Short nicht bestätigt.

Abbildung 3. Handelssignale des Musters "Morning Star" mit der Bestätigung durch den RSI-Indikator

Die Bedingungen für Einstieg und Ausstieg werden in den folgenden Methoden überprüft:

• int CMS_ES_RSI::LongCondition() - überprüft die Bedingungen für das Eröffnen einer Long-Position (die Funktion gibt 80 zurück) und Schließen einer Short-Position (die Funktion liefert 40 zurück);
  
• int CMS_ES_RSI::ShortCondition() - überprüft die Bedingungen für das Eröffnen einer Short-Position (die Funktion liefert 80) und Schließen einer Long-Position (die Funktion liefert 40).

2.1. Eröffnen einer Long-Position und Schließen einer Short-Position

1. Das Signal zum Eröffnen einer Long-Position entsteht, wenn sich das Muster Morning Star ("Morgenstern") bildet und die Bedingung RSI(1)<40 erfüllt ist (der Wert des RSI Indikators auf dem letzten Balken ist kleiner als 40).

2. Das Signal zum Schließen einer Short-Position entsteht, wenn der RSI Indikator den Level 30 (von unten nach oben) oder den Level 70 (von unten nach oben) kreuzt.
   

   //+--------------------------------------------------------------------+
   //| Methode zur Überprüfung der Bedingungen für Einstieg und Ausstieg  |
   //| Überprüfung der Bedingungen für                                    |
   //| 1) Einstieg (Eröffnen einer Long-Position, result=80)              |
   //| 2) Ausstieg (Schließen einer Short-Position, result=40)            |
   //+--------------------------------------------------------------------+
   int CMS_ES_RSI::LongCondition()
     {
      int result=0;
   //--- idx kann verwendet werden, um den Modus des EAs festzustellen
   //--- idx=0 - der EA wird die Erfüllung der Bedingungen auf jedem Tick überprüfen
   //--- idx=1 - der EA wird die Erfüllung der Bedingungen nur auf neuen Balken überprüfen
      int idx   =StartIndex();
   //--- Überprüfung der Bedingungen für das Eröffnen einer Long-Position
   //--- Formation des Musters Morning Star und Erfüllung der Bedingung RSI<40
      if(CheckCandlestickPattern(CANDLE_PATTERN_MORNING_STAR) && (RSI(1)<40))
        result=80;
   //--- Überprüfung der Bedingungen für das Schließen einer Short-Position
      if(((RSI(1)>30) && (RSI(2)<30)) || ((RSI(1)>70) && (RSI(2)<70)))
         result=40;
        result=40;
   //--- result zurückgeben
      return(result);
     }
   

2.2. Eröffnen einer Short-Position und Schließen einer Long-Position

1. Das Signal zum Eröffnen einer Short-Position entsteht, wenn das Muster Evening Star ("Abendstern") auftritt und die Bedingung RSI(1)>60 erfüllt ist (der Wert des RSI Indikators auf dem letzten vollständigen Balken ist größer 60).

2. Das Signal zum Schließen einer Long-Position entsteht, wenn der RSI Indikator den Level 70 (von oben nach unten) oder den Level 30 (von oben nach unten) kreuzt.
   

   //+-------------------------------------------------------------------+
   //| Methode zur Überprüfung der Bedingungen für Einstieg und Ausstieg |
   //| Überprüfung der Bedingungen für                                   |
   //| 1) Einstieg (Eröffnen einer Short-Position, result=80)            |
   //| 2) Ausstieg (Schließen einer Long-Position, result=40)            |
   //+-------------------------------------------------------------------+
   Sint CMS_ES_RSI::ShortCondition()
     {
      int result=0;
   //--- idx kann verwendet werden, um den Modus des EAs festzustellen
   //--- idx=0 - der EA wird die Erfüllung der Bedingungen auf jedem Tick überprüfen
   //--- idx=1 - der EA wird die Erfüllung der Bedingungen nur auf neuen Balken überprüfen
      int idx   =StartIndex();
   //--- Überprüfung der Bedingungen für das Eröffnen einer Short-Position
   //--- Formation des bärischen Modells Evening Star und Erfüllung der Bedingung RSI>60
     if(CheckCandlestickPattern(CANDLE_PATTERN_EVENING_STAR) && (RSI(1)>60))
        result=80;
   //--- Überprüfung der Bedingungen für das Schließen einer Long-Position
     if(((RSI(1)<70) && (RSI(2)>70)) || ((RSI(1)<30) && (RSI(2)>30)))
        result=40;
   //--- result zurückgeben
      return(result);
     }
   

2.3. Erstellung eines Expert Advisors auf der Basis der Handelssignale des Umkehrmodells "Morning/Evening Stars + RSI" mithilfe von MQL5 Wizard

Starten Sie den MQL5 Wizard, um einen Handelsroboter nach dieser Strategie zu erstellen:

Abb. 4. Erstellung eines EAs im MQL5 Wizard

Klicken Sie auf "Next" und geben Sie den Namen des EAs ein:

Abb. 5. Allgemeine Parameter des EAs

Danach sind die Parameter der Signale einzugeben:

Abb. 6. Parameter der Signale

In unserem Fall verwenden wir nur ein Modul von Handelssignalen.

Fügen wir das Modul "Signals based on Morning/Evening Stars confirmed by RSI" hinzu:

Abb. 7. Parameter der Signale

Das Modul ist hinzugefügt:

Abb. 8. Parameter der Signale

Danach kann man das Modul des Trailings auswählen, wir werden es allerdings nicht verwenden. "Trailing Stop not used" auswählen:

Abb. 9. Trailing Modul

Des Weiteren ist das Money Management Modul auszuwählen, wir werden den Handel mit einem festen Volumen (Trading with fixed trade volume) verwenden:

Abb. 10. Money Management Modul

Klicken Sie auf "Finish" Button und Sie bekommen den Code des generierten Expert Advisors - die Datei Expert_AMS_ES_RSI.mq5 wird in terminal_data_folder\MQL5\Experts\ gespeichert.

Die Eingabeparameter des Expert Advisors (default):

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in Punkten)
input double         Signal_TakeLevel       =50.0;   // Take Profit level (in Punkten)

ersetzen durch:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in Punkten)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in Punkten)

Die Parameter Signal_ThresholdOpen und Signal_ThresholdClose lassen Schwellenwerte für das Eröffnen und Schließen von Position setzen.

Im Code der Funktionen LongCondition() und ShortCondition() des Moduls von Handelssignalen haben wir die festen Schwellenwerte angegeben:

• Für das Eröffnen von Positionen: 80;
• Für das Schließen von Positionen: 40.
  

Die Werte von Signal_StopLevel und Signal_TakeLevel setzen wir auf 0, dies bedeutet, dass die Positionen nur beim Eingehen von Handelssignalen zum Schließen geschlossen werden.

2.4 Testergebnisse anhand historischer Daten

Die Ergebnisse des Expert Advisors bei einem Test unter Verwendung von historischen Daten (EURUSD H1, Testperiode: 2009.01.01-2011.03.03, PeriodRSI=47, MA_period=3).

Dieser Expert Advisor benutzt das Modul für den Handel mit einer festgelegten Lotgröße von 0.1 Lot (Trading Fixed Lot), ein Trailing Stop wurde nicht verwendet (Trailing not used).

Abb. 11. Testergebnisse des EAs, der auf der Basis des Generators der Handelssignale "Morning/Evening Stars + RSI" erstellt wurde

Das beste Parameterset für das Tradingsystem ist mithilfe von Strategietester des MetaTrader 5 Kundenterminals zu finden.

Der Code des EAs, der im MQL5 Wizard erstellt wurde, ist in der Datei expert_ams_es_rsi.mq5 .

Das beste Parameterset für das Tradingsystem ist mithilfe von Strategietester des MetaTrader 5 Kundenterminals zu finden.

Der Modus der 3D-Visualisierung für Testergebnisse erleichtert deutlich die Ermittlung der Parameter von Handelssystemen (Abb. 6).

Abb. 12. Ergebnisse der 3D-Visualisirung des Kontostandes als Funktion der PeriodRSI und MA_period Parameter.

Der von dem MQL5 Wizard generierte Code für den Expert Advisor ist angehängt als Datei: expert_ms_es_rsi.mq5.