MQL5 Wizard - Handelssignale der Kerzenformationen Bullish Harami/Bearish Harami + Stochastic - Experte für den MetaTrader 5

Mit dem MQL5 Wizard können Trader nun Expert Advisor Codes automatisch generieren, die auf den Klassen von Handelssignalen, Positions Tracking und Money Management basieren. Neben den Klassen von Handelssignalen aus der Standardbibliothek können Sie Ihre eigenen Handelssysteme erstellen und testen, dafür brauchen Sie lediglich ein Modul für Handelssignale zu schreiben.

Das Buch "The Strategies of the Best Traders in the World" (in Russisch) beschreibt Indikatoren und Handelsstrategien für die technische Analyse unter Verwendung des MetaStock Softwarepaketes. Neben den konventionellen Handelssignalen befasst sich dieses Buch auch mit denen, die auf einer kombinierten Anwendung von Umkehrkerzenformationen mit der Bestätigung durch Stochastic, CCI, MFI und RSI basieren.

Die Verwendung von Umkehrkerzenformationen, zusammen mit Signalen von Oszillatoren, reduziert die Anzahl der falschen Signale und erhöht die Effizienz des Handelssystems.

In dieser Beschreibung werden die Ergebnisse einer kombinierten Anwendung der Kerzenformationen Bullish Harami und Bearish Harami zusammen mit den Signalen des Stochastic Indikators betrachtet.

1. Die Kerzenformationen "Bullish Harami" und "Bearish Harami" und deren Erkennung

Als "Harami" wird eine Kombination aus zwei Kerzen bezeichnet. Das Muster besteht aus einem langen Körper und einem darauffolgenden kleinen Körper, der komplett innerhalb des ersten Körpers liegt. Harami ist das Gegenteil des Musters Engulfing. Im Muster "Engulfing" umschlingt eine lange Kerze den Körper der Vortagskerze, und in der Kerzenformation "Harami" folgt auf einen langen Körper ein ganz kleiner Körper.

1.1. Kerzenformation Bullish Harami

Die Umkehrkerzenformation "Bullish Harami" tritt auf, wenn in einem Abwärtstrend nach einer langen bärischen Kerze eine bullische Kerze erscheint, deren Körper komplett innerhalb des Körpers der bärischen Kerze liegt.

Die zweite Kerze eröffnet sich mit einer Lücke gegenüber dem Schlusskurs der ersten Kerze.

Die Kerzenformation Bullish Harami weist auf die Umkehr eines Abwärtstrends hin. Je kleiner der Körper der bullischen Kerze ist, desto wahrscheinlicher ist die Umkehr.

Abb. 1. Kerzenformation "Bullish Harami"

Die Erkennung der Kerzenformation "Bullish Harami" wird in der Methode CheckPatternBullishHarami der Klasse CCandlePattern umgesetzt:

//+------------------------------------------------------------------+
//| Methode zur Überprüfung der Formation "Bullish Harami"           |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishHarami()
  {
//--- Bullish Harami- Erkennung des Musters Bullish Harami
   if((Close(1)>Open(1))              && // die letzte vollständige Kerze ist eine bärische Kerze (white day)
     ((Open(2)-Close(2))>AvgBody(1))  && // die Vortagskerze ist eine bärische Kerze, ihr Körper ist überdurchschnittlich lang (long black)
     ((Close(1)<Open(2))              && // der Schlusskurs der bullischen Kerze liegt unter dem Eröffnungskurs der bärischen Kerze 
      (Open(1)>Close(2)))             && // der Eröffnugskurs der bullischen Kerze liegt über dem Schlusskurs der bärischen Kerze (engulfment)
      (MidPoint(2)<CloseAvg(2)))         // Abwärtstrend (down trend)
      return(true);
//---
   return(false);
  }

1.2. Kerzenformation "Bearish Harami"

Das Umkehrmodell "Bearish Harami" entsteht, wenn in einem Aufwärtstrend nach einer langen bullischen Kerze eine bärische Kerze erscheint, deren Körper komplett innerhalb des Körpers der bullischen Kerze liegt.

Die zweite Kerze eröffnet sich mit einer Lücke gegenüber dem Schlusskurs der ersten Kerze.

Die Bearish Harami weist auf die Umkehr eines Aufwärtstrends. Je kleiner der Körper der bärischen Kerze ist, desto wahrscheinlicher ist die Umkehr.

Abb. 2. Kerzenformation "Bearish Harami"

Methode zur Erkennung des Musters "Bearish Harami":

//+------------------------------------------------------------------+
//| Methode zur Überprüfung der Formation "Bearish Harami"           |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishHarami()
  {
//--- Bearish Harami- Erkennung des Musters  "Bearish Harami"
   if((Close(1)<Open(1))              && // die letzte vollständige Kerze ist eine bärische Kerze (black day)
     ((Close(2)-Open(2))>AvgBody(1))  && // die Vortagskerze ist eine bullische Kerze, ihr Körper ist überdurchschnittlich lang (long white)
     ((Close(1)>Open(2))              && // der Schlusskurs der bärischen Kerze liegt oberhalb des Eröffnungskurses der bullischen Kerze 
      (Open(1)<Close(2)))             && // der Eröffnugskurs der bärischen Kerze liegt unterhalb des Schlusskurses der bullischen Kerze (engulfment)
      (MidPoint(2)>CloseAvg(2)))         // Aufwärtstrend (up trend)
      return(true);
//---
   return(false);
  }

2. Handelssignale in der Kombination mit dem Stochastic Indikator

Die Signale zum Eröffnen einer Long- oder Short-Position werden nur unter der Bedingung gesendet, dass das Umkehrmuster durch die Lage des Stochastic-Oszillator bestätigt wird. Der Wert der Signallinie %D muss oberhalb oder unterhalb eines entsprechenden kritischen Levels liegen (30 und 70).

Die Ausstiegssignale werden je nach dem weiteren Verhalten der %D gebildet: wenn %D einen gegensätzlichen Level erreicht (80 in Long- und 20 in Short-Positionen) oder wenn %D das Umkehrsignal nicht bestätigt und den Level 20 in einer Long- und 80 in einer Short-Position erreicht.

Abb. 3. Handelssignale der Kerzenformation "Bearish Harami" mit der Bestätigung durch den Stochastic Indikator

Die Bedingungen für Einstieg und Ausstieg werden in den folgenden Methoden überprüft:

• int CBH_BH_Stoch::LongCondition() überprüft die Bedingungen für das Eröffnen einer Long-Position (die Funktion gibt 80 zurück) und Schließen einer Short-Position (die Funktion gibt 40 zurück);
  
• int CBH_BH_Stoch::ShortCondition() überprüft der Bedingungen für das Eröffnen einer Short-Position (die Funktion gibt 80 zurück) und Schließen einer Long-Position (die Funktion gibt 40 zurück).

2.1. Eröffnen einer Long-Position und Schließen einer Short-Position

1. Das Signal zum Eröffnen einer Long-Position entsteht, wenn die Kerzenformation Bullish Harami auftritt und die Bedingung StochSignal(1)<30 erfüllt ist (der Wert der Signallinie des Stochastic Indikators auf dem letzten vollständigen Balken ist kleiner als 30):

2. Das Signal zum Schließen einer Short-Position entsteht, wenn die Signallinie des Stochastic Indikators den Level 20 (von unten nach oben) oder den Level 80 (von unten nach oben) kreuzt.

//+--------------------------------------------------------------------+
//| Methode zur Überprüfung der Bedingungen für Einstieg und Ausstieg  |
//| Überprüfung der Bedingungen für                                    |
//| 1) Einstieg (Eröffnen einer Long-Position, result=80)              |
//| 2) Ausstieg (Schließen einer Short-Position, result=40)            |
//+--------------------------------------------------------------------+
int CBH_BH_Stoch::LongCondition()
  {
   int result=0;
//--- idx kann verwendet werden, um den Modus des EAs festzustellen
//--- idx=0 - der EA wird die Erfüllung der Bedingungen auf jedem Tick überprüfen
//--- idx=1 - der EA wird die Erfüllung der Bedingungen nur auf neuen Balken überprüfen
   int idx   =StartIndex();
//--- Überprüfung der Bedingungen für das Eröffnen einer Long-Position
//--- bullische Kerzenformation Bullish Harami und die Erfüllung der Bedingung signal line<30
  if (CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_HARAMI) && (StochSignal(1)<30))
     result=80;
//--- Überprüfung der Bedingungen für das Schließen einer Short-Position
//--- die Signallinie kreuzt die Levels (20 von oben nach unten, 80 von unten nach oben)
   if((((StochSignal(1)>20) && (StochSignal(2)<20)) ||
       ((StochSignal(1)>80) && (StochSignal(2)<80))))
     result=40;
//--- result zurückgeben
   return(result);
  }

2.2. Eröffnen einer Short-Position und Schließen einer Long-Position

1. Das Signal zum Eröffnen einer Short-Position entsteht, wenn die Kerzenformation Bearish Harami auftritt und die Bedingung StochSignal(1)>70 erfüllt ist (der Wert der Signallinie des Stochastic Indikators auf dem letzten vollständigen Balken ist größer als 70):

2. Das Signal zum Schließen einer Long-Position entsteht, wenn die Signallinie des Stochastic Indikators den Level 80 (von oben nach unten) oder des Levels 20 von oben nach unten) kreuzt.

//+--------------------------------------------------------------------+
//| Methode zur Überprüfung der Bedingungen für Einstieg und Ausstieg  |
//| Überprüfung der Bedingungen für                                    |
//| 1) Einstieg (Eröffnen einer Short-Position, result=80)             |
//| 2) Ausstieg (Schließen einer Long-Position, result=40)             |
//+--------------------------------------------------------------------+
int CBH_BH_Stoch::ShortCondition()
  {
   int result=0;
//--- idx kann verwendet werden, um den Modus des EAs festzustellen
//--- idx=0 - der EA wird die Erfüllung der Bedingungen auf jedem Tick überprüfen
//--- idx=1 - der EA wird die Erfüllung der Bedingungen nur auf neuen Balken überprüfen
   int idx   =StartIndex();
//--- Überprüfung der Bedingungen für das Eröffnen einer Short-Position
//--- bärische Kerzenformation Bearish Harami und Erfüllung der Bedingung signal line>70
  if (CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_HARAMI) && (StochSignal(1)>70))
     result=80;
//--- Überprüfung der Bedingungen für das Schließen einer Long-Position
//--- die Signallinie kreuzt die Levels (80 - von oben nach unten, 20 von oben nach unten)
   if((((StochSignal(1)<80) && (StochSignal(2)>80)) ||
       ((StochSignal(1)<20) && (StochSignal(2)>20))))
     result=40;
//--- result zurückgeben
   return(result);
  }

2.3. Erstellung eines Expert Advisors auf der Basis der Handelssignale des Umkehrkerzenformation "Bullish Harami/Bearish Harami + Stochastic" mithilfe von MQL5 Wizard

Starten Sie den MQL5 Wizard, um einen Handelsroboter nach dieser Strategie zu erstellen:

Abb. 4. Erstellung eines EAs im MQL5 Wizard

Klicken Sie auf "Next" und geben Sie den Namen des EAs ein:

Abb. 5. Allgemeine Parameter des EAs

Danach sind die Parameter der Signale einzugeben:

Abb. 6. Parameter der Signale

In unserem Fall verwenden wir nur ein Modul von Handelssignalen.

Fügen wir das Modul "Signals based on Bullish Harami/Bearish Harami confirmed by Stochastic" hinzu:

Abb. 7. Parameter der Signale

Das Modul ist hinzugefügt:

Abb. 8. Parameter der Signale

Danach kann man das Modul des Trailings auswählen, wir werden es allerdings nicht verwenden. "Trailing Stop not used" auswählen:

Abb. 9. Trailing Modul

Des Weiteren ist das Money Management Modul auszuwählen, wir werden den Handel mit einem festen Volumen (Trading with fixed trade volume) verwenden:

Abb. 10. Money Management Modul

Klicken Sie auf "Finish" und Sie erhalten den Code des erstellten Expert Advisors - die Datei Expert_BH_BH_Stoch.mq5 wird in terminal_data_folder\MQL5\Experts\ gespeichert.

Die Eingabeparameter des Expert Advisors (default):

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in Punkten)
input double         Signal_TakeLevel       =50.0;   // Take Profit level (in Punkten)

ersetzen durch:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in Punkten)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in Punkten)

Die Parameter Signal_ThresholdOpen und Signal_ThresholdClose lassen Schwellenwerte für das Eröffnen und Schließen von Position setzen.

Im Code der Funktionen LongCondition() und ShortCondition() des Moduls von Handelssignalen haben wir die festen Schwellenwerte angegeben:

• Für das Eröffnen von Positionen: 80;
• Für das Schließen von Positionen: 40.
  

Die Werte von Signal_StopLevel und Signal_TakeLevel setzen wir auf 0, dies bedeutet, dass die Positionen nur beim Eingehen von Handelssignalen zum Schließen geschlossen werden.

2.4. Testergebnisse

Die Testergebnisse des EAs bei einem Test unter Verwendung von historischen Daten (EURUSD H1, Zeitraum: 1.1.2010-04.03.2011, PeriodK=47, PeriodD=9, PeriodSlow=13, MA_period=5).

Dieser Expert Advisor benutzt das Modul für den Handel mit einer festgelegten Lotgröße von 0.1 Lot (Trading Fixed Lot), ein Trailing Stop wurde nicht verwendet (Trailing not used).

Abb. 11. Testergebnisse für den EA, der auf der Basis des Generators von Handelssignalen "Bullish/Bearish Harami + Stochastic" erstellt wurde

Das beste Parameterset für das Tradingsystem ist mithilfe von Strategietester des MetaTrader 5 Kundenterminals zu finden.

Der von dem MQL5 Wizard generierte Code für den Expert Advisor ist angehängt als Datei: expert_abh_bh_stoch.mq5 enthalten.