CDouble & CDoubleVector - Bibliothek für den MetaTrader 5

Eine Bibliothek für gängige Rundungsmethoden in der MQL-Entwicklung, primitive Wrapper-Klasse für Typ (double) und Vektor für CDouble-Objekte. MQL5 und MQL4 kompatibel!

CDouble

Die Klasse CDouble umschließt einen Wert vom primitiven Typ double in ein Objekt. Zusätzlich bietet diese Klasse mehrere Methoden und statische Methoden für Rundung von Doubles und Arrays/Kollektionen vom Typ double.

Deklaration

class CDouble : public CObject

Titel

#include <Double.mqh>

Vererbungshierarchie

• CObject
  • CDouble

Virtuelle Methode implemented/overridden von der Klassen CObject: Type, Load, Save, Compare.

Ein Objekt vom Typ CDouble mit folgenden 5 Datenfeldern:

string

m_symbol

double

m_value

uchar

m_step

uchar

m_digits

ENUM_PRECISION

m_mode

Bevor wir weiter in die Dokumentation einsteigen, hier ein kurzes praktisches Beispiel der Wrapper-Klasse in Aktion:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   CDouble  price = tick.ask - 0.0087263487676283476,
            sl    = price - 500*_Point,
            tp    = price + 500*_Point,
            lots  = 5.25 / 3.78789;
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = price.AsRoundedTick();
   r.sl    = sl.AsRoundedTick();
   r.tp    = tp.AsRoundedTick();
   r.volume= lots.AsRoundedLots();
...

Ein anderes Beispiel, das die 'static' Methoden der Bibliothek verwendet:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = tick.ask - 0.0087263487676283476,
   r.sl    = price - 500*_Point,
   r.tp    = price + 500*_Point,
   r.volume= 5.25 / 3.78789;
   ...
   CDouble::RoundTradeRequest(r);
   //Preis wird automatisch auf 'tick size' gerundet
   //und das Volumen auf 'lot step'

Zusammenfassung der 'static' Methoden

Hinweis: Es ist nicht notwendig, OOP zu kennen oder eine Wrapper-Klasseninstanz zu verwenden, um diese Bibliothek zu nutzen. Alles was man tun muss, ist die 'static' Funktionen mit CDouble Scope Auflösung aufzurufen. Die Syntax ist wie folgt:

type variable_name = CDouble::Method(args);

static bool

IsEqual
(double number1,
 double number2,
 double step);

static bool

IsEqual
(double number1,
 double number2,
 int digits);

static int

Compare
(double number1,
 double number2,
 double step)

static double

RoundToStep
(const double number, 
 double step)

static double

RoundToDigit
(const double number, 
 int digits)

static double

RoundToStepUp
(const double number, 
 double step)

static double

RoundToStepDown
(const double number, 
 double step)

static double

RoundToTick
(const double number, 
 string symbol=NULL)

static double

RoundToLots
(const double number,
 string symbol=NULL,
 bool always_return_valid=true)

static void (MQL5)

RoundTradeRequest
(MqlTradeRequest &request)

static void

RoundArrayToStep
(double &arr[],
 double step = NULL)

static void

RoundArrayToStep
(CArrayDouble &arr,
 double step = NULL)

static int

GetDigits
(double floating_point)

static double 

GetPoint
(int digits)

static string

ToString
(double number,
 int digits)

Beispiele:

MqlTick tick;
   SymbolInfoTick(_Symbol,tick);
   double rnd_by_step   = CDouble::RoundToStep(tick.bid*1.052565465,_Point);
   double rnd_by_digits = CDouble::RoundToDigit(tick.bid*1.052565465,_Digits);
   double by_lot_step   = CDouble::RoundToLots(0.123423,_Symbol);
   double by_tick_size  = CDouble::RoundToTick(tick.ask-100*_Point,_Symbol);
   double roundup       = CDouble::RoundToStepUp(3.999999999,_Point);
   double rounddn       = CDouble::RoundToStepDown(3.999999999,_Point);
   int    digits        = CDouble::GetDigits(0.0000025);
   double point         = CDouble::GetPoint(10);
   bool   equal         = CDouble::IsEqual(tick.bid,tick.bid+0.00000009,_Point);
   string tostr         = CDouble::ToString(3.1399999999999999);
   int    compare       = CDouble::Compare(tick.ask,tick.bid);
   
#ifdef __MQL5__
   MqlTradeRequest r={0};
   r.symbol= _Symbol;
   r.price = tick.ask+0.000089849847658759198199999;
   r.sl    = r.price - 503 * _Point;
   r.tp    = r.price + 503 * _Point;
   r.volume= 1.127984984;
   
   CDouble::RoundTradeRequest(r);
#endif 

Zusammenfassung der Konstruktoren

CDouble
(const ENUM_PRECISION mode = PRECISION_DEFAULT,
 const string symbol = NULL)

CDouble
(const CDouble &other)

Beispiele:

CDouble num;
CDouble bid(PRECISION_TICK_SIZE, _Symbol);
CDouble ask(bid)
CDouble ask2 = bid;
CDouble lots(PRECISION_LOT_STEP, _Symbol);

Zzusammenfassung der Zuordnungen - Überladene Zuweisungsoperatoren

void

Set(const double value)

void

Set(const CDouble &other)

void

Hinweis: Der Zuweisungsoperator = kann in derselben Zeile wie die Deklaration aufgerufen werden.

Beispiele:

CDouble bid;
bid.Set(tick.bid);
CDouble ask = tick.ask;

CDouble pi = 3.14;
CDouble factor = 2;
pi*=factor;
Print(pi.ToString());
//6.28

Zusammenfassung der überladenen arithmetischen Operatoren

double

Hinweis: Nur eine arithmetischer Operator kann je Anweisung verwendet werden.

Syntax der überladenen arithmetischen Operatoren:

type_double_result <-- CDouble_object <-- operator <-- double
//CDouble Objekte stehen immer auf der linken Seite des Operators

type_double_result <-- CDouble_object1 <-- operator <-- CDouble_object2
//Die Reihenfolge spielt bei der Verwendung von zwei CDouble Objekten keine Rolle.

Beispiele:

CDouble foo    = 3.14;
CDouble bar    = 10;
CDouble foobar = bar + foo;          //13.14
CDouble err    = bar + foo + foobar; //Error - illegale Operation verwendet

double var = bar / foo;

Zusammenfassung, überladene Vergleichsoperator

bool

Beispiele:

CDouble foo = 3.14, bar = 3.139999999999999999999;
   
   Print(foo == bar); //true
   Print(foo <= bar); //true
   Print(foo >  bar); //false

Zusammenfassung Methoden zu Instanziierung

Präzisionssteuerung (Standardwerte): Dezimalstelle (digits) = 8; Schrittweite (step) = 1e-08

• Es gibt drei Möglichkeiten, die Genauigkeit zu steuern: Schrittweite, Dezimalstellen oder PrecisionMode(ENUM_PRECISION). Jeder Aufruf einer dieser Methoden überschreibt die vorherigen Einstellungen.
• Die Schrittweite ist entweder der _Point oder LOT_STEP oder TickSize; dargestellt als Dezimalzahl (zB 0.00001, 0.025 etc.)
• Es ist nicht erforderlich, die Schrittweite festzulegen, da RoundToTick und RoundToLot automatisch die entsprechenden Schrittweiten für die Rundung verwenden.

void

PrecisionMode
(const ENUM_PRECISION mode)

ENUM_PRECISION

PrecisionMode()

void

Step
(const double step_or_point)

double

Step()

void

Digits
(const int digits)

int

Digits()

double

AsRawDouble()

double

AsRounded()

double

AsRoundedUp()

double

AsRoundedDown()

double

AsRoundedTick()

double

AsRoundedLots
(bool always_return_valid = true)

int

ToInt()

long

ToLong()

string

ToStringPrecision()

string

ToString()

string

Symbol()

string

Symbol(const string symbol)

Beispiele:

CDouble pi2 = 3.14159265359;
   
   // getting value as... 
   double raw_double             = pi2.AsRawDouble();
   double round_double_to_step   = pi2.AsRounded();
   double tick_size_double       = pi2.AsRoundedTick();
   double lot_step_double        = pi2.AsRoundedLots();
   double rounded_up             = pi2.AsRoundedUp();
   double rounded_down           = pi2.AsRoundedDown();
   int    double_to_int          = pi2.ToInt();
   long   double_to_long         = pi2.ToLong();
   string precision_str          = pi2.ToStringPrecision();
   pi2 = 3.140000000009;
   pi2.Digits(8);
   string truncated_str          = pi2.ToString();

Zusammenfassung der virtuellen Methoden

Methoden, die von CObject überschrieben werden:

virtual int

Compare
(const CObject *node,
 const int mode=0)

virtual int

Type()

virtual bool

Save(const int file_handle)

virtual bool

Load(const int file_handle)

Für Beispiele siehe CDoubleVector weiter unten.

CDoubleVector

Die KLasse CDoubleVector ist eine Kollektion von Objektzeigern, die für die dynamischen Instanzen CDouble spezialisiert ist.

Deklaration

class CDoubleVector : public CArrayObj

Titel

#include <Double.mqh>

Vererbungshierarchie

• CObject
  • CArray
    • CArrayObj
      • CDoubleVector

Virtuelle Methoden implementiert/überschrieben von der Klasse CArrayObj: CreateElement.

Zusammenfassung Methoden zu Instanziierung

**Siehe CArrayObj für die geerbten 'public' Methoden.

CDouble*

operator[]
(const int index)

bool

Add(const double value)

bool

AssignDoubleArray
(const double &array[])

bool

CopyOut(double &arr[])

bool

CopyOut(CArrayDouble &arr)

virtual bool

Save(const int file_handle)

virtual bool

Load(const int file_handle)

Beispiele:

CDoubleVector *vect = new CDoubleVector;
   
   double dubs[]={3.14,1.21,55.555};
   vect.AssignDoubleArray(dubs);
   vect.Add(tick.bid);
   
   //Aufruf des CDouble Objekts über den Index
   Print(vect[vect.Total()-1].ToString());
   
   //neues CDouble object hinzufügen
   CDouble *lot = new CDouble(PRECISION_LOT_STEP);
   lot = 1.22;
   vect.Add(lot);
   
   //Vektor aufwärts sortieren
   vect.Sort();
   
   int total = vect.Total();
   
   //Speichern des Vektors in der Datei einschließlich des Status von CDouble Objekts und der Werte
   string f = "testdub.bin";
   int    h = FileOpen(f,FILE_WRITE|FILE_BIN);
   if(vect.Save(h))
      Print("save successful");
   FileClose(h);
   delete vect;
   
   //laden des Vektors aus der Datei
   CDoubleVector vect_reborn;
   h=FileOpen(f,FILE_READ|FILE_BIN);
   if(vect_reborn.Load(h))
      Print("load successful");
   FileClose(h);
   total = vect_reborn.Total();
   Print("Total vector size = ",sizeof(vect_reborn)," bytes");
   for(int i=0;i<vect_reborn.Total();i++)
      Print(vect_reborn[i].ToString());
      
   //Kopieren in double arr
   double arr2[];
   vect_reborn.CopyOut(arr2);
   Print(ArraySize(arr2));