Cualquier pregunta de los recién llegados sobre MQL4 y MQL5, ayuda y discusión sobre algoritmos y códigos

[Artyom Trishkin]

En este hilo quiero empezar a ayudar a aquellos que realmente quieren entender y aprender a programar en el nuevo MQL4 y quieren cambiar fácilmente a MQL5 - los lenguajes son muy similares.

Este blog será un buen lugar para discutir los problemas, los algoritmos de su solución y cualquier otra cuestión relacionada con la programación de MT de una manera u otra.

Espero que otros miembros experimentados de nuestro foro se unan a nosotros y este hilo sea interesante para todos.

[mila.com]

Hola.

¿Es posible hacer que el número de barras de construcción en el indicador estándar de Fractales sea personalizable, es decir, diferente de 5?

Si es así, ¿cómo se puede hacer?

[Andrey F. Zelinsky]

mila.com:

¿Es posible hacer que el número de barras de construcción en el indicador estándar de Fractales sea personalizable, es decir, diferente de 5?

Si es así, ¿cómo se puede hacer?

No se puede hacer esto en el estándar (terminal)

[Artyom Trishkin]

mila.com:

Hola.

¿Es posible hacer que el número de barras de construcción en el indicador estándar de Fractales sea personalizable, es decir, diferente de 5?

Si es así, ¿cómo se puede hacer?

Como ya te ha dicho Andrey, no se puede utilizar el estándar, pero ¿qué te impide hacer el tuyo propio?

[Andrey F. Zelinsky]

el código base tiene unhttps://www.mql5.com/ru/search#!keyword=fractals&module=mql5_module_codebase

[mila.com]

Andrey F. Zelinsky:
existe en la base de códigohttps://www.mql5.com/ru/search#!keyword=fractals&module=mql5_module_codebase

Gracias. Necesito uno sólo para mq4https://www.mql5.com/es/code/1381

Lo he compilado en el editor de MT4, funciona, pero carga la cpu, ¿qué debo cambiar para que no la cargue?

//--- indicator buffers
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   2
//--- plot UpFractals
#property indicator_label1  "Up Fractals"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrDodgerBlue
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- plot DnFractals
#property indicator_label2  "Down Fractals"
#property indicator_type2   DRAW_ARROW
#property indicator_color2  clrTomato
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//--- input parameters
input int      InpLeftSide = 3;          // Кол-во баров слева от фрактала
input int      InpRightSide = 3;         // Кол-во баров справа от фрактала
//--- indicator buffers
double         UpFractalsBuffer[];
double         DnFractalsBuffer[];
//--- global variables
int            minRequiredBars;
int            leftSide, rightSide;
int            maxSide;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit() {
//---
   if ( InpLeftSide < 1 ) {
      leftSide = 2;
      printf("Неккоретно указан параметр \"Кол-во баров слева от фрактала\": %d. Будет использовано значение: %d.",
         InpLeftSide, leftSide);
   } else {
      leftSide = InpLeftSide;
   }
   if ( InpRightSide < 1 ) {
      rightSide = 2;
      printf("Неккоретно указан параметр \"Кол-во баров справа от фрактала\": %d. Будет использовано значение: %d.",
         InpRightSide, rightSide);
   } else {
      rightSide = InpRightSide;
   }
//---
   minRequiredBars = leftSide + rightSide + 1;
   maxSide = int(MathMax(leftSide, rightSide));
//---
   SetIndexBuffer(0, UpFractalsBuffer, INDICATOR_DATA);
   SetIndexBuffer(1, DnFractalsBuffer, INDICATOR_DATA);
//---
   PlotIndexSetInteger(0, PLOT_ARROW, 217);
   PlotIndexSetInteger(1, PLOT_ARROW, 218);
//---
   PlotIndexSetInteger(0, PLOT_ARROW_SHIFT, -10);  
   PlotIndexSetInteger(1, PLOT_ARROW_SHIFT, 10);
//---
   for ( int i = 0; i < 2; i++ ) {
      PlotIndexSetInteger(i, PLOT_DRAW_BEGIN, minRequiredBars);
      PlotIndexSetDouble(i, PLOT_EMPTY_VALUE, 0.0);
   }
//---
   IndicatorSetInteger(INDICATOR_DIGITS, _Digits);
//---
   IndicatorSetString(INDICATOR_SHORTNAME, "ffra ("+(string)leftSide+", "+(string)rightSide+")");
//---
   return(0);
}
//+------------------------------------------------------------------+
//| Check if is Up Fractal function                                  |
//+------------------------------------------------------------------+
bool isUpFractal(int bar, int max, const double &High[]) {
//---
   for ( int i = 1; i <= max; i++ ) {
      if ( i <= leftSide && High[bar] < High[bar-i] ) {
         return(false);
      }
      if ( i <= rightSide && High[bar] <= High[bar+i] ) {
         return(false);
      }
   }
//---
   return(true);  
}
//+------------------------------------------------------------------+
//| Check if is Down Fractal function                                |
//+------------------------------------------------------------------+
bool isDnFractal(int bar, int max, const double &Low[]) {
//---
   for ( int i = 1; i <= max; i++ ) {
      if ( i <= leftSide && Low[bar] > Low[bar-i] ) {
         return(false);
      }
      if ( i <= rightSide && Low[bar] >= Low[bar+i] ) {
         return(false);
      }
   }
//---
   return(true);  
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
{
//---
   int startBar, lastBar;
//---
   if ( rates_total < minRequiredBars ) {
      Print("Недостаточно данных для расчёта");
      return(0);
   }
//---
   if (prev_calculated < minRequiredBars) {
      startBar = leftSide;
      ArrayInitialize(UpFractalsBuffer, 0.0);
      ArrayInitialize(DnFractalsBuffer, 0.0);
   }        
   else {
      startBar = rates_total - minRequiredBars;
   }
//---
   lastBar = rates_total - rightSide;
   for ( int bar = startBar; bar < lastBar && !IsStopped(); bar++ ) {
      //---
      if ( isUpFractal(bar, maxSide, high) ) {
         UpFractalsBuffer[bar] = high[bar];
      } else {
         UpFractalsBuffer[bar] = 0.0;
      }
      //---
      if ( isDnFractal(bar, maxSide, low) ) {
         DnFractalsBuffer[bar] = low[bar];
      } else {
         DnFractalsBuffer[bar] = 0.0;
      }
   }  
//--- return value of prev_calculated for next call
   return(rates_total);
}
//+------------------------------------------------------------------+

[Artyom Trishkin]

mila.com:

Gracias. Necesito uno sólo en mq4https://www.mql5.com/es/code/1381

Las correcciones son mínimas:

//+------------------------------------------------------------------+
//|                                              iXBarsFractals.mq4  |
//|               Copyright 2011, Rone. redaction 2016 by artmedia70 |
//|                                            [e-mail] |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, Rone."
#property link      "[e-mail]"
#property version   "1.00"
#property description "Индикатор позволяет отдельно указывать кол-во баров слева и справа от фрактала. Хорошо подходит "
#property description "для определения как локальных, так и глобальных экстремумов."
#property strict
//--- indicator buffers
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   2
//--- plot UpFractals
#property indicator_label1  "Up Fractals"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrDodgerBlue
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- plot DnFractals
#property indicator_label2  "Down Fractals"
#property indicator_type2   DRAW_ARROW
#property indicator_color2  clrTomato
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//--- input parameters
input int      InpLeftSide = 3;          // Кол-во баров слева от фрактала
input int      InpRightSide = 3;         // Кол-во баров справа от фрактала
//--- indicator buffers
double         UpFractalsBuffer[];
double         DnFractalsBuffer[];
//--- global variables
int            minRequiredBars;
int            leftSide,rightSide;
int            maxSide;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   leftSide=(InpLeftSide<2?2:InpLeftSide);
   rightSide=(InpRightSide<2?2:InpRightSide);
//---
   minRequiredBars=leftSide+rightSide+1;
   maxSide=int(fmax(leftSide,rightSide));
//---
   SetIndexBuffer(0,UpFractalsBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,DnFractalsBuffer,INDICATOR_DATA);
//---
   SetIndexArrow(0,217);
   SetIndexArrow(1,218);
   //PlotIndexSetInteger(0,PLOT_ARROW,217);
   //PlotIndexSetInteger(1,PLOT_ARROW,218);
//---
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,-10);
   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,10);
//---
   for(int i=0; i<2; i++) {
      PlotIndexSetInteger(i,PLOT_DRAW_BEGIN,minRequiredBars);
      PlotIndexSetDouble(i,PLOT_EMPTY_VALUE,0.0);
      }
//---
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//---
   IndicatorSetString(INDICATOR_SHORTNAME,"XBarsFractals("+(string)leftSide+", "+(string)rightSide+")");
//---
   return(0);
  }
//+------------------------------------------------------------------+
//| Check if is Up Fractal function                                  |
//+------------------------------------------------------------------+
bool isUpFractal(int bar,int max,const double &high[])
  {
//---
   for(int i=1; i<=max; i++) {
      if(i<=leftSide && high[bar]<high[bar-i])     return(false);
      if(i<=rightSide && high[bar]<=high[bar+i])   return(false);
      }
//---
   return(true);
  }
//+------------------------------------------------------------------+
//| Check if is Down Fractal function                                |
//+------------------------------------------------------------------+
bool isDnFractal(int bar,int max,const double &low[])
  {
//---
   for(int i=1; i<=max; i++) {
      if(i<=leftSide && low[bar]>low[bar-i])    return(false);
      if(i<=rightSide && low[bar]>=low[bar+i])  return(false);
      }
//---
   return(true);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   int startBar,lastBar;
//---
   if(rates_total<minRequiredBars) return(0);
//---
   if(prev_calculated<minRequiredBars) {
      startBar=leftSide;
      ArrayInitialize(UpFractalsBuffer, 0.0);
      ArrayInitialize(DnFractalsBuffer, 0.0);
      }
   else startBar=rates_total-minRequiredBars;
//---
   lastBar=rates_total-rightSide;
   for(int bar=startBar; bar<lastBar && !IsStopped(); bar++) {
      //---
      if(isUpFractal(bar,maxSide,high))   UpFractalsBuffer[bar]=high[bar];
      else                                UpFractalsBuffer[bar]=0.0;
      //---
      if(isDnFractal(bar,maxSide,low))    DnFractalsBuffer[bar]=low[bar];
      else                                DnFractalsBuffer[bar]=0.0;
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+

Es cierto que yo lo haría un poco diferente, pero es la fuerza de la costumbre...

Incluso podrías hacerlo así:

   leftSide=(InpLeftSide<1?1:InpLeftSide);
   rightSide=(InpRightSide<1?1:InpRightSide);

Entonces obtendrás fractales bastante divertidos...

[mila.com]

Artyom Trishkin:

Las correcciones son mínimas:

Aunque yo lo hubiera hecho un poco diferente, pero eso es la fuerza de la costumbre...

Incluso podrías hacerlo así:

   leftSide=(InpLeftSide<1?1:InpLeftSide);
   rightSide=(InpRightSide<1?1:InpRightSide);

En ese caso, mostrará fractales absolutamente ridículos...

Gracias, así.

PLOT_ARROW_SHIFT

Tampoco se encuentra en la Ayuda de MT4, ¿con qué sustituirlo?

[Artyom Trishkin]

mila.com:

Gracias, hay uno como este.

PLOT_ARROW_SHIFT

Tampoco en la ayuda de MT4, ¿con qué sustituirlo?

Es "Desplazamiento de la flecha vertical para el estilo DRAW_ARROW".

Ninguna de las estándar.

Sólo tiene que establecer el desplazamiento en la configuración, o por el valor de ATR

Y haz estas líneas así:

//---
   for(int i=0; i<2; i++) {
      SetIndexDrawBegin(i,minRequiredBars);
      SetIndexEmptyValue(i,0);
      //PlotIndexSetInteger(i,PLOT_DRAW_BEGIN,minRequiredBars);
      //PlotIndexSetDouble(i,PLOT_EMPTY_VALUE,0.0);
      }
//---

Borra lo que se comenta aquí y pon lo que se comenta.

[mila.com]

Artyom Trishkin:

Esto es "Desplazamiento de la flecha vertical para el estilo DRAW_ARROW".

Borra lo que está comentado aquí y pon lo que está escrito.

Todavía se está cargando.

Llamando desde otro indicador, incluso se cuelga el terminal por un momento.

¿Qué más puedo hacer?

[Artyom Trishkin]

mila.com:

Todavía se está cargando.

Llamando desde otro indicador, incluso se cuelga el terminal por un momento.

¿Qué más puedo hacer?

No llame desde otro indicador :)

O mostrar cómo lo haces.