DokümantasyonBölümler
MQL5 ReferansıDosya FonksiyonlarıFileReadString 

FileReadString

Belirtilen dosyadaki dizgiyi dosya işaretçisinin mevcut konumundan başlayarak okur.

string  FileReadString(
   int  file_handle,     // Dosya tanıtıcısı
   int  length=-1        // Dizgi uzunluğu
   );

Parametreler

file_handle

[in] FileOpen() fonksiyonunun dönüş yaptığı dosya tanımlayıcısı.

length=-1

[in]  Okunacak karakterlerin sayısı.

Dönüş değeri

Okunan satır (dizgi).

Not

Bir bin-dosyasından okuma yapılırken. okunacak dizginin uzunluğu belirtilmelidir. txt dosyasından okuma yapıldığında dizgi uzunluğunun belirtilmesi gerekmez ve dizgi, mevcut pozisyondan "\r\n" satır atlama karakterine kadar okunur. csv dosyasından okuma yapıldığında da, aynı şekilde, dizgi uzunluğunun belirtilmesi gerekmez ve dizgi mevcut pozisyondan ayırıcıya kadar veya metin dizgisinin sonuna kadar okunur

Eğer dosya FILE_ANSI bayrağı ile açılmışsa, o zaman satırlar Unicode'a dönüştürülür.

Example (burada kullanılan dosya, FileWriteInteger fonksiyonunun örneğinden elde edilmiştir)

//--- script çalıştırıldığında giriş parametrelerinin penceresini göster
#property script_show_inputs
//--- verinin okunması için gereken parametreler
input string InpFileName="Trend.bin"; // dosya ismi
input string InpDirectoryName="Data"; // dizin ismi
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- dosyayı aç
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_BIN|FILE_ANSI);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("%s dosyası, okuma için müsait",InpFileName);
      PrintFormat("Dosya yolu: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- ek değişkenler
      int    str_size;
      string str;
      //--- dosyadan veriyi oku
      while(!FileIsEnding(file_handle))
        {
         //--- zamanın yazılması için kaç adet sembol kullanıldığını öğren
         str_size=FileReadInteger(file_handle,INT_VALUE);
         //--- dizgiyi oku
         str=FileReadString(file_handle,str_size);
         //--- dizgiyi çıktıla
         PrintFormat(str);
        }
      //--- dosyayı kapat
      FileClose(file_handle);
      PrintFormat("Veriler okundu, %s dosyası kapatıldı",InpFileName);
     }
   else
      PrintFormat("%s dosyası açılamadı, Hata kodu = %d",InpFileName,GetLastError());
  }

Ayrıca Bakınız

string Tipi, Veri Dönüşümü, FileWriteInteger