//+------------------------------------------------------------------+
//| Demo_FileReadNumber.mq5 |
//| Copyright 2013, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link "https://www.mql5.com"
#property version "1.00"
#property indicator_chart_window
#property indicator_buffers 5
#property indicator_plots 1
//---- plot Label1
#property indicator_label1 "Overbought & Oversold"
#property indicator_type1 DRAW_COLOR_BARS
#property indicator_color1 clrRed, clrBlue
#property indicator_style1 STYLE_SOLID
#property indicator_width1 2
//--- verinin okunması için gereken parametreler
input string InpFileName="RSI.csv"; // dosya ismi
input string InpDirectoryName="Data"; // dizin ismi
//--- gösterge tamponları
double open_buff[];
double high_buff[];
double low_buff[];
double close_buff[];
double color_buff[];
//--- aşırı-alım değişkenleri
int ovb_ind=0;
int ovb_size=0;
datetime ovb_time[];
//--- aşırı-satım değişkenleri
int ovs_ind=0;
int ovs_size=0;
datetime ovs_time[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- ön tanımlı olarak dizi büyüklüğü değişkenleri
int ovb_def_size=100;
int ovs_def_size=100;
//--- diziler için bellek tahsis et
ArrayResize(ovb_time,ovb_def_size);
ArrayResize(ovs_time,ovs_def_size);
//--- dosyayı aç
ResetLastError();
int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_CSV|FILE_ANSI);
if(file_handle!=INVALID_HANDLE)
{
PrintFormat("%s dosyası, okuma için müsait",InpFileName);
PrintFormat("Dosya yolu: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
double value;
//--- dosyadan veri oku
while(!FileIsEnding(file_handle))
{
//--- dizgideki ilk değeri oku
value=FileReadNumber(file_handle);
//--- fonksiyon sonucuna göre farklı dizilere oku
if(value>=70)
ReadData(file_handle,ovb_time,ovb_size,ovb_def_size);
else
ReadData(file_handle,ovs_time,ovs_size,ovs_def_size);
}
//--- dosyayı kapat
FileClose(file_handle);
PrintFormat("Veri yazıldı, %s dosyası kapatıldı",InpFileName);
}
else
{
PrintFormat("%s dosyası açılamadı, Hata kodu = %d",InpFileName,GetLastError());
return(INIT_FAILED);
}
//--- dizilerin bağlanması
SetIndexBuffer(0,open_buff,INDICATOR_DATA);
SetIndexBuffer(1,high_buff,INDICATOR_DATA);
SetIndexBuffer(2,low_buff,INDICATOR_DATA);
SetIndexBuffer(3,close_buff,INDICATOR_DATA);
SetIndexBuffer(4,color_buff,INDICATOR_COLOR_INDEX);
//---- çizelgede görüntülenmesi istenmeyen gösterge değerlerini ayarla
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Dosyadaki dizgi verisini oku |
//+------------------------------------------------------------------+
void ReadData(const int file_handle,datetime &arr[],int &size,int &def_size)
{
bool flag=false;
//--- dizginin veya sayfanın sonuna kadar oku
while(!FileIsLineEnding(file_handle) && !FileIsEnding(file_handle))
{
//--- sayıyı okuduktan sonra kaydır
if(flag)
FileReadNumber(file_handle);
//--- mevcut tarihi kaydet
arr[size]=FileReadDatetime(file_handle);
size++;
//--- gerekirse dizi büyüklüğünü artır
if(size==def_size)
{
def_size+=100;
ArrayResize(arr,def_size);
}
//--- ilk tekrarı geç
flag=true;
}
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
ArraySetAsSeries(time,false);
ArraySetAsSeries(open,false);
ArraySetAsSeries(high,false);
ArraySetAsSeries(low,false);
ArraySetAsSeries(close,false);
//--- hala işlenmemiş çubuklar için döngü
for(int i=prev_calculated;i<rates_total;i++)
{
//--- varsayılan olarak 0
open_buff[i]=0;
high_buff[i]=0;
low_buff[i]=0;
close_buff[i]=0;
color_buff[i]=0;
//--- tarihlerden biri hala mevcut mu kontrol et
if(ovb_ind<ovb_size)
for(int j=ovb_ind;j<ovb_size;j++)
{
//--- tarihler aynıysa çubuk aşırı-alım bölgesinde
if(time[i]==ovb_time[j])
{
open_buff[i]=open[i];
high_buff[i]=high[i];
low_buff[i]=low[i];
close_buff[i]=close[i];
//--- 0 - kırmızı renk
color_buff[i]=0;
//--- sayacı artır
ovb_ind=j+1;
break;
}
}
//--- hala her hangi bir veri var mı kontrol et
if(ovs_ind<ovs_size)
for(int j=ovs_ind;j<ovs_size;j++)
{
//--- tarihler kesişiyorsa, çubuk aşırı-satım bölgesinde
if(time[i]==ovs_time[j])
{
open_buff[i]=open[i];
high_buff[i]=high[i];
low_buff[i]=low[i];
close_buff[i]=close[i];
//--- 1 - mavi renk
color_buff[i]=1;
//--- sayacı artır
ovs_ind=j+1;
break;
}
}
}
//--- bir sonraki çağrı için prev_calculated değerine dönüş yap
return(rates_total);
}
//+------------------------------------------------------------------+
//| ChartEvent event handler |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
const long &lparam,
const double &dparam,
const string &sparam
)
{
//--- gösterge çizgi genişliğini ölçeğe göre değiştir
if(ChartGetInteger(0,CHART_SCALE)>3)
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,2);
else
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,1);
}
|