//+------------------------------------------------------------------+
//| DRAW_CANDLES.mq5 |
//| Copyright 2000-2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "DRAW_CANDLES stilini tanıtmak için bir gösterge."
#property description "Seçilen sembolün mumlarını ayrı bir pencerede çizer"
#property description " "
#property description "Çubukların renk ve genişliği ve sembolü, her N tikten sonra"
#property description "rassal olarak değiştirilir"
#property indicator_separate_window
#property indicator_buffers 4
#property indicator_plots 1
//--- plot Bars
#property indicator_label1 "DRAW_CANDLES1"
#property indicator_type1 DRAW_CANDLES
#property indicator_color1 clrGreen
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- giriş parametreleri
input int N=5; // Tipin değişmesi için gereken tik sayısı
input int bars=500; // Gösterilecek çubuk sayısı
input bool messages=false; // "Uzmanlar" günlüğünde mesajları göster
//--- Gösterge tamponları
double Candle1Buffer1[];
double Candle1Buffer2[];
double Candle1Buffer3[];
double Candle1Buffer4[];
//--- Sembol ismi
string symbol;
//--- Renkleri depolayacak bir dizi
color colors[]={clrRed,clrBlue,clrGreen,clrPurple,clrBrown,clrIndianRed};
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- Çubuklar çok küçükse işi planlanandan önce bitir
if(bars<50)
{
Comment("Lütfen daha fazla sayıda çubuk belirtin! Gösterge işlemi sonlandırıldı");
return(INIT_PARAMETERS_INCORRECT);
}
//--- gösterge tamponlarının eşlenmesi
SetIndexBuffer(0,Candle1Buffer1,INDICATOR_DATA);
SetIndexBuffer(1,Candle1Buffer2,INDICATOR_DATA);
SetIndexBuffer(2,Candle1Buffer3,INDICATOR_DATA);
SetIndexBuffer(3,Candle1Buffer4,INDICATOR_DATA);
//--- Bir boş değer
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- Çubukların çizileceği sembolün ismi
symbol=_Symbol;
//--- Sembolün görünümünü ayarla
PlotIndexSetString(0,PLOT_LABEL,symbol+" Open;"+symbol+" High;"+symbol+" Low;"+symbol+" Close");
IndicatorSetString(INDICATOR_SHORTNAME,"DRAW_CANDLES("+symbol+")");
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=INT_MAX-100;
//--- Çizginin stilini,rengini ve genişliğini değiştirmek için tikleri hesapla
ticks++;
//--- Yeterli sayıda tik birikmişse
if(ticks>=N)
{
//--- Piyasa Gözlemi penceresinden yeni bir sembol seç
symbol=GetRandomSymbolName();
//--- Biçimi değiştir
ChangeLineAppearance();
//--- Piyasa Gözlemi penceresinden yeni bir sembol seç
int tries=0;
//--- plot1 tamponlarını sembolün fiyatlarıyla doldurmak için 5 deneme yap
while(!CopyFromSymbolToBuffers(symbol,rates_total,0,
Candle1Buffer1,Candle1Buffer2,Candle1Buffer3,Candle1Buffer4)
&& tries<5)
{
//--- CopyFromSymbolToBuffers() fonksiyonunun çağrıları için bir sayaç
tries++;
}
//--- Tik sayacını sıfırla
ticks=0;
}
//--- bir sonraki çağrı için prev_calculated değerine dönüş yap
return(rates_total);
}
//+------------------------------------------------------------------+
//| Belirtilen mumu doldurur |
//+------------------------------------------------------------------+
bool CopyFromSymbolToBuffers(string name,
int total,
int plot_index,
double &buff1[],
double &buff2[],
double &buff3[],
double &buff4[]
)
{
//--- rates[] dizisinde, Open, High, Low ve Close fiyatlarını kopyalayacağız
MqlRates rates[];
//--- Deneme sayacı
int attempts=0;
//--- Kaç tane kopyalandı
int copied=0;
//--- İstenen sembole dair bir zaman serisi elde etmek için 25 deneme gerçekleştir
while(attempts<25 && (copied=CopyRates(name,_Period,0,bars,rates))<0)
{
Sleep(100);
attempts++;
if(messages) PrintFormat("%s CopyRates(%s) denemeler=%d",__FUNCTION__,name,attempts);
}
//--- Yeterli sayıda çubuk kopyalanamamışsa
if(copied!=bars)
{
//--- Bir mesaj dizgisi oluştur
string comm=StringFormat("%s sembolü için, sadece %d çubuk alınabildi (istenen %d çubuktan)",
name,
copied,
bars
);
//--- Mesajı ana çizelge penceresindeki bir yorumda göster
Comment(comm);
//--- Mesajı göster
if(messages) Print(comm);
return(false);
}
else
{
//--- Sembolün görüntüsünü ayarla
PlotIndexSetString(plot_index,PLOT_LABEL,name+" Open;"+name+" High;"+name+" Low;"+name+" Close");
}
//--- Tamponları boş değerlerle başlat
ArrayInitialize(buff1,0.0);
ArrayInitialize(buff2,0.0);
ArrayInitialize(buff3,0.0);
ArrayInitialize(buff4,0.0);
//--- Her tik ile birlikte fiyatları tamponlara kopyala
for(int i=0;i<copied;i++)
{
//--- Tamponlar için uygun indisleri hesapla
int buffer_index=total-copied+i;
//--- Fiyatları tamponlara yaz
buff1[buffer_index]=rates[i].open;
buff2[buffer_index]=rates[i].high;
buff3[buffer_index]=rates[i].low;
buff4[buffer_index]=rates[i].close;
}
return(true);
}
//+------------------------------------------------------------------+
//| Piyasa Gözleminden rassal bir sembole dönüş yapar |
//+------------------------------------------------------------------+
string GetRandomSymbolName()
{
//--- Piyasa Gözleminde görünen sembollerin sayısı
int symbols=SymbolsTotal(true);
//--- Sembolün listedeki pozisyonu - 0'dan symbols'e kadar rassal bir sayı
int number=MathRand()%symbols;
//--- Belirtilen konumdaki sembolün ismine dönüş yap
return SymbolName(number,true);
}
//+------------------------------------------------------------------+
//| Çubukların görünümünü değiştirir |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- Çubuk özellikleri ile ilgili bilgiyi biçimlendirmek için bir dizgi
string comm="";
//--- Çubukların renklerini değiştirmek için bir blok
int number=MathRand(); // Rassal bir sayı al
//--- Bölen, colors[] dizisinin boyutuna eşit
int size=ArraySize(colors);
//--- Bölümden kalan tam-sayı değeri şeklinde yeni bir renk seçmek için indis değerini al
int color_index=number%size;
//--- Rengi PLOT_LINE_COLOR özelliği şeklinde ayarla
PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- Rengi yaz
comm=comm+"\r\n"+(string)colors[color_index];
//--- Sembol ismini yaz
comm="\r\n"+symbol+comm;
//--- Bir yorum kullanarak çizelge üzerinde bilgi göster
Comment(comm);
}
|
