UT Bot Alerts by QuantNomad MT4

To get access to MT5 version please click here.

• This is the exact conversion from TradingView: "UT Bot Alerts" by "QuantNomad".
• The screenshot shows 95% similar results from tradingview and Metatrader when tested on ICMarkets on both platforms. It should be 100%. However I realized there are small difference between quotes even if brokers are the same. This is strange... I think the indicator logic is very data dependent. I have done quite a lot of conversions from tradingview and do not see anything wrong regarding this indicator... You can trust me. If I find out something I will update and let you know. 
• This is a light-load processing and non-repaint indicator.
• Buffers are available for processing in EAs.
• Candle color option is not available.
• You can message in private chat for further changes you need.

Here is the source code of a simple Expert Advisor operating based on signals from UT Bot Alerts.

#property strict

input string EA_Setting="";
input int magic_number=1234;
input double fixed_lot_size=0.01; // select fixed lot size

input string    UTBOT_Setting="";
input double a = 2; //Key Vaule
input int c = 11; //ATR Period
bool h = false; //Signals from Heikin Ashi Candles

void OnTick()
  {
      if(!isNewBar()) return;
         
      bool buy_condition=true;
      buy_condition &= (BuyCount()==0);
      buy_condition &= (IsUTBOTBuy(1));
      if(buy_condition) 
      {
         CloseSell();
         Buy();
      }
         
      bool sell_condition=true;
      sell_condition &= (SellCount()==0);
      sell_condition &= (IsUTBOTSell(1));
      if(sell_condition) 
      {
         CloseBuy();
         Sell();
      }
  }

bool IsUTBOTBuy(int index)
{
   double value_buy=iCustom(_Symbol, PERIOD_CURRENT,
    "Market\\UT Bot Alerts by QuantNomad MT4",
    a, c, h, 6, index);
   return value_buy!=EMPTY_VALUE;
}

bool IsUTBOTSell(int index)
{
   double value_sell=iCustom(_Symbol, PERIOD_CURRENT,
    "Market\\UT Bot Alerts by QuantNomad MT4",
    a, c, h, 7, index);
   return value_sell!=EMPTY_VALUE;
}

int BuyCount()
{
   int counter=0;
   for(int i=0;i<OrdersTotal();i++)
   {
      if(OrderSelect(i, SELECT_BY_POS)==false) continue;
      if(OrderSymbol()!=_Symbol) continue;
      if(OrderMagicNumber()!=magic_number) continue;
      if(OrderType()==OP_BUY) counter++;
   }
   return counter;
}

int SellCount()
{
   int counter=0;
   for(int i=0;i<OrdersTotal();i++)
   {
      if(OrderSelect(i, SELECT_BY_POS)==false) continue;
      if(OrderSymbol()!=_Symbol) continue;
      if(OrderMagicNumber()!=magic_number) continue;
      if(OrderType()==OP_SELL) counter++;
   }
   return counter;
}

void Buy()
{
   if(OrderSend(_Symbol, OP_BUY, fixed_lot_size, Ask, 3, 0, 0, NULL, magic_number, 0, clrNONE)==-1)
   {
      Print("Error Executing Order: ", GetLastError());
      //ExpertRemove();
   }
}

void Sell()
{
   if(OrderSend(_Symbol, OP_SELL, fixed_lot_size, Bid, 3, 0, 0, NULL, magic_number, 0, clrNONE)==-1)
   {
      Print("Error Executing Order: ", GetLastError());
      //ExpertRemove();
   }
}

void CloseBuy()
{
   for(int i=OrdersTotal()-1;i>=0;i--)
   {
      if(OrderSelect(i, SELECT_BY_POS)==false) continue;
      if(OrderSymbol()!=_Symbol) continue;
      if(OrderMagicNumber()!=magic_number) continue;
      if(OrderType()==OP_BUY) 
         if(OrderClose(OrderTicket(), OrderLots(), Bid, 3, clrNONE)==false)
         {
            Print("Error Closing Position: ", GetLastError());
         }
   }
}

void CloseSell()
{
   for(int i=OrdersTotal()-1;i>=0;i--)
   {
      if(OrderSelect(i, SELECT_BY_POS)==false) continue;
      if(OrderSymbol()!=_Symbol) continue;
      if(OrderMagicNumber()!=magic_number) continue;
      if(OrderType()==OP_SELL) 
         if(OrderClose(OrderTicket(), OrderLots(), Ask, 3, clrNONE)==false)
         {
            Print("Error Closing Position: ", GetLastError());
         }
   }
}

datetime timer=NULL;
bool isNewBar()
{
   datetime candle_start_time= (int)(TimeCurrent()/(PeriodSeconds()))*PeriodSeconds();
   if(timer==NULL) {}
   else if(timer==candle_start_time) return false;
   timer=candle_start_time;
   return true;
}