Ищу индикаторы.

Новый комментарий
 
Кто-нибудь встречал индикаторы Bears Power, Bulls Power с раскраской разным цветом выше нуля и ниже нуля?
 

на фрилансе должен быть - где то там потерял ;-)

 
khorosh:    Кто-нибудь встречал индикаторы Bears Power, Bulls Power с раскраской разным цветом выше нуля и ниже нуля?

   Делается очень просто

Исходный вариант чуть переделал для ясности последующего

//+------------------------------------------------------------------+
//| Предварительный вариант Color Bears Power            Bears_0.mq4 |
//+------------------------------------------------------------------+
#property description "Color Bears Power"
#property strict

#property indicator_separate_window
#property indicator_buffers 2
#property indicator_width2  2

#property indicator_color2 Silver

input int InpBearsPeriod=13; // Bears Period

double Buf_0[];              // Буфер для расчетов
double Buf_1[];              // Буфер гистограммы

//+------------------------------------------------------------------+
//| Инициализация                                                    |
//+------------------------------------------------------------------+
void OnInit(void)
{
   IndicatorDigits(Digits);

   SetIndexBuffer(0,Buf_0);
   SetIndexStyle (0,DRAW_NONE);   // Запрет отображения
   SetIndexLabel (0,NULL);        // Запрет вывода в окно данных

   SetIndexStyle (1,DRAW_HISTOGRAM);
   SetIndexBuffer(1,Buf_1);
   string short_name="Bears_"+IntegerToString(InpBearsPeriod)+" ";
   IndicatorShortName(short_name);
   SetIndexLabel(1,short_name);
}

//+------------------------------------------------------------------+
//| Расчет на каждый тик                                             |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
{
   int limit=rates_total-prev_calculated;
   if(rates_total<=InpBearsPeriod) return(0);
   if(prev_calculated>0)  limit++;

   for(int i=0; i<limit; i++)
   {
      Buf_0[i]=iMA(NULL,0,InpBearsPeriod,0,MODE_EMA,PRICE_CLOSE,i);
      Buf_1[i]=low[i]-Buf_0[i];
   }
   return(rates_total);
}
//+------------------------------------------------------------------+

Внес изменения (кажется в 12 строк): добавил буфер и еще чуть-чуть

//+------------------------------------------------------------------+
//|                                                  Bears_Color.mq4 |
//+------------------------------------------------------------------+
#property description "Color Bears Power"
#property strict

#property indicator_separate_window
#property indicator_buffers 3
#property indicator_width2  2
#property indicator_width3  2

#property indicator_color2 Lime
#property indicator_color3 Red

input int InpBearsPeriod=13;   // Bears Period

double Buf_0[];              // Буфер для расчетов
double Buf_1[];              // Буфер гистограммы
double Buf_2[];              // Буфер гистограммы

//+------------------------------------------------------------------+
//| Инициализация                                                    |
//+------------------------------------------------------------------+
void OnInit(void)
{
   IndicatorDigits(Digits);
   SetIndexBuffer(0,Buf_0);
   SetIndexStyle (0,DRAW_NONE);   // Запрет отображения
   SetIndexLabel (0,NULL);        // Запрет вывода в окно данных

   SetIndexStyle (1,DRAW_HISTOGRAM);
   SetIndexBuffer(1,Buf_1);

   SetIndexStyle (2,DRAW_HISTOGRAM);
   SetIndexBuffer(2,Buf_2);

   string short_name="Bears_"+IntegerToString(InpBearsPeriod)+" ";
   IndicatorShortName(short_name);
   SetIndexLabel(1,short_name+"_up");
   SetIndexLabel(2,short_name+"_dn");
}

//+------------------------------------------------------------------+
//| Расчет на каждый тик                                             |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   int limit=rates_total-prev_calculated;
   if(rates_total<=InpBearsPeriod) return(0);
   if(prev_calculated>0)  limit++;

   for(int i=0; i<limit; i++)
   {
      Buf_1[i]=0;  Buf_2[i]=0;
      Buf_0[i]=iMA(NULL,0,InpBearsPeriod,0,MODE_EMA,PRICE_CLOSE,i);
      double Rezultat=low[i]-Buf_0[i];
      if(Rezultat>0) Buf_1[i]=Rezultat;
      else           Buf_2[i]=Rezultat;
   }
   return(rates_total);
  }
//+------------------------------------------------------------------+
Второй индикатор доработайте по аналогии и покажите результат
 
khorosh:
Кто-нибудь встречал индикаторы Bears Power, Bulls Power с раскраской разным цветом выше нуля и ниже нуля?
Файлы:
Bears_Bulls_Power.mq4  4 kb
 
khorosh:
Кто-нибудь встречал индикаторы Bears Power, Bulls Power с раскраской разным цветом выше нуля и ниже нуля?

Привет, а зачем они вам, просто для удобного созерцания? Ведь практическая польза от них одинаковая.

Вы создавали много тем начиная с очень давних времен, интересно было их просмотреть от прошлого к будущему. И вы знаете, я не понимаю зачем вам в 2017 году могли бы понадобиться беар пауэр и булл пауэр, еще и с цветной раскраской.

 
Stanislav Aksenov:

Привет, а зачем они вам, просто для удобного созерцания? Ведь практическая польза от них одинаковая.

Вы создавали много тем начиная с очень давних времен, интересно было их просмотреть от прошлого к будущему. И вы знаете, я не понимаю зачем вам в 2017 году могли бы понадобиться беар пауэр и булл пауэр, еще и с цветной раскраской.

Польза от раскрашенного даже меньше. У него 2 буфера. Следовательно, программное обращение к нему в 2 раза сложнее

 
STARIJ:

   Делается очень просто

Исходный вариант чуть переделал для ясности последующего

Внес изменения (кажется в 12 строк): добавил буфер и еще чуть-чуть

Второй индикатор доработайте по аналогии и покажите результат
Большое спасибо за ваши труды.
 
poruchik:

SEM:

Большое спасибо.

 
Stanislav Aksenov:

Привет, а зачем они вам, просто для удобного созерцания? Ведь практическая польза от них одинаковая.

Вы создавали много тем начиная с очень давних времен, интересно было их просмотреть от прошлого к будущему. И вы знаете, я не понимаю зачем вам в 2017 году могли бы понадобиться беар пауэр и булл пауэр, еще и с цветной раскраской.

Я иногда пробую создавать ТС с помощью своего советника-полуавтомата и разных индикаторов. Логику ТС, индикаторы и их параметры подбираю в процессе визуального тестирования. А так как зрение у меня плохое, старость не радость), то смену полярности индикаторов мне легче наблюдать, когда меняется цвет. Если полученная в полуавтоматическом режиме ТС показывает положительные результаты, тогда я уже делаю советник-автомат по этой ТС. А на эти индикаторы обратил внимание после того, как встретил в интернете, как они были использованы в качестве фильтров одной из стратегий.
 
khorosh:
Я иногда пробую создавать ТС с помощью своего советника-полуавтомата и разных индикаторов. Логику ТС, индикаторы и их параметры подбираю в процессе визуального тестирования. А так как зрение у меня плохое, старость не радость), то смену полярности индикаторов мне легче наблюдать, когда меняется цвет. Если полученная в полуавтоматическом режиме ТС показывает положительные результаты, тогда я уже делаю советник-автомат по этой ТС. А на эти индикаторы обратил внимание после того, как встретил в интернете, как они были использованы в качестве фильтров одной из стратегий.

Тогда понятно, я то думал что вы молодая девушка, а вы старый дедушка оказывается, тогда понятно все. Просто смутила меня и аватарка с бабочкой, и картинка, понятно все тогда.

12
Новый комментарий