Особенности языка mql5, тонкости и приёмы работы - страница 58

[fxsaber]

В тестере правильно узнать текущее время возможно только через TimeTradeServer(), не TimeCurrent().

[Slava]

fxsaber:
В тестере правильно узнать текущее время возможно только через TimeTradeServer(), не TimeCurrent().

Весьма спорное утверждение.

[fxsaber]

Slava:
Весьма спорное утверждение.

void OnTick()
{
  Print(TimeCurrent());
  
  Sleep(3600 * 1000);
  
  Print(TimeCurrent());
  Print(TimeTradeServer());    
  
  ExpertRemove();
}

Результат

2017.10.02 00:03:03   2017.10.02 00:03:03
2017.10.02 01:03:03   2017.10.02 01:02:59
2017.10.02 01:03:03   2017.10.02 01:03:03

TimeCurrent возвращает время последнего тика основного символа, не тестера (сервера). Узнать же точное текущее время сервера в миллисекундах не представляется возможным.

[gastinets]

добрый день . прочитал про служебные массивы https://www.mql5.com/ru/docs/constants/objectconstants/enum_anchorpoint ( в последнем примере )

double Ups[],Downs[];
   datetime Time[];

есть где-то перечень всех служебных массивов?

[Artyom Trishkin]

i have been following this signal one more week i will follow

and then lets see

en/signals/352123

[fxsaber]

Языковой прием, который позволяет использовать protected-методы/поля.

Пример

#include <Canvas\Canvas.mqh>

// Помещает картинку в ресурс
bool ToResource( const string Name, const uint &Data[], const uint Width )
{
  return(::ResourceCreate(Name, Data, Width, (Width == 0) ? ::ArraySize(Data) : ::ArraySize(Data) / Width, 0, 0, Width, ::COLOR_FORMAT_ARGB_NORMALIZE));
}

// Прием использования protected полей/методов
class CANVAS : public CCanvas
{
public:
  // Загрузка картинки из BMP-файла
  static bool BMPToArray( const string FileName, uint &Data[], int &Width )
  {
    CANVAS Canvas;
    
    const bool Res = Canvas.LoadFromFile(FileName);
    
    if (Res)
    {
      ArrayCopy(Data, Canvas.m_pixels);
      
      Width = Canvas.m_width;
    }
    
    return(Res);
  }
};

// Грузим BMP с альфаканалом не из ресурса, а из файла
void OnStart()
{     
  const string Resource = "::Resource";
         
  uint Data[], Width;   
  
  if (CANVAS::BMPToArray("Picture.bmp", Data, Width) &&
      ToResource(Resource, Data, Width))
  {
   ObjectCreate(0, __FILE__, OBJ_BITMAP_LABEL, 0, 0, 0);   
   ObjectSetString(0, __FILE__, OBJPROP_BMPFILE, Resource);
        
   // Сконвертировали BMP в PNG (без учета прозрачности)
   BitmapObjectToFile(0, __FILE__, "Picture.png"); // https://www.mql5.com/ru/forum/170952/page57#comment_5985505
  }
}

[Artyom Trishkin]

Комментарии, не относящиеся к этой теме, были перенесены в "Любые вопросы новичков по MQL4, помощь и обсуждение по алгоритмам и кодам".

[fxsaber]

Из-за такой особенности

типизация параметров шаблона строгая, специализировать с неявным приведением недопустимо

можно добиться написания функций, которые во входных параметрах принимают указатели только базового класса, а потомков отшивают на этапе компиляции.

Пример

template <typename T>
void StrongCondition( T, T ) {}

class A
{
public:
  int i;
  
  template <typename T>  
  void SetStong( T Value )
  {
    StrongCondition(&this, Value);
    
    this.i = Value.i;
  }
  
  void Set( A* Value )
  {
    this.i = Value.i;
  }
};

class B : public A {};

void OnStart()
{
  A a;
  B b;
  
  a.Set(&b);   
  a.SetStong(&a);
  
  a.SetStong(&b);       // потомки в явном виде запрещены
  a.SetStong((A*)(&b)); // только явное приведение разрешено
}

[fxsaber]

Можно ли поменять поля const-объекта класса или вызвать его не const-методы? -Можно!

template <typename T>
T GetMe( const T Ptr )
{
  return((T)Ptr);
}

class A
{
public:  
  int i;
};

void OnStart()
{
  const A a;

  GetMe(&a).i = 1;
  
  Print(a.i); // 1
}

Самому не нравится такая фишка. Думал, что застрахован от несанкционированного доступа. Облом, однако! С const-структурами такое, конечно, не прокатывает. Так что имейте в виду эту лазейку.

[A100]