Используйте язык MQL4 для расстановки графиков в определенной последовательности - MQL4 и MetaTrader 4

Alexey Viktorov 2017.03.04 07:51 #1371

missha689:
Подскажите как программно узнать дату и время вчерашнего дня

Так ведь там-же есть всё что нужно, только читай. Например вот это

iTime("USDCHF",PERIOD_H1,0)

только замени конкретно указанный символ на _Symbol, PERIOD_H1 на PERIOD_D1 и вот тебе время открытия дня. Замени 0 на 1 будет время открытия вчерашнего дня.

‌

iTime Bars iBarShift

Maxim Kuznetsov 2017.03.04 08:45 #1372

missha689:
Подскажите как программно узнать дату и время вчерашнего дня

‌календарный вчерашний день:

datetime tim=TimeCurrent()‌-24*60*60;

MqlDateTime ts;

TimeToStruct(tim,ts);

ts.hour=0;ts.min=0;ts.sec=0;

tim=StructToTime(ts);

теперь в tim - начало вчерашнего календарного дня (!! не время открытия пред. бара D1)
‌

Время открытия пред.бара D1 - iTime(0,PERIOD_D1,1); с мелким фиксом - если получается субота то добавить 24 часа‌, если воскр. то 48 часов.

‌

Как получить iLow и Вопросы от начинающих MQL5 Как узнать, что по

missha689 2017.03.04 09:28 #1373

Alexey Viktorov:

Так ведь там-же есть всё что нужно, только читай. Например вот это

iTime("USDCHF",PERIOD_H1,0)

только замени конкретно указанный символ на _Symbol, PERIOD_H1 на PERIOD_D1 и вот тебе время открытия дня. Замени 0 на 1 будет время открытия вчерашнего дня.

‌

я уже пытаюсь сообразить со вчерашнего дня как это сделать но никак не получается поэтому и прошу помочь так как я новичек в этом деле.

Помогите пожалуйста найти индекс бара вчерашнего дня допустим в 15:00 ‌ и индекс сегодняшнего бара допустим в 7:00 только без явного указания даты как было показано в примере

Любой вопрос новичка, чтоб Иметь цену открытия свечи Открытие ордера на той

missha689 2017.03.04 09:57 #1374

Maxim Kuznetsov:

‌календарный вчерашний день:

datetime tim=TimeCurrent()‌-24*60*60;

MqlDateTime ts;

TimeToStruct(tim,ts);

ts.hour=0;ts.min=0;ts.sec=0;

tim=StructToTime(ts);

теперь в tim - начало вчерашнего календарного дня (!! не время открытия пред. бара D1)
‌

Время открытия пред.бара D1 - iTime(0,PERIOD_D1,1); с мелким фиксом - если получается субота то добавить 24 часа‌, если воскр. то 48 часов.

‌

Спасибо

FOTOGRAF14 2017.03.04 14:33 #1375

Sergey Gritsay:

функция перевода стполосса в безубыток, в функцию передается тикет ордера и расстояние в пипсах через которое переводить

void zero_profit(int ticket, int distance)
  {
   double sl=0.0;

   if(OrderSelect(ticket,SELECT_BY_TICKET))
     {
      if(OrderType()==OP_BUY)
        {
         if(Bid>=OrderOpenPrice() && Bid-OrderOpenPrice()>=distance*_Point) sl=OrderOpenPrice();
         if(OrderStopLoss()!=0 && OrderStopLoss()>=OrderOpenPrice())return;
        }
      if(OrderType()==OP_SELL)
        {
         if(Ask<=OrderOpenPrice() && OrderOpenPrice()-Ask>=distance*_Point) sl=OrderOpenPrice();
         if(OrderStopLoss()!=0 && OrderStopLoss()<=OrderOpenPrice())return;
        }
      ResetLastError();

      if(sl<=0)return;
      if(!OrderModify(OrderTicket(),OrderOpenPrice(),sl,OrderTakeProfit(),0))
        {
         int error=GetLastError();
         rezult=StringConcatenate(OrderSymbol(),": error modifying StopLoss order ",OrderTicket()," ",TypeToStr(OrderType())," №- ",error);
         Print(rezult);
        }

     }
  }

‌...спасибо Сергей!!!!!

Artyom Trishkin 2017.03.04 19:09 #1376

Vitaly Muzichenko:

Прикольно, попробую выдернуть функции в советник. Позже напишу результат.

С‌пасибо!!!

Добавил второй метод поиска.

//+------------------------------------------------------------------+
//|                                             iFreeNumFractals.mq4 |
//|              Copyright 2017, Artem A. Trishkin, Skype artmedia70 |
//|                       https://login.mql5.com/ru/users/artmedia70 |
//+------------------------------------------------------------------+
#property copyright "Copyright 2017, Artem A. Trishkin, Skype artmedia70"
#property link      "https://login.mql5.com/ru/users/artmedia70"
#property version   "3.00"
#property strict
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   2
//--- plot UpperFractal
#property indicator_label1  "Upper Fractal"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- plot LowerFractal
#property indicator_label2  "Lower Fractal"
#property indicator_type2   DRAW_ARROW
#property indicator_color2  clrSteelBlue
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//---
enum ENUM_TYPE_FRACTAL
  {
   TYPE_FRACTAL_ACCURATE   =  0,    // Accurate fractal
   TYPE_FRACTAL_INACCURATE =  1,    // Inaccurate fractal
  };
//--- input parameters
input ENUM_TYPE_FRACTAL TypeFractals   =  TYPE_FRACTAL_ACCURATE;  // Type of fractal
input int               LeftNumUp      =  2;                      // The number of bars on the left for upper fractals
int leftNumUp;    // Количество баров слева для верхнего фрактала
input int               RightNumUp     =  2;                      // The number of bars on the right for upper fractals
int rightNumUp;   // Количество баров справа для верхнего фрактала
input int               LeftNumDn      =  2;                      // The number of bars on the left for lower fractals
int leftNumDn;    // Количество баров слева для нижнего фрактала
input int               RightNumDn     =  2;                      // The number of bars on the right for lower fractals
int rightNumDn;   // Количество баров справа для нижнего фрактала
//--- indicator buffers
double         BufferUpperFractal[];
double         BufferLowerFractal[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,BufferUpperFractal);
   SetIndexBuffer(1,BufferLowerFractal);
//--- setting a code from the Wingdings charset as the property of PLOT_ARROW
   PlotIndexSetInteger(0,PLOT_ARROW,217);
   PlotIndexSetInteger(1,PLOT_ARROW,218);
   SetIndexArrow(0,217);
   SetIndexArrow(1,218);
   SetIndexEmptyValue(0,EMPTY_VALUE);
   SetIndexEmptyValue(1,EMPTY_VALUE);
//---
   leftNumUp=(LeftNumUp<1?1:LeftNumUp);
   rightNumUp=(RightNumUp<1?1:RightNumUp);
   leftNumDn=(LeftNumDn<1?1:LeftNumDn);
   rightNumDn=(RightNumDn<1?1:RightNumDn);
   string short_name=MQLInfoString(MQL_PROGRAM_NAME)+"("+(string)leftNumUp+","+(string)rightNumUp+")("+(string)leftNumDn+","+(string)rightNumDn+")";
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
   IndicatorSetInteger(INDICATOR_DIGITS,Digits());
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   if(rates_total<fmax(leftNumUp+rightNumUp,leftNumDn+rightNumDn)) return(0);
   int limit=rates_total-prev_calculated;
   if(limit>0) {
      ArrayInitialize(BufferUpperFractal,0.0);
      ArrayInitialize(BufferUpperFractal,0.0);
      limit=rates_total-fmax(leftNumUp,leftNumDn)-1;
      }
   //---
   for(int i=limit; i>fmin(rightNumUp,rightNumDn); i--) {
      if(GetFreeUpperFractal(Symbol(),PERIOD_CURRENT,i,leftNumUp,rightNumUp)>0) BufferUpperFractal[i]=high[i];
      if(GetFreeLowerFractal(Symbol(),PERIOD_CURRENT,i,leftNumDn,rightNumDn)>0) BufferLowerFractal[i]=low[i];
      }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+----------------------------------------------------------------------------+
double GetFreeLowerFractal(const string symbol_name,ENUM_TIMEFRAMES timeframe,int shift,int left_dimension=2,int right_dimension=2) {
   int bars=Bars(symbol_name,timeframe);
   if(left_dimension<1)  left_dimension=1;
   if(right_dimension<1) right_dimension=1;
   if(shift-right_dimension<1 || shift+left_dimension>bars-1) return(-1);
   if(TypeFractals==TYPE_FRACTAL_ACCURATE) {
      for(int i=shift-1; i>=shift-right_dimension; i--) if(GetPriceLow(symbol_name,timeframe,i)<GetPriceLow(symbol_name,timeframe,i+1)) return(-1);
      for(int i=shift+1; i<=shift+left_dimension; i++)  if(GetPriceLow(symbol_name,timeframe,i)<GetPriceLow(symbol_name,timeframe,i-1)) return(-1);
      }
   else {
      for(int i=shift-1; i>=shift-right_dimension; i--) if(GetPriceLow(symbol_name,timeframe,i)<GetPriceLow(symbol_name,timeframe,shift)) return(-1);
      for(int i=shift+1; i<=shift+left_dimension; i++)  if(GetPriceLow(symbol_name,timeframe,i)<GetPriceLow(symbol_name,timeframe,shift)) return(-1);
      }
   return(GetPriceLow(symbol_name,timeframe,shift));
}
//+----------------------------------------------------------------------------+
double GetFreeUpperFractal(const string symbol_name,ENUM_TIMEFRAMES timeframe,int shift,int left_dimension=2,int right_dimension=2) {
   int bars=Bars(symbol_name,timeframe);
   if(left_dimension<1)  left_dimension=1;
   if(right_dimension<1) right_dimension=1;
   if(shift-right_dimension<1 || shift+left_dimension>bars-1) return(-1);
   if(TypeFractals==TYPE_FRACTAL_ACCURATE) {
      for(int i=shift-1; i>=shift-right_dimension; i--) if(GetPriceHigh(symbol_name,timeframe,i)>GetPriceHigh(symbol_name,timeframe,i+1)) return(-1);
      for(int i=shift+1; i<=shift+left_dimension; i++)  if(GetPriceHigh(symbol_name,timeframe,i)>GetPriceHigh(symbol_name,timeframe,i-1)) return(-1);
      }
   else {
      for(int i=shift-1; i>=shift-right_dimension; i--) if(GetPriceHigh(symbol_name,timeframe,i)>GetPriceHigh(symbol_name,timeframe,shift)) return(-1);
      for(int i=shift+1; i<=shift+left_dimension; i++)  if(GetPriceHigh(symbol_name,timeframe,i)>GetPriceHigh(symbol_name,timeframe,shift)) return(-1);
      }
   return(GetPriceHigh(symbol_name,timeframe,shift));
}
//+----------------------------------------------------------------------------+
double GetPriceHigh(const string symbol_name, ENUM_TIMEFRAMES timeframe, int shift){
   double array[1];
   if(CopyHigh(symbol_name,timeframe,shift,1,array)==1) return(array[0]);
   return(-1);
}
//+----------------------------------------------------------------------------+
double GetPriceLow(const string symbol_name, ENUM_TIMEFRAMES timeframe, int shift){
   double array[1];
   if(CopyLow(symbol_name,timeframe,shift,1,array)==1) return(array[0]);
   return(-1);
}
//+----------------------------------------------------------------------------+

‌

Файлы:

iFreeNumFractals.mq4 15 kb

Вопросы от начинающих MQL5 Переделать Fractals.mq5 Как сместить МА по

Vitaly Muzichenko 2017.03.04 19:53 #1377

Artyom Trishkin:

Добавил второй метод поиска.

Спасибо, просто всё супер.

О‌сталось загрузить в кодобазу)

Artyom Trishkin 2017.03.04 20:27 #1378

Vitaly Muzichenko:

Спасибо, просто всё супер.

О‌сталось загрузить в кодобазу)

Уже :)) Отправил на проверку.

DVlad 2017.03.05 05:31 #1379

‌

Здравствуйте.

‌Я на Линуксе. В МТ4 открыты несколько валютных пар - до 10. Как можно с помощью языка MQL4 расставить вкладки графиков в определённой последовательности?

Работа с профилями, изучение 1_MQL4.pdf, просторов интернета ничего не дало.‌

С уважением, Владимир‌

Помощь по MQL4 Установка индикаторов на график MQL не позволяет работать

Artyom Trishkin 2017.03.05 06:15 #1380

DVlad:

‌

Здравствуйте.

‌Я на Линуксе. В МТ4 открыты несколько валютных пар - до 10. Как можно с помощью языка MQL4 расставить вкладки графиков в определённой последовательности?

Работа с профилями, изучение 1_MQL4.pdf, просторов интернета ничего не дало.‌

С уважением, Владимир‌

Даже на Windows средствами mql4 нельзя вкладки сортировать.

Можно лишь открыть графики в нужной вам последовательности и установить на них нужные шаблоны.‌

Любые вопросы новичков по MQL4 и MQL5, помощь и обсуждение по алгоритмам и кодам - страница 138