HistoryOrderGetString

string  HistoryOrderGetString(
   ulong                       ticket_number,     // тикет
   ENUM_ORDER_PROPERTY_STRING  property_id        // идентификатор свойства
   );

bool  HistoryOrderGetString(
   ulong                       ticket_number,     // тикет
   ENUM_ORDER_PROPERTY_STRING  property_id,       // идентификатор свойства
   string&                     string_var         // сюда примем значение свойства
   );

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- запрашиваем историю сделок и ордеров
   if(!HistorySelect(0, TimeCurrent()))
     {
      Print("HistorySelect() failed. Error ", GetLastError());
      return;
     }
     
//--- в цикле по списку всех исторических ордеров на счёте
   int total=HistoryOrdersTotal();
   for(int i=0; i<total; i++)
     {
      //--- получаем тикет ордера в списке по индексу цикла
      ulong ticket=HistoryOrderGetTicket(i);
      if(ticket==0)
         continue;
      
      //--- получаем тип ордера и выводим заголовок для списка строковых свойств выбранного ордера
      string type=OrderTypeDescription((ENUM_ORDER_TYPE)HistoryOrderGetInteger(ticket, ORDER_TYPE));
      PrintFormat("String properties of an history order %s #%I64u:", type, ticket);
      
      //--- распечатываем под заголовком все строковые свойства выбранного ордера
      HistoryOrderPropertiesStringPrint(ticket, 16);
     }
   /*
   результат:
   String properties of an history order Buy #2646074112:
   Comment:        [tp 1.09137]
   Symbol:         EURUSD
   External ID:    
   String properties of an history order Buy #2646131906:
   Comment:        
   Symbol:         EURUSD
   External ID:    
   */
  }
//+------------------------------------------------------------------+
//| Выводит в журнал строковые свойства                              |
//| выбранного исторического ордера                                  |
//+------------------------------------------------------------------+
void HistoryOrderPropertiesStringPrint(const long ticket, const uint header_width=0)
  {
   uint   w=0;
   string header="";
   string value="";
   
//--- определяем текст заголовка и ширину поля заголовка
//--- если ширина заголовка передана в функцию равной нулю, то шириной будет размер строки заголовка + 1
   header="Comment:";
   w=(header_width==0 ? header.Length()+1 : header_width);
//--- получаем и выводим в журнал комментарий с заголовком установленной ширины
   if(!HistoryOrderGetString(ticket, ORDER_COMMENT, value))
      return;
   PrintFormat("%-*s%-s", w, header, value);
   
//--- выводим в журнал символ, по которому выставлен ордер
   header="Symbol:";
   w=(header_width==0 ? header.Length()+1 : header_width);
   if(!HistoryOrderGetString(ticket, ORDER_SYMBOL, value))
      return;
   PrintFormat("%-*s%-s", w, header, value);
   
//--- выводим в журнал идентификатор ордера во внешней системе 
   header="External ID:";
   w=(header_width==0 ? header.Length()+1 : header_width);
   if(!HistoryOrderGetString(ticket, ORDER_EXTERNAL_ID, value))
      return;
   PrintFormat("%-*s%-s", w, header, value);
  }
//+------------------------------------------------------------------+
//| Возвращает описание типа ордера                                  |
//+------------------------------------------------------------------+
string OrderTypeDescription(const ENUM_ORDER_TYPE type)
  {
   switch(type)
     {
      case ORDER_TYPE_BUY              :  return("Buy");
      case ORDER_TYPE_SELL             :  return("Sell");
      case ORDER_TYPE_BUY_LIMIT        :  return("Buy Limit");
      case ORDER_TYPE_SELL_LIMIT       :  return("Sell Limit");
      case ORDER_TYPE_BUY_STOP         :  return("Buy Stop");
      case ORDER_TYPE_SELL_STOP        :  return("Sell Stop");
      case ORDER_TYPE_BUY_STOP_LIMIT   :  return("Buy Stop Limit");
      case ORDER_TYPE_SELL_STOP_LIMIT  :  return("Sell Stop Limit");
      default                          :  return("Unknown order type: "+(string)type);
     }
  }