ДокументацияРазделы
Справочник MQL5Операции с графикамиChartIndicatorsTotal 

ChartIndicatorsTotal

Возвращает количество всех индикаторов, присоединенных к указанному окну графика.

int  ChartIndicatorsTotal(
   long  chart_id,      // идентификатор графика
   int   sub_window     // номер подокна
   );

Параметры

chart_id

[in]  Идентификатор графика. 0 означает текущий график.

sub_window

[in]  Номер подокна графика. 0 означает главное окно графика.

Возвращаемое значение

Количество индикаторов на указанном окне графика. Чтобы получить информацию об ошибке, необходимо вызвать функцию GetLastError().

Примечание

Функция предназначена для организации перебора всех индикаторов, присоединенных к данному графику. Количества всех окон графика можно получить из свойства CHART_WINDOWS_TOTAL функцией ChartGetInteger().

Пример:

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- получаем идентификатор текущего графика и количество его подокон, включая главное окно
   long chart_id = ChartID();
   int  wnd_total= (int)ChartGetInteger(0,CHART_WINDOWS_TOTAL);
   
//--- пройдём в цикле по всем окнам текущего графика
   for(int w=0; w<wnd_total; w++)
     {
      //--- получим количество индикаторов, присоединенных к указанному индексом цикла окну графика
      int ind_total=ChartIndicatorsTotal(chart_id, w);
      
      //--- распечатаем количество индикаторов, присоединенных к указанному окну графика
      PrintFormat("Chart ID %I64d, subwindow %d. Attached indicators: %d", chart_id, w, ind_total);
     }
   /*
   результат:
   Chart ID 133246248352168439, subwindow 0. Attached indicators: 3
   Chart ID 133246248352168439, subwindow 1. Attached indicators: 2
   Chart ID 133246248352168439, subwindow 2. Attached indicators: 1
   */
  }

Смотри также

ChartIndicatorAdd(), ChartIndicatorDelete(), iCustom(), IndicatorCreate(), IndicatorSetString()