Nadaraya Watson Envelope LuxAlgo MT4

To get access to MT5 version click here.

• This is the exact conversion from "Nadaraya-Watson Envelope" by "LuxAlgo". (with non-repaint input option)
• This is not a light-load processing indicator if repaint input is set to true.
• All input options are available. 
• Buffers are available for processing in EAs.
• I changed default input setup to non-repaint mode for better performance required for mql market validation procedure.

#property strict

input string EA_Setting="";
input int magic_number=1234;
input double fixed_lot_size=0.01; // select fixed lot size
input bool multiplie_entry=false; //allow multiple entries in the same direction

input string    NW_Setting="";
input double h = 8.;//Bandwidth
input double mult = 3; //
input ENUM_APPLIED_PRICE src = PRICE_CLOSE; //Source
input bool repaint = false; //Repainting Smoothing

void OnTick()
  {
      if(!isNewBar()) return;
         
      bool buy_condition=true;
      if(!multiplie_entry) buy_condition &= (BuyCount()==0);
      buy_condition &= (IsNWBuy(1));
      if(buy_condition) 
      {
         CloseSell();
         Buy();
      }
         
      bool sell_condition=true;
      if(!multiplie_entry) sell_condition &= (SellCount()==0);
      sell_condition &= (IsNWSell(1));
      if(sell_condition) 
      {
         CloseBuy();
         Sell();
      }
  }

bool IsNWBuy(int index)
{
   double value_buy=iCustom(_Symbol, PERIOD_CURRENT,
    "Market/Nadaraya Watson Envelope LuxAlgo MT4",
    h, mult, src, repaint, 5, index);
   return value_buy!=EMPTY_VALUE;
}

bool IsNWSell(int index)
{
   double value_sell=iCustom(_Symbol, PERIOD_CURRENT,
    "Market/Nadaraya Watson Envelope LuxAlgo MT4",
    h, mult, src, repaint, 6, index);
   return value_sell!=EMPTY_VALUE;
}

int BuyCount()
{
   int counter=0;
   for(int i=0;i<OrdersTotal();i++)
   {
      if(OrderSelect(i, SELECT_BY_POS)==false) continue;
      if(OrderSymbol()!=_Symbol) continue;
      if(OrderMagicNumber()!=magic_number) continue;
      if(OrderType()==OP_BUY) counter++;
   }
   return counter;
}

int SellCount()
{
   int counter=0;
   for(int i=0;i<OrdersTotal();i++)
   {
      if(OrderSelect(i, SELECT_BY_POS)==false) continue;
      if(OrderSymbol()!=_Symbol) continue;
      if(OrderMagicNumber()!=magic_number) continue;
      if(OrderType()==OP_SELL) counter++;
   }
   return counter;
}

void Buy()
{
   if(OrderSend(_Symbol, OP_BUY, fixed_lot_size, Ask, 3, 0, 0, NULL, magic_number, 0, clrNONE)==-1)
   {
      Print("Error Executing Order: ", GetLastError());
      //ExpertRemove();
   }
}

void Sell()
{
   if(OrderSend(_Symbol, OP_SELL, fixed_lot_size, Bid, 3, 0, 0, NULL, magic_number, 0, clrNONE)==-1)
   {
      Print("Error Executing Order: ", GetLastError());
      //ExpertRemove();
   }
}

void CloseBuy()
{
   for(int i=OrdersTotal()-1;i>=0;i--)
   {
      if(OrderSelect(i, SELECT_BY_POS)==false) continue;
      if(OrderSymbol()!=_Symbol) continue;
      if(OrderMagicNumber()!=magic_number) continue;
      if(OrderType()==OP_BUY) 
         if(OrderClose(OrderTicket(), OrderLots(), Bid, 3, clrNONE)==false)
         {
            Print("Error Closing Position: ", GetLastError());
         }
   }
}

void CloseSell()
{
   for(int i=OrdersTotal()-1;i>=0;i--)
   {
      if(OrderSelect(i, SELECT_BY_POS)==false) continue;
      if(OrderSymbol()!=_Symbol) continue;
      if(OrderMagicNumber()!=magic_number) continue;
      if(OrderType()==OP_SELL) 
         if(OrderClose(OrderTicket(), OrderLots(), Ask, 3, clrNONE)==false)
         {
            Print("Error Closing Position: ", GetLastError());
         }
   }
}

datetime timer=NULL;
bool isNewBar()
{
   datetime candle_start_time= (int)(TimeCurrent()/(PeriodSeconds()))*PeriodSeconds();
   if(timer==NULL) {}
   else if(timer==candle_start_time) return false;
   timer=candle_start_time;
   return true;
}