Procurando por padrões - página 185

Novo comentário
 
Serqey Nikitin:
Antes de objetar, é aconselhável observar e avaliar ISTO...

Si Chas.

 
Serqey Nikitin:
Antes de objetar, é aconselhável ver e avaliar ISTO...
Por que é mais fácil esculpir durante anos, o que quer que lhe venha à cabeça e está bem
 

E algumas pessoas não têm nada a moldar aqui. Há um vazio na cabeça deles.

Tudo o que resta é se atirar a todos.

 
Алексей Тарабанов:

Então, vamos começar a falar sobre a tendência. Uma tendência é uma tendência em preço. Ao contrário de um apartamento, ele é unidirecional. Portanto, acho que devemos começar com o fato de que não há tendência, o mercado está sempre oscilando.

Então do que estamos falando? Estamos falando de partes de movimento unidirecional em um gráfico oscilante. Se o gráfico for uma onda sinusoidal (o sonho de um operador de rádio), o movimento unidirecional será exatamente dentro de um meio período. O período é medido no tempo. Mais uma vez, iPulsar novamente? Sim, exatamente.

Quando faço a pergunta: qual é a tendência (para onde estamos indo), devo primeiro responder à pergunta: em que horizonte? As tendências vêm de hora em hora, diariamente, semanalmente, anualmente; todos os tipos (não confundir com prazos, que também vêm em todos os tipos). Falando de prazos: é fácil identificar a tendência anual em minutos, mas impossível identificar a tendência diária em semanas. Kotelnikov o provou.

Conclusão: Eu primeiro determino o intervalo comercial (intraday, semana, ...). Depois disso, percebo a tendência neste intervalo, e depois tento fazer o meu melhor. Isso é tudo por enquanto.

Estou muito feliz que haja uma discussão. Estou feliz que tanto aqueles que concordam como aqueles que discordam de mim tenham participado dela. Vamos tentar continuar.

No inverno de 95/96, fui apresentado pela primeira vez ao Forex. Eu me recusei a participar deste esquema porque não entendia quais eram minhas vantagens, como eu era melhor do que os outros e o que me permitia fazer meu próprio dinheiro.

Hoje eu compartilho o que entendo. Mesmo que todos os membros deste e de outros fóruns se apressem a negociar em um sistema muito bom, o mercado não o sentirá.

Vamos voltar às tendências.

Antes de comercializar ao longo da tendência, vale a pena verificar se vale a pena. Um ziguezague ajudará a avaliá-lo. Vamos tentar construir um ziguezague para uma tendência mensal, semanal, ou diária. Exatamente para a tendência, não para alguns parâmetros técnicos. Para isso, usaremos a mesma curva fractal - 119 barras à esquerda e 1 barra à direita. 119 porque há 120 horas por semana e os comerciantes são pagos uma vez por semana. Aqui está o resultado:


Era uma tendência semanal e uma foto da minha neta que eu nunca consegui apagar. Acrescentado acidentalmente. Experimente você mesmo as outras tendências, eu vou me afastar por alguns dias.

Aqui está o código:

/* Indicador de ziguezague dos fractais - o indicador constrói um ziguezague sobre os fractais

com tamanhos arbitrários de asas direita e esquerda. */

#property strict
#property copyright "Copyright 2012, Тарабанов А.В."
#property link      "alextar@bk.ru"
#property indicator_chart_window                   // Индикатор в главном окне
// Индикаторные буферы
#property indicator_buffers 4
#property indicator_width1 2                       // Толщина зигзага
#property indicator_color1 Blue                    // Цвет зигзага
#property indicator_color3 Green                   // Нижние вершины
#property indicator_width3 1
#property indicator_color4 Red                     // Верхние вершины
#property indicator_width4 1
double Min[]   , Max[],                            // Изломы зигзага
       Bottom[], Top[];                            // Вершины
// Константы
#define  Version "iSFZZ"                            // Версия
#define  Zero    0.00000001                         // Точность определения нуля
// Глобальные переменные
double      LastBottom , LastTop;                  // Предыдущие значения
int         iLastBottom, iLastTop;                 //    и их бары
datetime    tLastBottom, tLastTop;                 // Время предыдущих значений
bool        LastIsTop  , LastIsBottom;             // Предыдущий пик/впадина
extern bool ОтображатьВершины   =true;
extern int  БаровЛевееВершины   =119,
            БаровПравееВершины  =1,
            СимволНижнейВершины =161,
            СимволВерхнейВершины=161;
//+------------------------------------------------------------------+
int init(){
   int DrawFractals=DRAW_NONE;
   if( ОтображатьВершины ) DrawFractals=DRAW_ARROW;
   // Атрибуты буферов
   SetIndexLabel(0,"Max");
   SetIndexBuffer(0,Max);
   SetIndexStyle(0,DRAW_ZIGZAG);
   SetIndexEmptyValue(0,0);
   SetIndexLabel(1,"Min");
   SetIndexBuffer(1,Min);
   SetIndexStyle(1,DRAW_ZIGZAG);
   SetIndexEmptyValue(1,0);
   SetIndexLabel(2,"Bottom");
   SetIndexBuffer(2,Bottom);
   SetIndexStyle(2,DrawFractals);
   SetIndexArrow(2,СимволНижнейВершины);
   SetIndexEmptyValue(2,0);
   SetIndexLabel(3,"Top");
   SetIndexBuffer(3,Top);
   SetIndexStyle(3,DrawFractals);
   SetIndexArrow(3,СимволВерхнейВершины);
   SetIndexEmptyValue(3,0);
   if( БаровЛевееВершины <1 ) БаровЛевееВершины=1; // Контроль значений
   if( БаровПравееВершины <1 ) БаровПравееВершины=1;
   LastBottom  =0;                                 // Инициализация
   LastTop     =0;
   iLastBottom =0;
   iLastTop    =0;
   tLastBottom =0;
   tLastTop    =0;
   LastIsTop   =false;
   LastIsBottom=false;
   return(0);
}
//+------------------------------------------------------------------+
int start(){
   int i, History=Bars-1, BarsLost=History-IndicatorCounted();
   if( BarsLost<History ){
      if( BarsLost<1 ) return(0);                  // Не повторять на том-же баре
      i=BarsLost+БаровПравееВершины;               // Число баров пересчета
   }
   else i=History-БаровЛевееВершины;               // Просмотр на всей истории
   double C[];
   int dim=ArrayResize(C,БаровЛевееВершины+1+БаровПравееВершины), j;
   if( tLastTop>0 ) iLastTop=iBarShift(NULL,0,tLastTop);
   if( tLastBottom>0 ) iLastBottom=iBarShift(NULL,0,tLastBottom);
   while( i>БаровПравееВершины ){                  // Перебор слева направо
      j=0;                                         // Поиск нижнего фрактала
      Bottom[i]=0;
      while( j < dim ){
         C[j]=Low[j+i-БаровПравееВершины];
         j++;
      }
      if( C[БаровПравееВершины+1]-C[БаровПравееВершины]>-Zero
       && C[БаровПравееВершины-1]-C[БаровПравееВершины]>-Zero ){
         Bottom[i]=C[БаровПравееВершины];          // Локальный минимум
         j=1;
         while ( j < dim ){
            if( ( j<БаровПравееВершины && Bottom[i]-C[j-1]>Zero )
             || ( j>БаровПравееВершины && Bottom[i]-C[j]  >Zero ) ) {
               Bottom[i]=0;                        // Нет фрактала
               break;
            }
            j++;
      }  }
      j=0;             // Поиск верхнего фрактала
      Top[i]=0;
      while( j<dim ){
         C[j]=High[j+i-БаровПравееВершины];
         j++;
      }
      if( C[БаровПравееВершины]-C[БаровПравееВершины+1]>-Zero
       && C[БаровПравееВершины]-C[БаровПравееВершины-1]>-Zero ){
         Top[i]=C[БаровПравееВершины];             // Локальный максимум
         j=1;
         while ( j < dim ){
            if( ( j<БаровПравееВершины && C[j-1]-Top[i]>Zero )
             || ( j>БаровПравееВершины && C[j]  -Top[i]>Zero ) ) {
               Top[i]=0;                           // Нет фрактала
               break;
            }
            j++;
      }  }
      if( Top[i]>Zero ){                           // Выбор вершины зигзага
         if( Bottom[i]>Zero ){                     // Top и Bottom
            if( LastIsTop || LastIsBottom ){       // Не начало зигзага
               Min[i]     =Bottom[i];              // Вертикальное колено
               Max[i]     =Top[i];
               LastBottom =Bottom[i];              // Запомнить Top и Bottom
               iLastBottom=i;
               LastTop    =Top[i];
               iLastTop   =i;
         }  }
         else{                                     // Top
            if( !LastIsTop ){                      // LastIsBottom, или
               Max[i]      =Top[i];                //    начало зигзага
               LastIsTop   =true;
               LastIsBottom=false; 
               LastTop     =Top[i];                // Запомнить Top
               iLastTop    =i;
            }
            else{                                  // LastIsTop
               if( Top[i]-LastTop>-Zero ){         // Перерисовка
                  Max[iLastTop]=0;
                  Max[i]       =Top[i];
                  LastTop      =Top[i];            // Запомнить Top
                  iLastTop     =i;
      }  }  }  }
      else{
         if( Bottom[i]>Zero ){                     // Bottom
            if( !LastIsBottom ){                   // LastIsTop, или
               Min[i]      =Bottom[i];             //    начало зигзага
               LastIsTop   =false;
               LastIsBottom=true; 
               LastBottom  =Bottom[i];             // Запомнить Bottom
               iLastBottom =i;
            }
            else{                                  // LastIsBottom
               if( LastBottom-Bottom[i]>-Zero ){   // Перерисовка
                  Min[iLastBottom]=0;
                  Min[i]          =Bottom[i];
                  LastBottom      =Bottom[i];      // Запомнить Bottom
                  iLastBottom     =i;
      }   }  }  }
      i--;
   }
   if( iLastTop>0 ) tLastTop=Time[iLastTop];       // Время крайних изломов
   if( iLastBottom>0 ) tLastBottom=Time[iLastBottom];
   return(0);
}
 
Алексей Тарабанов:

Antes de comercializar uma tendência, é uma boa idéia avaliar se vale a pena. Um ziguezague ajudará. Vamos tentar construir um ziguezague para uma tendência mensal, semanal, ou diária. Exatamente para a tendência, não para alguns parâmetros técnicos. Para isso, usaremos a mesma curva fractal - 119 barras à esquerda e 1 barra à direita. 119 porque há 120 horas por semana e os comerciantes são pagos uma vez por semana. Este é o resultado:

Sobre o código inserido incorretamente, o moderador vai jurar agora.

O princípio e a fórmula de cálculo fractal e ziguezague é um desenho baseado em um evento que ocorreu e não ajuda a identificara direção da tendência, se é sobre isso que se trata :) Ou é outro procedimento confuso?

 
VVT:

Sobre o inserido incorretamente quando o moderador está prestes a repreender.

Quanto à funcionalidade, o princípio e a fórmula de cálculo fractal e ziguezague é um desenho baseado em um fato consumado e não ajuda a determinar a direção da tendência, se for sobre isso de modo algum :) Ou é algo errado?

Simplesmente, novamente, tudo em tempo hábil. Tente fazer alguma prática com o ziguezague, para entender suas dimensões. Se for bem sucedido, ganharemos dinheiro com isso. )

 
Алексей Тарабанов:

Apenas, novamente, tudo em tempo hábil. Pratique o ziguezague, entenda sua dimensão. Se você tiver sucesso, você ganhará dinheiro com isso. )

Eu tentei, não me ajuda a ganhar dinheiro, é por isso que estou lhe dizendo.

 
VVT:

Tentei, não me ajuda a ganhar dinheiro, é por isso que estou lhe dizendo.

Bem, você experimenta com este ziguezague. É um diferente.

 
Алексей Тарабанов:

Bem, você tenta este ziguezague com a história. É bem diferente.

Tudo é muito bonito na história, mas os problemas começam quando você começa a negociar com o real

 
VVT:

Tudo é muito bom na história, mas os problemas começam quando você começa a negociar com o real

Ainda não estamos negociando.

1...178179180181182183184185186187188189190191192...306
Novo comentário