Referência MQL5Biblioteca PadrãoMatemáticaEstatísticaDistribuição gama

Distribuição gama

Esta seção apresenta as funções para trabalhar com a distribuição gama. Elas permitem que você calcule a densidade, probabilidade, quantis e gere números pseudo-aleatórios de acordo com a distribuição correspondente. A distribuição gama é descrita pela seguinte fórmula:

Onde:

x – valor da variável aleatória

a – primeiro parâmetro de distribuição
b – segundo parâmetro de distribuição

DemoGammaDistribution

Além do cálculo das variáveis aleatórias individuais, é possível trabalhar com suas matrizes.

Função	Descrição
MathProbabilityDensityGamma	Calcula a densidade de probabilidade da distribuição gama
MathCumulativeDistributionGamma	Calcula o valor da função distribuição gama de probabilidades
MathQuantileGamma	Calcula o inverso da função de distribuição gama para a probabilidade especificada
MathRandomGamma	Gera um valor/matriz pseudo-aleatório de valores pseudo-aleatórios de acordo com a distribuição gama
MathMomentsGamma	Calcula os valores numéricos teóricos dos primeiros 4 momentos da distribuição gama

Exemplo:

#include <Graphics\Graphic.mqh>
#include <Math\Stat\Gamma.mqh>
#include <Math\Stat\Math.mqh>
#property script_show_inputs
//--- input parameters
input double alpha=9;   // primeiro parâmetro de distribuição gama (shape)
input double beta=0.5;  // segundo parâmetro de distribuição gama (shape)
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- desativamos a exibição do gráfico de preço
   ChartSetInteger(0,CHART_SHOW,false);
//--- inicializamos o gerador de números aleatórios
   MathSrand(GetTickCount());
//--- geramos a amostragem da variável aleatória
   long chart=0;
   string name="GraphicNormal";
   int n=1000000;       // número de valores na amostragem
   int ncells=51;       // número de intervalos no gráfico de colunas
   double x[];          // centros de intervalos no gráfico de colunas
   double y[];          // número de valores a partir da amostragem dentro do intervalo
   double data[];       // amostragem de valores aleatórios
   double max,min;      // valores máximo e mínimo na amostragem
//--- obtemos a amostragem a partir da distribuição gama
   MathRandomGamma(alpha,beta,n,data);
//--- calculamos os dados para plotagem do gráfico de colunas
   CalculateHistogramArray(data,x,y,max,min,ncells);
//--- obtemos os limites de sequência e passo para plotagem da curva teórica
   double step;
   GetMaxMinStepValues(max,min,step);
   step=MathMin(step,(max-min)/ncells);
//--- obtemos teoricamente os cálculos no intervalo [min,max]
   double x2[];
   double y2[];
   MathSequence(min,max,step,x2);
   MathProbabilityDensityGamma(x2,alpha,beta,false,y2);
//--- dimensionamos
   double theor_max=y2[ArrayMaximum(y2)];
   double sample_max=y[ArrayMaximum(y)];
   double k=sample_max/theor_max;
   for(int i=0; i<ncells; i++)
      y[i]/=k;
//--- imprimimos o gráfico
   CGraphic graphic;
   if(ObjectFind(chart,name)<0)
      graphic.Create(chart,name,0,0,0,780,380);
   else
      graphic.Attach(chart,name);
   graphic.BackgroundMain(StringFormat("Gamma distribution alpha=%G beta=%G",alpha,beta));
   graphic.BackgroundMainSize(16);
//--- desativamos o dimensionamento automático no eixo Y
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Max(NormalizeDouble(theor_max,1));
   graphic.YAxis().Min(0);
//--- plot all curves
   graphic.CurveAdd(x,y,CURVE_HISTOGRAM,"Sample").HistogramWidth(6);
//--- e agora traçamos a curva teórica de densidade da distribuição
   graphic.CurveAdd(x2,y2,CURVE_LINES,"Theory");
   graphic.CurvePlotAll();
//--- plot all curves
   graphic.Update();
  }
//+------------------------------------------------------------------+
//|  Calculate frequencies for data set                              |
//+------------------------------------------------------------------+
bool CalculateHistogramArray(const double &data[],double &intervals[],double &frequency[],
                             double &maxv,double &minv,const int cells=10)
  {
   if(cells<=1) return (false);
   int size=ArraySize(data);
   if(size<cells*10) return (false);
   minv=data[ArrayMinimum(data)];
   maxv=data[ArrayMaximum(data)];
   double range=maxv-minv;
   double width=range/cells;
   if(width==0) return false;
   ArrayResize(intervals,cells);
   ArrayResize(frequency,cells);
//--- definimos os centros dos intervalos
   for(int i=0; i<cells; i++)
     {
      intervals[i]=minv+(i+0.5)*width;
      frequency[i]=0;
     }
//--- preenchemos a frequência de aparecimento no intervalo
   for(int i=0; i<size; i++)
     {
      int ind=int((data[i]-minv)/width);
      if(ind>=cells) ind=cells-1;
      frequency[ind]++;
     }
   return (true);
  }
//+------------------------------------------------------------------+
//|  Calculates values for sequence generation                       |
//+------------------------------------------------------------------+
void GetMaxMinStepValues(double &maxv,double &minv,double &stepv)
  {
//--- calculamos a magnitude da sequência para obter a precisão da normalização
   double range=MathAbs(maxv-minv);
   int degree=(int)MathRound(MathLog10(range));
//--- normalizamos os valores máx. e mín. com a precisão
   maxv=NormalizeDouble(maxv,degree);
   minv=NormalizeDouble(minv,degree);
//--- definimos o passo de geração da mesma maneira a partir da precisão definida
   stepv=NormalizeDouble(MathPow(10,-degree),degree);
   if((maxv-minv)/stepv<10)
      stepv/=10.;
  }

MathMomentsNoncentralBeta

MathProbabilityDensityGamma