MathExp

double  MathExp(
   double  value      // potência para o número e
   );

#define GRAPH_WIDTH  750
#define GRAPH_HEIGHT 350
 
#include <Graphics\Graphic.mqh>
 
CGraphic ExtGraph;
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- obtemos 9 valores de 0 a 8 em incrementos de 1
   vector X(9,VectorArange);
   Print("vector X = \n",X);
//--- calculamos o valor do número "e" (número de Euler) elevado à potência de cada valor no vetor X
   X=MathExp(X);
   Print("MathExp(X) = \n",X);
   
//--- transferimos os valores calculados do vetor para o array
   double y_array[];
   X.Swap(y_array);
 
//--- plotamos os valores calculados do vetor
   CurvePlot(y_array,clrDodgerBlue);
 
//--- aguardamos o pressionamento das teclas Escape ou PgDn para excluir o gráfico (criar uma captura de tela) e concluir o trabalho
   while(!IsStopped())
     {
      if(StopKeyPressed())
         break;
      Sleep(16);
     }
 
//--- limpamos o que for preciso
   ExtGraph.Destroy();
  }
//+------------------------------------------------------------------+
//| Preenche o vetor com os value com incremento step                |
//+------------------------------------------------------------------+
template<typename T> 
void VectorArange(vector<T> &vec,T value=0.0,T step=1.0) 
  { 
   for(ulong i=0; i<vec.Size(); i++,value+=step) 
      vec[i]=value; 
  }
//+------------------------------------------------------------------+
//| Ao pressionar ESC, retorna true                                  |
//| Ao pressionar PgDn, faz uma captura de tela e retorna true       |
//| Caso contrário, retorna false                                    |
//+------------------------------------------------------------------+
bool StopKeyPressed()
  {
//--- Ao pressionar ESC, retorna true                                  
   if(TerminalInfoInteger(TERMINAL_KEYSTATE_ESCAPE)!=0)
      return(true);
//--- caso PgDn seja pressionado e a captura de tela do gráfico seja bem-sucedida, retornamos true
   if(TerminalInfoInteger(TERMINAL_KEYSTATE_PAGEDOWN)!=0 && MakeAndSaveScreenshot(MQLInfoString(MQL_PROGRAM_NAME)+"_Screenshot"))
      return(true);
//--- retornamos false
   return(false);
  }
//+------------------------------------------------------------------+
//| Cria um objeto gráfico e desenha uma curva                       |
//+------------------------------------------------------------------+
void CurvePlot(double &x_array[], double &y_array[], const color colour)
  {
   ExtGraph.Create(ChartID(), "Graphic", 0, 0, 0, GRAPH_WIDTH, GRAPH_HEIGHT);
   ExtGraph.CurveAdd(x_array, y_array, ColorToARGB(colour), CURVE_LINES);
   ExtGraph.IndentUp(30);
   ExtGraph.CurvePlotAll();
   string text1="Press ESC to delete the graph and stop the script, or";
   string text2="Press PgDn to create a screen, delete the graph and stop the script";
   ExtGraph.TextAdd(54, 9, text1, ColorToARGB(clrBlack));
   ExtGraph.TextAdd(54,21, text2, ColorToARGB(clrBlack));
   ExtGraph.Update();
  }
//+------------------------------------------------------------------+
//| Cria uma captura de tela e a salva em um arquivo                 |
//+------------------------------------------------------------------+
bool MakeAndSaveScreenshot(const string file_name)
  {
   string file_names[];
   ResetLastError();
   int selected=FileSelectDialog("Save Picture", NULL, "All files (*.*)|*.*", FSD_WRITE_FILE, file_names, file_name+".png");
   if(selected<1)
     {
      if(selected<0)
         PrintFormat("%s: FileSelectDialog() function returned error %d", __FUNCTION__, GetLastError());
      return false;
     }
   
   bool res=false;
   if(ChartSetInteger(0,CHART_SHOW,false))
      res=ChartScreenShot(0, file_names[0], GRAPH_WIDTH, GRAPH_HEIGHT);
   ChartSetInteger(0,CHART_SHOW,true);
   return(res);
  }