//+------------------------------------------------------------------+
//| Demo_iStochastic.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| ;https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "O indicador demonstra como obter dados"
#property description "de buffers do indicador para o indicador técnico iStochastic."
#property description "Um símbolo e o prazo utilizado para o cálculo do indicador,"
#property description "são definidos pelos parâmetros de símbolo e período."
#property description "O método de criação do manipulador é definido através do parâmetro "type" (tipo de função)."
#property description "Todos os outros parâmetros são similares ao padrão."
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots 2
//--- plotar Stochastic
#property indicator_label1 "Stochastic"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrLightSeaGreen
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- plotar Signal
#property indicator_label2 "Signal"
#property indicator_type2 DRAW_LINE
#property indicator_color2 clrRed
#property indicator_style2 STYLE_SOLID
#property indicator_width2 1
//--- definir o limite dos valores do indicador
#property indicator_minimum 0
#property indicator_maximum 100
//--- níveis horizontais na janela de indicador
#property indicator_level1 -100.0
#property indicator_level2 100.0
//+------------------------------------------------------------------+
//| Enumerador dos métodos de criação do manipulador |
//+------------------------------------------------------------------+
enum Creation
{
Call_iStochastic, // usar iStochastic
Call_IndicatorCreate // usar IndicatorCreate
};
//--- parâmetros de entrada
input Creation type=Call_iStochastic; // tipo de função
input int Kperiod=5; // o período K ( o número de barras para cálculo)
input int Dperiod=3; // o período D (o período da suavização primária)
input int slowing=3; // período final da suavização
input ENUM_MA_METHOD ma_method=MODE_SMA; // tipo de suavização
input ENUM_STO_PRICE price_field=STO_LOWHIGH; // método de cálculo do Estocástico
input string symbol=" "; // símbolo
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // timeframe
//--- buffers do indicador
double StochasticBuffer[];
double SignalBuffer[];
//--- variável para armazenar o manipulador do indicator iStochastic
int handle;
//--- variável para armazenamento
string name=symbol;
//--- nome do indicador num gráfico
string short_name;
//--- manteremos o número de valores no indicador Stochastic Oscillatorr
int bars_calculated=0;
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado |
//+------------------------------------------------------------------+
int OnInit()
{
//--- atribuição de arrays para buffers do indicador
SetIndexBuffer(0,StochasticBuffer,INDICATOR_DATA);
SetIndexBuffer(1,SignalBuffer,INDICATOR_DATA);
//--- determinar o símbolo do indicador, é desenhado para
name=symbol;
//--- excluir os espaços à direita e à esquerda
StringTrimRight(name);
StringTrimLeft(name);
//--- se resulta em comprimento zero da string do 'name'
if(StringLen(name)==0)
{
//--- tomar o símbolo do gráfico, o indicador está anexado para
name=_Symbol;
}
//--- criar manipulador do indicador
if(type==Call_iStochastic)
handle=iStochastic(name,period,Kperiod,Dperiod,slowing,ma_method,price_field);
else
{
//--- preencher a estrutura com os parâmetros do indicador
MqlParam pars[5];
//--- o período K para cálculos
pars[0].type=TYPE_INT;
pars[0].integer_value=Kperiod;
//--- o período D para suavização primária
pars[1].type=TYPE_INT;
pars[1].integer_value=Dperiod;
//--- o período K final para suavização
pars[2].type=TYPE_INT;
pars[2].integer_value=slowing;
//--- tipo de suavização
pars[3].type=TYPE_INT;
pars[3].integer_value=ma_method;
//--- método de cálculo do Estocástico
pars[4].type=TYPE_INT;
pars[4].integer_value=price_field;
handle=IndicatorCreate(name,period,IND_STOCHASTIC,5,pars);
}
//--- se o manipulador não é criado
if(handle==INVALID_HANDLE)
{
//--- mensagem sobre a falha e a saída do código de erro
PrintFormat("Falha ao criar o manipulador do indicador para o símbolo %s/%s, código de erro %d",
name,
EnumToString(period),
GetLastError());
//--- o indicador é interrompido precocemente
return(INIT_FAILED);
}
//--- mostra que o símbolo/prazo do indicador Stochastic Oscillator é calculado para
short_name=StringFormat("iStochastic(%s/%s, %d, %d, %d, %s, %s)",name,EnumToString(period),
Kperiod,Dperiod,slowing,EnumToString(ma_method),EnumToString(price_field));
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- inicialização normal do indicador
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- número de valores copiados a partir do indicador iStochastic
int values_to_copy;
//--- determinar o número de valores calculados no indicador
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() retornando %d, código de erro %d",calculated,GetLastError());
return(0);
}
//--- se for o princípio do cálculo do indicador, ou se o número de valores é modificado no indicador iStochastic
//--- ou se é necessário cálculo do indicador para duas ou mais barras (isso significa que algo mudou no histórico do preço)
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- se o array StochasticBuffer é maior do que o número de valores no indicador iStochastic para o símbolo/período, então não copiamos tudo
//--- caso contrário, copiamos menor do que o tamanho dos buffers do indicador
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- isso significa que não é a primeira vez do cálculo do indicador, é desde a última chamada de OnCalculate())
//--- para o cálculo não mais do que uma barra é adicionada
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- preencher os arrays com valores do indicador iStochastic
//--- se FillArraysFromBuffer retorna falso, isto significa que a informação ainda não está pronta, sair da operação
if(!FillArraysFromBuffers(StochasticBuffer,SignalBuffer,handle,values_to_copy)) return(0);
//--- formar a mensagem
string comm=StringFormat("%s ==> Valor atualizado no indicador %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- exibir a mensagem de serviço no gráfico
Comment(comm);
//--- memorizar o número de valores no indicador Stochastic Oscillator
bars_calculated=calculated;
//--- retorna o valor prev_calculated para a próxima chamada
return(rates_total);
}
//+------------------------------------------------------------------+
//| Preencher buffers do indicador a partir do indicador iStochastic |
//+------------------------------------------------------------------+
bool FillArraysFromBuffers(double &main_buffer[], // buffer do indicador dos valores do Stochastic Oscillator
double &signal_buffer[], // buffer do indicator da linha de sinal
int ind_handle, // manipulador do indicador iStochastic
int amount // número de valores copiados
)
{
//--- redefinir o código de erro
ResetLastError();
//--- preencher uma parte do array StochasticBuffer com valores do buffer do indicador que tem índice 0 (zero)
if(CopyBuffer(ind_handle,MAIN_LINE,0,amount,main_buffer)<0)
{
//--- Se a cópia falhar, informe o código de erro
PrintFormat("Falha ao copiar dados do indicador iStochastic, código de erro %d",GetLastError());
//--- parar com resultado zero - significa que indicador é considerado como não calculado
return(false);
}
//--- preencher uma parte do array SignalBuffer com valores do buffer do indicador que tem índice 1(um)
if(CopyBuffer(ind_handle,SIGNAL_LINE,0,amount,signal_buffer)<0)
{
//--- Se a cópia falhar, informe o código de erro
PrintFormat("Falha ao copiar dados do indicador iStochastic, código de erro %d",GetLastError());
//--- parar com resultado zero - significa que indicador é considerado como não calculado
return(false);
}
//--- está tudo bem
return(true);
}
//+------------------------------------------------------------------+
//| Função de desinicialização do indicador |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- limpar o gráfico após excluir o indicador
Comment("");
}
|