UninitializeReason

int  UninitializeReason();

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- obtemos o código do motivo da desinicialização na variável reason
   int reason=UninitializeReason();
//--- criamos a string da mensagem com o motivo da desinicialização e enviamos a mensagem para o log
   string message=StringFormat("%s: Uninitialize reason code: %d (%s)",__FUNCTION__, reason, UninitializeReasonDescription(reason));
   Print(message);
//--- sucesso
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- criamos a string da mensagem com o código do motivo da desinicialização a partir da variável formal reason e enviamos a mensagem para o log
   string message=StringFormat("%s: Uninitialize reason code: %d (%s)",__FUNCTION__, reason, UninitializeReasonDescription(reason));
   Print(message);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
  }
//+------------------------------------------------------------------+
//| Retorna a descrição do motivo da desinicialização                |
//+------------------------------------------------------------------+
string UninitializeReasonDescription(const int reason)
  {
   switch(reason)
     {
      //--- o expert interrompeu sua tarefa chamando a função ExpertRemove()
      case REASON_PROGRAM :
        return("Expert Advisor terminated its operation by calling the ExpertRemove() function");
      //--- programa removido do gráfico
      case REASON_REMOVE :
        return("Program has been deleted from the chart");
      //--- programa recompilado
      case REASON_RECOMPILE :
        return("Program has been recompiled");
      //--- o símbolo ou o período do gráfico foi alterado
      case REASON_CHARTCHANGE :
        return("Symbol or chart period has been changed");
      //--- gráfico encerrado
      case REASON_CHARTCLOSE :
        return("Chart has been closed");
      //--- os parâmetros de entrada foram alterados pelo usuário
      case REASON_PARAMETERS :
        return("Input parameters have been changed by a user");
      //--- outra conta foi ativada ou ocorreu uma reconexão ao servidor de negociação devido a alterações nas configurações da conta
      case REASON_ACCOUNT :
        return("Another account has been activated or reconnection to the trade server has occurred due to changes in the account settings");
      //--- aplicado um novo modelo de gráfico
      case REASON_TEMPLATE :
        return("A new template has been applied");
      //--- sinal de que o manipulador OnInit() retornou um valor diferente de zeroе
      case REASON_INITFAILED :
        return("This value means that OnInit() handler has returned a nonzero value");
      //--- o terminal foi fechado
      case REASON_CLOSE :
        return("Terminal has been closed");
     }
 
//--- motivo desconhecido para a desinicialização
   return("Unknown reason");
  }