DocumentaçãoSeções
Referência MQL5Operações de GráficosChartTimePriceToXY 

ChartTimePriceToXY

Converte as coordenadas do gráfico a partir da representação tempo/preço para as coordenadas X e Y.

bool  ChartTimePriceToXY(
   long           chart_id,     // ID Gráfico
   int            sub_window,   // O número de sub-janelas
   datetime       time,         // Tempo do Gráfico
   double         price,        // Preço no gráfico
   int&           x,            // A coordenada X para o tempo no gráfico
   int&           y             // A coordenada Y para o tempo no gráfico
   );

Parâmetros

chart_id

[in]  ID Gráfico. Significa o gráfico atual.

sub_window

[in]  O numero da sub-janela do gráfico. 0 (zero) significa a principal janela do gráfico.

time

[in]  O valor do tempo do gráfico, valores em pixels para o qual vai ser recebido ao longo do eixo X. A origem está no canto superior esquerdo da principal janela do gráfico.

price

[in]   O valor do preço no gráfico, valores em pixels para o qual vai ser recebido ao longo do eixo Y. A origem está no canto superior esquerdo da principal janela do gráfico.

x

[out]  A variável, dentro do qual a conversão do tempo para X será recebida.

y

[out]  A variável, dentro do qual a conversão do preço para Y será recebida.

Valor do Retorno

Retorna true se bem sucedido, caso contrário false. Para obter informação sobre o erro, chamar a função GetLastError().

Пример:

#define   BAR_NUMBER    0  // номер бара, с которого получаем цену и время
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- копируем данные одного бара по индексу BAR_NUMBER
   MqlRates rates[]={};
   if(CopyRates(_Symbol, _Period, BAR_NUMBER, 1, rates)!=1)
     {
      PrintFormat("CopyRates() failed for bar %d. Error %d", BAR_NUMBER, GetLastError());
      return;
     }
       
//--- преобразуем полученные цену и время в пиксельные координаты графика
   int x=0, y=0;
   ResetLastError();
   if(!ChartTimePriceToXY(ChartID(), 0, rates[0].time, rates[0].close, x, y))
     {
      Print("ChartTimePriceToXY() failed. Error ", GetLastError());
      return;
     }
     
//--- распечатаем полученный результат в журнале
   PrintFormat("For bar[%d] with opening time %s and price %.*f, the chart coordinates are x: %d, y: %d", BAR_NUMBER, TimeToString(rates[0].time), _Digits, rates[0].close, x, y);
   
   /*
   результат:
   For bar[0] with opening time 2024.08.09 15:06 and price 1.27378, the chart coordinates are x: 784, y: 240
   */
  }

Também Veja

ChartXYToTimePrice()