Assistente MQL5 - Sinais de negociação baseado no padrão candle Cobertura de Nuvem Negra/Linha Perfurante + MFI - expert para MetaTrader 5

O Assistente MQL5 permite a criação de Expert Advisors prontos para usar com base nas classes da Biblioteca Padrão entregues juntamente com o terminal do cliente (veja Criando Expert Advisors Prontos Para Usar no Assistente MQL5 para mais detalhes). Ele permite verificar suas idéias de negociação rapidamente, tudo que você precisa é criar sua própria classe de sinais de negociação. A estrutura desta classe e exemplo podem ser encontrado no artigo Assistente MQL5: Como criar um módulo de sinais de negociação.

A ideia genérica é o seguinte: a classe dos sinais de negociação deriva do CExpertSignal, em seguida, é necessário substituir os métodos virtuais LongCondition() e ShortCondition() com seus próprios métodos.

Há um livro chamado "Estratégias dos melhores traders" (em Russo), existem muitas estratégias de negociação que são considerados neste livro, vamos nos concentrar em padrões de velas de reversão, confirmados pelos osciladores Stochastic, CCI, MFI e RSI.

A melhor maneira é criar a classe separada, derivado de CExpertSignal para a verificação da formação de padrões de candles. Para confirmar os sinais de negociação, gerados por padrões de velas, apenas escreva a classe derivada de CCandlePattern e adicionar aos recursos necessários existentes (por exemplo, a confirmação por osciladores).

Aqui vamos considerar os sinais baseados no padrão candle de reversão "Cobertura de Nuvem Negra/Linha Perfurante", confirmado pelo indicador Market Facilitation Index (MFI). O módulo de sinais de negociação baseia-se na classe CCandlePattern, é um simples exemplo de seu uso para a criação de sinais de negociação com padrões de candles.

1. Padrão candle de reversão "Cobertura de Nuvem Negra" e "Linha Perfurante"

1.1. Cobertura de Nuvem Negra

É uma candle de reversão de baixa que ocorre no final de uma tendência de alta. Um longo candle branco é formado no primeiro dia e uma lacuna (gap) para cima é criada no segundo dia. Observe a imagem abaixo e veja que o preço de abertura do segundo dia está acima do preço alto da sombra do longo candle branco fechado no primeiro dia, esta é a lacuna formada, conhecida também como gap. No entanto, o segundo dia fecha abaixo do ponto médio do primeiro dia.

Padrão candle Fig. 1. "Cobertura de Nuvem Negra"

O reconhecimento do padrão "Cobertura de Nuvem Negra" é implementado no método CheckPatternDarkCloudCover() da classe CCandlePattern:

//+-------------------------------------------------------------------+
//| Verificando a formação do padrão candle "Cobertura de Nuvem Negra"|
//+-------------------------------------------------------------------+
bool CCandlePattern::CheckPatternDarkCloudCover()
  {
//--- Cobertura de Nuvem Negra  
   if((Close(2)-Open(2)>AvgBody(1))  && // (longo candle branco)
      (Close(1)<Close(2))            && // 
      (Close(1)>Open(2))             && // (fechamento dentro do corpo anterior)
      (MidOpenClose(2)>CloseAvg(1))  && // (tendência de alta)
      (Open(1)>High(2)))                // (abrir em nova alta)
      return(true);
//---
   return(false);
  }

1.2. Linha Perfurante

Uma lacuna (gap) para baixo no segundo dia perpetua a tendência de baixa. Observe na imagem abaixo a lacuna formada quando o preço de abertura do segundo dia está abaixo do menor preço da sombra do candle negro fechado no dia anterior. No entanto, fechamento do candle segundo dia está acima do ponto médio do corpo do primeiro dia. Isto sugere para os ursos (vendedores) que um fundo pode estar se formando. Esta ação do preço não é tão perceptível usando gráficos de barras, temos um visualização melhor com gráficos de candles (velas). Quanto maior a penetração do fechamento no segundo dia sobre o corpo do primeiro dia, maior é a probabilidade da reversão do sinal ser bem sucedida..

Fig. 2. Padrão Candle "Linha Perfurante" (Piercing Line)

O reconhecimento do padrão "Linha Perfurante" é implementado no método CheckPatternPiercingLine() da classe CCandlePattern:

//+------------------------------------------------------------------+
//| Verificando a formação do padrão candle "Linha Perfurante"       |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternPiercingLine()
  {
//--- Linha Perfurante
   if((Close(1)-Open(1)>AvgBody(1)) && // (longo candle branco)
      (Open(2)-Close(2)>AvgBody(1)) && // (longo candle negro)
      (Close(1)>Close(2))           && //  
      (Close(1)<Open(2))            && // (fechamento dentro do corpo anterior) 
      (MidOpenClose(2)<CloseAvg(2)) && // (tendência de baixa)
      (Open(1)<Low(2)))                // (abrir menor do que o Preço Baixo anterior) 
      return(true);
//---
   return(false);
  }

2. Sinais de negociação confirmados pelo indicador MFI

Os sinais de negociação para abrir posição comprada ou vendida devem ser confirmados pelo indicador MFI. O valor do indicador MFI deve ser menor do que 40 (para posições compradas) ou superior a 60 (para as posições vendidas).

O fechamento da posição aberta depende dos valores do indicador MFI. Pode ser feito em dois casos:

1. Se o MFI atingir o nível crítico oposto (70 para a posição comprada e 30 para posição vendida)
2. se o sinal inverso não for confirmado (quando o indicador MFI atinge os seguintes níveis: 30 para a posição comprada e 70 para a posição vendida)

Fig. 3. Padrão "Cobertura de Nuvem Negra", confirmado pelo indicador MFI

• int CDC_PL_MFI::LongCondition() - verifica as condições para abrir posição comprada (retorna 80) e fecha na posição vendida (retorna 40);
  
• int CDC_PL_MFI::ShortCondition() - verifica as condições para abrir posição vendida (retorna 80) e fecha na posição comprada(retorna 40).

2.1. Abrir posição comprada/Fechar posição vendida

1. A formação do padrão "Linha Perfurante" deve ser confirmado pelo indicador MFI : MFi(1)<40 (o valor do indicador MFI da última barra completa deve ser menor do que 40).

2. A posição vendida deve ser fechada se o indicador MFI cruzar para cima os níveis críticos (70 ou 30).

//+------------------------------------------------------------------+
//|  Verifica as condições de entrada e saída do mercado             |
//| 1) Entrada no Mercado (abrir posição comprada, resultado=80)     |
//| 2) Saída do Mercado(fechar posição vendida, resultado=40)        |
//+------------------------------------------------------------------+
int CDC_PL_MFI::LongCondition()
  {
   int result=0;
//--- idx pode ser usado para determinar o modo de trabalho do Expert Advisor
//--- idx=0 - neste caso o EA verifica as condições de negócio a cada tick
//--- idx=1 - neste caso o EA verifica as condições de negócio apenas nas novas barras
   int idx   =StartIndex();
   int idx   =StartIndex();
//--- verificando as condições para abrir posição comprada
//--- formação do padrão Linha Perfurante e MFI<40
  if(CheckCandlestickPattern(CANDLE_PATTERN_PIERCING_LINE) && (MFI(1)<40))
     result=80;
//--- verificando as condições para fechar com posição vendida
//--- cruzamento da linha de sinal nos níveis sobrecomprados/sobrevendidos (ascendente 30, ascendente 70)
  if(((MFI(1)>30) && (MFI(2)<30)) || ((MFI(1)>70) && (MFI(2)<70)))
     result=40;
//--- resultado de retorno
   return(result);
  }

2.2. Abrir posição vendida/ Fechar posição comprada

1. A formação do padrão "Cobertura de Nuvem Negra" deve ser confirmada pelo indicador MFI: MFI(1)>60 (o valor do indicador MFI da última barra completa deve ser maior do que 60).

2. A posição longa deve ser fechado se o indicador MFI cruzar para cima os níveis críticos (70 ou 30).

//+------------------------------------------------------------------+
//| Verifica as condições de entrada e saída do mercado              |
//| 1) Entrada no Mercado (abrir posição vendida, resultado=80)      |
//| 2) Saída do Mercado (fechar posiçao comprada, resultado=40)      |
//+------------------------------------------------------------------+
int CDC_PL_MFI::ShortCondition()
  {
   int result=0;
//--- idx pode ser usado para determinar o modo de trabalho do Expert Advisor
//--- idx=0 - neste caso o EA verifica as condições de negócio a cada tick
//--- idx=1 - neste caso o EA verifica as condições de negócio apenas nas novas barras
   int idx   =StartIndex();
//--- verificando condições para abertura de posição vendida
//--- formação do padrão Cobertura de Nuvem Negra e MFI>60
  if(CheckCandlestickPattern(CANDLE_PATTERN_DARK_CLOUD_COVER) && (MFI(1)>60))
     result=80;
//--- verificando condições para fechamento com posição comprada
//--- cruzamento da linha de sinal nos níveis sobrecomprados/sobrevendidos (ascendente 70, descendente 30)
   if(((MFI(1)>70) && (MFI(2)<70)) || ((MFI(1)<30) && (MFI(2)>30)))
     result=40;
//--- resultado de retorno
   return(result);
  }

2.3. Criando Expert Advisor usando Assistente MQL5

Para criar um Expert Advisor através do Assistente MQL5:

Fig. 4. Criando Expert Advisor usando Assistente MQL5

Vamos especificar o nome do Expert Advisor:

Fig. 5. Propriedades gerais do Expert Advisor

Depois disso, precisamos selecionar os módulos de sinais de negociação a serem usados.

Fig. 6. Propriedades de sinal do Expert Advisor

No nosso caso, usamos apenas um módulo de sinais de negociação.

Adicionando o módulo "Sinal baseado na "Cobertura de Nuvem Negra/Linha Perfurante" confirmado pelo MFI" :

Fig. 7. Propriedades de sinal do Expert Advisor

Módulo de sinais de negociação adicionado:

Fig. 8. Propriedades de sinal do Expert Advisor

Você pode selecionar as propriedades à direita, mas vamos utilizar a opção "trailing stop não usado":

Fig. 9. Seguindo as propriedades do Expert Advisor

Em relação às propriedades de gerenciamento de dinheiro, utilisaremos a opção "Negociação com volume de negociação fixo":

Fig. 10. Propriedades de gerenciamento de dinheiro do Expert Advisor

Ao pressionar o botão "Finish", vamos obter o código gerado do Expert Advisor, localizado em Expert_ADC_PL_MFI.mq5, ele será salvo no terminal_data_folder\MQL5\Experts\.

Os parâmetros de entrada padrão do Expert Advisor que foi gerado são:

//--- Entrada para o sinal principal 
input int            Signal_ThresholdOpen   =10;     // Valor limite de sinal para abrir [0...100]
input int            Signal_ThresholdClose  =10;     // Valor limite de sinal para fechar[0...100]
input double         Signal_PriceLevel      =0.0;    // Nível do preço para executar uma oferta
input double         Signal_StopLevel       =50.0;   // Nível de Stop Loss (em pontos)
input double         Signal_TakeLevel       =50.0;   // Nível de Take Profit (em pontos)

deve ser substituído para:

//--- Entrada para o sinal principal
input int            Signal_ThresholdOpen   =40;     // Valor limite de sinal para abrir [0...100]
input int            Signal_ThresholdClose  =20;     // Valor limite de sinal para fechar [0...100]
input double         Signal_PriceLevel      =0.0;    // Nível do preço para executar uma oferta 
input double         Signal_StopLevel       =0.0;    // Nível de Stop Loss (em pontos)
input double         Signal_TakeLevel       =0.0;    // Nível de Take Profit(em pontos)

Os parâmetros de entrada Signal_ThresholdOpen/Signal_ThresholdClose permitem especificar os níveis de limite para abrir e fechar de posições.

No código dos métodos LongCondition() e ShortCondition() da classe de sinais de negociação colocaremos os valores fixos do limite:

• Abrir Posição: 80;
• Fechar posição: 40.
  

Os valores dos parâmetros de entrada Signal_StopLevel e Signal_TakeLevel são definidos como 0, isso significa que o fechamento das posições será realizado apenas quando as condições de fechamento forem verdadeiras.

2.4. Teste dos resultados pelo histórico

Vamos considerar o resultado do teste do Expert Advisor em dados históricos (EURUSD H1, período do teste: 2010.01.01-2011.03.16, PeriodMFI=49, MA_period=11).

Na criação de Expert Advisor usamos o volume fixo (Lote da Negociação Fixa, 0.1), o algorítimo do Trailing Stop não é usado (Trailing Stop não é usado).

Fig. 11. Resultados do Teste do Expert Advisor, baseado na "Cobertura de Nuvem Negra/Linha Perfurante + MFI

O melhor conjunto de parâmetros de entrada podem ser encontrados usando o Testador de Estratégias do terminal do cliente MetaTrader 5.

O código do Expert Advisor, criado pelo Assistente MQL5 está anexado em expert_adc_pl_mfi.mq5.