Demo_FileWriteArray - expert para MetaTrader 5

O Expert Advisor obtém valores de preço Bid e Ask em cada tick e lembra-os da estrutura array dos "preços". A cada vigésimo tick, o Expert Advisor escreve a estrutura de objetos de dados para o arquivo usando a função FileWriteArray(). Os dados serão registrados no arquivo binário no subdiretório da pasta local do terminal. A posição da pasta local do terminal pode ser obtida chamando a função TerminalInfoString().

PrintFormat("O caminho para a pasta local do terminal: %s\\Arquivos\\",TerminalInfoString(TERMINAL_DATA_PATH)); 

Quando é excluído o Expert Advisor a partir do gráfico, fica registrado os dados não escritos no arquivo depois que o Expert Advisor termina o seu trabalho.

Código:

//--- parâmetros de entrada
input string InpFileName="dados.bin";
input string InpDirectoryName="AlgumaPasta";
//+------------------------------------------------------------------+
//| Estrutura para o armazenamento de dados dos preços               |
//+------------------------------------------------------------------+
struct prices
  {
   datetime          date; // dados
   double            bid;  // preço Bid
   double            ask;  // preço Ask
  };
//--- variáveis globais
int    count=0;
int    size=20;
string path=InpDirectoryName+"//"+InpFileName;
prices arr[];
//+------------------------------------------------------------------+
//| Função de inicialização do Expert                                |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- alocando memória para o array
   ArrayResize(arr,size);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de desinicialização do Expert                             |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- escrever a contagem das string restantes se a quantidade<n
   WriteData(count);
  }
//+------------------------------------------------------------------+
//| Função tick do Expert                                            |
//+------------------------------------------------------------------+
void OnTick()
  {
//--- salvar dados para o array
   arr[count].date=TimeCurrent();
   arr[count].bid=SymbolInfoDouble(Symbol(),SYMBOL_BID);
   arr[count].ask=SymbolInfoDouble(Symbol(),SYMBOL_ASK);
//--- mostrar dados atuais
   Print("Data = ",arr[count].date," Bid = ",arr[count].bid," Ask = ",arr[count].ask);
//--- aumentar o contador
   count++;
//--- se o array é preenchido, escrever os dados para o arquivo e zerá-lo
   if(count==size)
     {
      WriteData(size);
      count=0;
     }
  }
//+------------------------------------------------------------------+
//|Escrever n elementos do array para o arquivo                      |
//+------------------------------------------------------------------+
void WriteData(const int n)
  {
//--- abrir o arquivo
   ResetLastError();
   int handle=FileOpen(path,FILE_READ|FILE_WRITE|FILE_BIN);
   if(handle!=INVALID_HANDLE)
     {
      //--- escrever os dados de array para o final do arquivo
      FileSeek(handle,0,SEEK_END);
      FileWriteArray(handle,arr,0,n);
      //--- fechar o arquivo
      FileClose(handle);
     }
   else
      Print("Falha ao abrir o arquivo, o erro",GetLastError());
  }