TradeState - o modo de negociação do EA se altera dependendo do tempo - biblioteca para MetaTrader 5

Você já restringiu as operações do seu EA dependendo do tempo? Por exemplo, como que uma pessoa faz para o EA não realizar nenhuma atividade de negociação durante a sessão noturna? Ou, se você negociar na seção de derivativos da Bolsa de Moscou, você já fechou todas as posições antes do fechamento do mercado antes do fim de semana? Que tal estruturas mais complexas? Por exemplo, como é que uma pessoa faz o EA ser capaz de abrir e fechar posições até as 19h00 e não realizar nenhuma negociação nova depois das 19h00? Na verdade, é possível obter tal configuração flexível. O módulo especial CTradeState irá lhe ajudar com isso.

Como a CTradeState funciona? O módulo retorna um dos seis estados, definidos usando a estrutura ENUM_TRADE_STATE:

//+------------------------------------------------------------------+
//| Determina o estado da negociação do EA                           |
//+------------------------------------------------------------------+
enum ENUM_TRADE_STATE
{
   TRADE_BUY_AND_SELL,              // Compra e venda é aceito.
   TRADE_BUY_ONLY,                  // Apenas a compra é permitida. A venda não é permitida.
   TRADE_SELL_ONLY,                 // Apenas a venda é permitida. A compra não é permitida.
   TRADE_STOP,                      // A negociação não é permitida. Fecha todas as posições imediatamente. Não aceita novos sinais de entrada.
   TRADE_WAIT,                      // O controle sobre as posições abertas é perdido. Novos sinais são ignorados. Útil durante os comunicados de imprensa.
   TRADE_NO_NEW_ENTRY               // Os sinais de entrada são ignorados. No entanto, as posições abertas são mantidas de acordo com a lógica de negociação. 
};

Em seu Expert Advisor você deve executar um conjunto de ações, dependendo de qual modificador específico a partir da estrutura dada a CTradeState retorna (o valor é devolvido utilizando o método GetTradeState).

Antes de utilizar os modos de trade, eles devem ser definidos, para qual método o SetTradeState deve chamar. O protótipo do método SetTradeState é como se segue:

//+-----------------------------------------------------------------------+
//| Define o estado da negociação de TradeState                           |
//| ENTRADA:                                                              |
//| time_begin  - Tempo, a partir de qual estado de negociação ele inicia |
//|               seu funcionamento.                                      |
//| time_end    - Tempo, até que estado do trade que ele funciona         |
//| day_of_week - Dia da semana, para que a definição do estado da        |
//|               negociação é aplicado. Corresponde aos modificadores    |
//|               ENUM_DAY_OF_WEEK ou o modificador ALL_DAYS_OF_WEEK      |
//| state       - O estado do trade.                                      |
//| Atenção, o componente de data em time_begin e time_end é ignorado.    |
//+-----------------------------------------------------------------------+
void CTradeState::SetTradeState(datetime time_begin,datetime time_end, int day_of_week, ENUM_TRADE_STATE state);

Por exemplo, para o módulo de estado da negociação retornar o modificador TRADE_WAIT (controle sobre as posições em aberto é interrompido, novas posições não são bertas) no horário das 18:45 até 18:49, é necessário chamar o SetTradeState com os seguintes parâmetros:

TradeState.SetTradeState(D'18:45', D'18:59', ALL_DAYS_OF_WEEK, TRADE_WAIT);

É possível especificar não só o horário de início e encerramento modo de negociação, mas também o dia da semana, para o qual este modo está ativo. Se o modo de negociação precisa ser específico para cada dia da semana, o modificador ALL_DAYS_OF_WEEK modifier necessita ser usado. Se o modo de negociação precisa ser específico para um certo dia da semana, especifique um dos valores da enumeração do sistema ENUM_DAY_OF_WEEK na variável day_of_week.

A fim de obter o modo de negociação atual, use o método GetTradeState.

Como um exemplo, considere uma combinação de modos, que pode ser útil se utilizado em uma negociação na seção de derivativos da Bolsa de Moscou:

Exemplo de uso. Esta combinação de modos é definida utilizando a seguinte sequência de chamadas do SetTradeState (exemplo como um script):

//+------------------------------------------------------------------+
//|                                               TestTradeState.mq5 |
//|                                 Copyright 2015, Vasiliy Sokolov. |
//|                                              http://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2015, Vasiliy Sokolov."
#property link      "http://www.mql5.com"
#property version   "1.00"
#include <Strategy\TradeState.mqh>

CTradeState TradeState(TRADE_BUY_AND_SELL);  // Define o modo padrão para Compra e Venda
//+------------------------------------------------------------------+
//| Script da função de início do programa                           |
//+------------------------------------------------------------------+
void OnStart()
{
   TradeState.SetTradeState(D'15:00', D'23:39', FRIDAY, TRADE_NO_NEW_ENTRY);
   TradeState.SetTradeState(D'10:00', D'10:01', ALL_DAYS_OF_WEEK, TRADE_WAIT);
   TradeState.SetTradeState(D'14:00', D'14:03', ALL_DAYS_OF_WEEK, TRADE_WAIT);
   TradeState.SetTradeState(D'18:45', D'18:59', ALL_DAYS_OF_WEEK, TRADE_WAIT);
   TradeState.SetTradeState(D'23:50', D'23:59', ALL_DAYS_OF_WEEK, TRADE_STOP);
   TradeState.SetTradeState(D'0:00',  D'9:59',  ALL_DAYS_OF_WEEK, TRADE_WAIT);
   TradeState.SetTradeState(D'23:40', D'23:49', FRIDAY, TRADE_STOP);
   TradeState.SetTradeState(D'00:00', D'23:59', SATURDAY, TRADE_WAIT);
   TradeState.SetTradeState(D'00:00', D'23:59', SUNDAY, TRADE_WAIT);
   
   printf("10:00 - " + EnumToString(TradeState.GetTradeState(D'10:00')));
   printf("14:01 - " + EnumToString(TradeState.GetTradeState(D'14:01')));
   printf("18:50 - " + EnumToString(TradeState.GetTradeState(D'18:50')));
   printf("23:50 - " + EnumToString(TradeState.GetTradeState(D'23:51')));
   printf("Friday, > 15:00 - " + EnumToString(TradeState.GetTradeState(D'2015.11.27 15:00')));
   printf("Saturday - " + EnumToString(TradeState.GetTradeState(D'2015.11.28')));
   printf("Sunday - " + EnumToString(TradeState.GetTradeState(D'2015.11.29')));
   printf("Default State - " + EnumToString(TradeState.GetTradeState(D'11:40')));
}
//+------------------------------------------------------------------+

Como um controle, este script implementa uma impressão de modo que corresponde ao tempo de negociação específica.

É importante perceber que o módulo proposto é apenas uma ferramenta auxiliar. A decisão de interromper a negociação (e para fechar todas as posições) deve ser feita pelo próprio Expert. No entanto, é bem fácil criar diferentes zonas de tempo e modos de negociação para qualquer Expert usando este módulo.