VolATR by barrettdenning

To get access to MT4 version please click here.

• This is the exact conversion from TradingView: "VolATR" by "barrettdenning"
• This is a light-load processing.
• This is a non-repaint indicator.
• All input options are available. 
• Buffers are available for processing in EAs.
• You can message in private chat for further changes you need.

Here is the source code of a sample EA operating based on signals from indicator:

#include <Trade\Trade.mqh>
CTrade trade;
int handle_volatr=0;

input group "EA Setting"
input int magic_number=123456; //magic number
input double fixed_lot_size=0.01; // select fixed lot size

input group "VOLATR setting"
input int atrPeriod = 20;//Period
input double atrMultiplier = 4;//Multiplier
input int len2 = 20; //Smooth
input ENUM_APPLIED_PRICE src = PRICE_CLOSE; //Source
input int vol_length = 20; //Volume SMA length

int OnInit()
  {
   trade.SetExpertMagicNumber(magic_number);
   handle_volatr=iCustom(_Symbol, PERIOD_CURRENT, "Market\\VolATR by barrettdenning", atrPeriod, atrMultiplier, len2, src, vol_length);
   if(handle_volatr==INVALID_HANDLE) 
   {
      Print("Indicator not found!");
      return INIT_FAILED;
   }
   return(INIT_SUCCEEDED);
  }

void OnDeinit(const int reason)
  {
   IndicatorRelease(handle_volatr);
  }

void OnTick()
  {
   if(!isNewBar()) return;
   ///////////////////////////////////////////////////////////////////
   bool buy_condition=true;
   buy_condition &= (BuyCount()==0);
   buy_condition &= (IsVOLATRBuy(1));
   if(buy_condition) 
   {
      CloseSell();
      Buy();
   }
      
   bool sell_condition=true;
   sell_condition &= (SellCount()==0);
   sell_condition &= (IsVOLATRSell(1));
   if(sell_condition) 
   {
      CloseBuy();
      Sell();
   }
  }

bool IsVOLATRBuy(int i)
{
   double array[];
   ArraySetAsSeries(array, true);
   CopyBuffer(handle_volatr, 6, i, 1, array);
   return array[0]!=EMPTY_VALUE;
}

bool IsVOLATRSell(int i)
{
   double array[];
   ArraySetAsSeries(array, true);
   CopyBuffer(handle_volatr, 7, i, 1, array);
   return array[0]!=EMPTY_VALUE;
}

int BuyCount()
{
   int buy=0;
   for(int i=0;i<PositionsTotal();i++)
   {
      ulong ticket=PositionGetTicket(i);
      if(ticket==0) continue;
      if(PositionGetInteger(POSITION_TYPE) != POSITION_TYPE_BUY) continue;
      if(PositionGetInteger(POSITION_MAGIC) != magic_number) continue;
      buy++;
   }  
   return buy;
}

int SellCount()
{
   int sell=0;
   for(int i=0;i<PositionsTotal();i++)
   {
      ulong ticket=PositionGetTicket(i);
      if(ticket==0) continue;
      if(PositionGetInteger(POSITION_TYPE) != POSITION_TYPE_SELL) continue;
      if(PositionGetInteger(POSITION_MAGIC) != magic_number) continue;
      sell++;
   }  
   return sell;
}


void Buy()
{
   double Ask=SymbolInfoDouble(_Symbol, SYMBOL_ASK);
   if(!trade.Buy(fixed_lot_size, _Symbol, Ask, 0, 0, ""))
   {
      Print("Error executing order: ", GetLastError());
      //ExpertRemove();
   }
}

void Sell()
{
   double Bid=SymbolInfoDouble(_Symbol, SYMBOL_BID);
   if(!trade.Sell(fixed_lot_size, _Symbol, Bid, 0, 0, ""))
   {
      Print("Error executing order: ", GetLastError());
      //ExpertRemove();
   }
}


void CloseBuy()
{
   for(int i=PositionsTotal()-1;i>=0;i--)
   {
      ulong ticket=PositionGetTicket(i);
      if(ticket==0) continue;
      if(PositionGetInteger(POSITION_TYPE) != POSITION_TYPE_BUY) continue;
      if(PositionGetInteger(POSITION_MAGIC) != magic_number) continue;
      if(trade.PositionClose(ticket)==false)
      {
         Print("Error closing position: ", GetLastError());
         //ExpertRemove();
      }
   }  
}

void CloseSell()
{
   for(int i=PositionsTotal()-1;i>=0;i--)
   {
      ulong ticket=PositionGetTicket(i);
      if(ticket==0) continue;
      if(PositionGetInteger(POSITION_TYPE) != POSITION_TYPE_SELL) continue;
      if(PositionGetInteger(POSITION_MAGIC) != magic_number) continue;
      if(trade.PositionClose(ticket)==false)
      {
         Print("Error closing position: ", GetLastError());
         //ExpertRemove();
      }
   }  
}

datetime timer=NULL;
bool isNewBar()
{
   datetime candle_start_time= (int)(TimeCurrent()/(PeriodSeconds()))*PeriodSeconds();
   if(timer==NULL) {}
   else if(timer==candle_start_time) return false;
   timer=candle_start_time;
   return true;
}