PositionSelectByTicket

bool  PositionSelectByTicket(
   ulong   ticket     // 포지션 티켓
   );

#define   EXPERT_MAGIC  123456   // MagicNumber
 
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수                                          |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 요청 및 결과 구조를 선언하고 초기화
   MqlTradeRequest request={};
   MqlTradeResult  result ={};
   
//--- 매수 포지션에 진입하려면 거래 요청 매개변수를 입력
   request.action    = TRADE_ACTION_DEAL;                      // 거래 동작 유형
   request.symbol    = Symbol();                               // 심볼
   request.volume    = 0.1;                                    // 0.1 랏의 볼륨
   request.type      = ORDER_TYPE_BUY;                         // 주문 유형
   request.price     = SymbolInfoDouble(Symbol(), SYMBOL_ASK); // 시가
   request.deviation = 5;                                      // 가격에서 허용된 편차
   request.magic     = EXPERT_MAGIC;                           // 주문 매직넘버
   
//--- 요청 전송 요청 전송에 실패한 경우 오류 코드를 표시하고 작업을 완료
   if(!OrderSend(request, result))
     {
      PrintFormat("OrderSend error ", GetLastError());
      return;
     }
      
//--- 작동 데이터 표시
   PrintFormat("Trade request result: retcode: %u, deal: %I64u, order: %I64u", result.retcode, result.deal, result.order);
   
//--- 거래 수행 결과에서 포지션 티켓을 얻어 티켓으로 포지션을 선택
//--- 새로 진입한 포지션의 티켓은 거래를 생성한 주문의 티켓에 해당합니다.
   ulong ticket=result.order;
   ResetLastError();
   if(!PositionSelectByTicket(ticket))
     {
      PrintFormat("PositionSelectByTicket(%I64u) failed. Error %d", ticket, GetLastError());
      return;
     }
 
//--- 티켓으로 선택한 포지션의 데이터를 저널에 표시
   ENUM_POSITION_TYPE type  = (ENUM_POSITION_TYPE)PositionGetInteger(POSITION_TYPE);
   long               time  = PositionGetInteger(POSITION_TIME_MSC);
   double             price = PositionGetDouble(POSITION_PRICE_OPEN);
   double             volume= PositionGetDouble(POSITION_VOLUME);
   string             symbol= PositionGetString(POSITION_SYMBOL);
   int                digits= (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS);
   PrintFormat("Current selected position: %s %.2f %s #%I64u at %.*f, %s",
               symbol, volume, (type==POSITION_TYPE_BUY ? "Buy" : "Sell"), ticket, digits, price, TimeMscToString(time));
   /*
   결과:
   Trade request result: retcode: 10009, deal: 2778100901, order: 2803905975
   Current selected position: EURUSD 0.10 Buy #2803905975 at 1.10672, 2024.09.02 12:09:51.239
   */
  }
//+------------------------------------------------------------------+
//| 말리세컨드로 시간을 반환                                            |
//+------------------------------------------------------------------+
string TimeMscToString(const long time_msc, int flags=TIME_DATE|TIME_MINUTES|TIME_SECONDS)
  {
   return(TimeToString(time_msc/1000, flags) + "." + IntegerToString(time_msc %1000, 3, '0'));
  }