初心者の方からの質問 MQL5 MT5 MetaTrader 5 - ページ 733

[Artyom Trishkin]

Vitaly Muzichenko:
あなたの"ArraySortBubbleTwoDims"へ。

どう呼ぶんだ？

[Artyom Trishkin]

Vitaly Muzichenko:

あなたの「ArraySortBubbleTwoDims」へ。

とにかく、ループを拡張して、問題は解決しました。しかし、やはり標準的な関数の形で正規解が欲しいところです

取り除く

[Artyom Trishkin]

Vitaly Muzichenko:

あなたの「ArraySortBubbleTwoDims」へ。

とにかく、ループを拡張して、問題は解決しました。しかし、やはり標準的な関数の形で正規解が欲しいところです

スクリプトを確認中。

//+------------------------------------------------------------------+
//|                                                    sTestSort.mq5 |
//|              Copyright 2017, Artem A. Trishkin, Skype artmedia70 |
//|                       https://login.mql5.com/ru/users/artmedia70 |
//+------------------------------------------------------------------+
#property copyright "Copyright 2017, Artem A. Trishkin, Skype artmedia70"
#property link      "https://login.mql5.com/ru/users/artmedia70"
#property version   "1.00"
//---
#define TWO_DIM   (2)
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//---
   double array[][TWO_DIM];
   ArrayResize(array,10);
   for(uchar i=0; i<10; i++) {
      array[i][0]=i*10;
      array[i][1]=rand();
      }
   Print("Перед сортировкой");
   for(uchar i=0; i<10; i++) Print("array[",i,"][0]=",array[i][0],", array[",i,"][1]=",array[i][1]);
   Print("Сортировка по первому измерению по возрастанию");
   ArraySortBubbleTwoDims(array);
   for(uchar i=0; i<10; i++) Print("array[",i,"][0]=",array[i][0],", array[",i,"][1]=",array[i][1]);
   Print("Сортировка по первому измерению по убыванию");
   ArraySortBubbleTwoDims(array,0,1);
   for(uchar i=0; i<10; i++) Print("array[",i,"][0]=",array[i][0],", array[",i,"][1]=",array[i][1]);
   //---
   Print("Сортировка по второму измерению по возрастанию");
   ArraySortBubbleTwoDims(array,1);
   for(uchar i=0; i<10; i++) Print("array[",i,"][0]=",array[i][0],", array[",i,"][1]=",array[i][1]);
   Print("Сортировка по второму измерению по убыванию");
   ArraySortBubbleTwoDims(array,1,1);
   for(uchar i=0; i<10; i++) Print("array[",i,"][0]=",array[i][0],", array[",i,"][1]=",array[i][1]);
  }
//+------------------------------------------------------------------+
//| Пузырьковая сортировка двумерного массива                        |
//+------------------------------------------------------------------+
template<typename T>
void ArraySortBubbleTwoDims(T& array[][TWO_DIM], int sort_dimension=0, int sort_direction=0) {
   T     t=0;
   int   k=ArrayRange(array,1);    // Количество колонок
   int   n=ArrayRange(array,0);    // Количество строк
  
   //---
   if(sort_dimension<0) sort_dimension=0;
   if(sort_dimension>k) sort_dimension=k;
   //---
   for(int i=n-1; i>0; i--) {
      for(int j=0; j<i; j++) {
         //--- по возрастанию
         if(sort_direction==0) {
            if(array[j][sort_dimension]>array[j+1][sort_dimension]) {
               for(int e=0; e<k; e++) {
                  t=array[j][e];
                  array[j][e]=array[j+1][e];
                  array[j+1][e]=t;
                  }
               }
            }
         //--- по убыванию
         else {
            if(array[j][sort_dimension]<array[j+1][sort_dimension]) {
               for(int e=0; e<k; e++) {
                  t=array[j][e];
                  array[j][e]=array[j+1][e];
                  array[j+1][e]=t;
                  }
               }
            }
         }
      }
}
//+------------------------------------------------------------------+

[Vitaly Muzichenko]

Artyom Trishkin:
スクリプトを確認中。

ありがとうございます、でも私のコードはマジックです(

Error: 'mas' - parameter conversion not allowed e.mq5 2129 25

[Artyom Trishkin]

Vitaly Muzichenko:

ありがとうございます、でも私のコードはマジックです(

Error: 'mas' - parameter conversion not allowed e.mq5 2129 25

あなたのmasは二次元の大きさ3です。2個必要です。

[Vitaly Muzichenko]

Artyom Trishkin:
あなたのmasは2次元が3です。2個必要です。

結論から言うと

#define TWO_DIM (3)

void PosBySort(double &mas[][3])

ありがとうございました。

[dzhabrailov]

mql5の勉強に苦労しているのですが、金融の部分が分からないので、何を書けばいいのかすら分からないことに気づきました。基本的な知識はあるが、どう使っていいかわからない。同じ状況に陥った善良な人たちに、どのように出口を見出したのか、アドバイスをお願いします。

[Alexey Viktorov]

dzhabrailov:
mql5の勉強に苦労しているのですが、金融の部分が理解できていないことに気づき、何を書けばいいのかもわからなくなりました。基本的な知識はあるが、どう使っていいかわからない。同じ境遇の善良な人たちにアドバイスしてあげてください。

金融パートとはどういう意味ですか？トレーディング機能？OrderSend() は、整理する方法が明確ではありません？

[dzhabrailov]

それこそ、安く仕入れて高く売れるとは限りませんよね。取引に参入するタイミングと撤退するタイミングなど、そういうことです。

[Alexey Viktorov]

dzhabrailov:
それこそ明確なのですが、常に安く仕入れて高く売るというわけにはいきません。取引に参入するタイミングと撤退するタイミングなど、そういうことです。

まあ、これはプログラミングという概念にはないんですけどね。これがトレーディングの技術です。しかし、私はそのようなトレーニングが成功するとは思っていません。