オブジェクトの可視性

void OnStart()
 {
//---
  string highlevel="PreviousDayHigh";
  string lowlevel="PreviousDayLow";
  double prevHigh;           // 昨日の高値
  double prevLow;           // 昨日の安値
  double highs[],lows[];     // 高安値の配列
 
//--- 最終エラ—をリセットする
  ResetLastError();
//--- 毎日の時間軸の最後の 2 つの高値を取得する
  int highsgot=CopyHigh(Symbol(),PERIOD_D1,0,2,highs);
  if(highsgot>0) // 複製が成功
    {
    Print("High prices for the last 2 days were obtained successfully");
     prevHigh=highs[0]; // 昨日の高値
    Print("prevHigh = ",prevHigh);
    if(ObjectFind(0,highlevel)<0) // highlevel オブジェクトが見つからない
       {
        ObjectCreate(0,highlevel,OBJ_HLINE,0,0,0); // 水平線オブジェクトを作成する
       }
    //--- highlevel 線の価格レベルの値を設定する
    ObjectSetDouble(0,highlevel,OBJPROP_PRICE,0,prevHigh);
    //--- 可視を PERIOD_M10 及び PERIOD_H4 に設定する
    ObjectSetInteger(0,highlevel,OBJPROP_TIMEFRAMES,OBJ_PERIOD_M10|OBJ_PERIOD_H4);
    }
  else
    {
    Print("Could not get High prices over the past 2 days, Error = ",GetLastError());
    }
 
//--- 最終エラ—をリセットする
  ResetLastError();
//--- 1 日時間軸の 2 日の安値を取得する
  int lowsgot=CopyLow(Symbol(),PERIOD_D1,0,2,lows);
  if(lowsgot>0) // 複製が成功
    {
    Print("Low prices for the last 2 days were obtained successfully");
     prevLow=lows[0]; // 昨日の安値
    Print("prevLow = ",prevLow);
    if(ObjectFind(0,lowlevel)<0) // lowlevel オブジェクトが見つからない
       {
        ObjectCreate(0,lowlevel,OBJ_HLINE,0,0,0); // 水平線オブジェクトを作成する
       }
    //--- lowlevel 線の価格レベルの値を設定する
    ObjectSetDouble(0,lowlevel,OBJPROP_PRICE,0,prevLow);
    //--- 可視を PERIOD_M10 及び PERIOD_H4 に設定する
    ObjectSetInteger(0,lowlevel,OBJPROP_TIMEFRAMES,OBJ_PERIOD_M10|OBJ_PERIOD_H4);
    }
  else Print("Could not get Low prices for the last 2 days, Error = ",GetLastError());
 
  ChartRedraw(0); // チャートの再描画を強制する
 }