serveur vps - page 4
Vous manquez des opportunités de trading :
- Applications de trading gratuites
- Plus de 8 000 signaux à copier
- Actualités économiques pour explorer les marchés financiers
Inscription
Se connecter
Vous acceptez la politique du site Web et les conditions d'utilisation
Si vous n'avez pas de compte, veuillez vous inscrire
et s'il n'y a pas d'internet, il n'y aura pas de tiques. La fonction OnTick ne fonctionne pas ?
Aussi correct. Je suis en quelque sorte bloqué sur la connexion au serveur de trading. Bien sûr, vous avez raison - pas d'internet, pas de tics - personne ne négocie nulle part.
Oui, merci)
Une autre question. Pouvez-vous me dire comment sélectionner dans l'historique les commandes de la dernière semaine ?
Oui, merci)
Une autre question. Pouvez-vous me dire comment sélectionner les commandes de la dernière semaine dans l'historique?
Qui utilise les commandes maintenant ? Il est préférable d'analyser les transactions. Voici un exemple de demande de transactions à partir de l'historique :
//| HistoryDealGetTicket.mq5 |
//| Copyright 2016, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link "https://www.mql5.com"
#property version "1.000"
#property script_show_inputs
//---
input datetime from_date=D'2016.09.20 11:11:00';
input datetime to_date=D'2016.09.20 11:40:00';
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
ulong deal_ticket; // тикет сделки
ulong order_ticket; // тикет ордера,по которому была совершена сделка
datetime transaction_time; // время совершения сделки
long deal_type; // тип торговой операции
long deal_entry; // направление сделки
long position_ID; // идентификатор позиции
string deal_description; // описание операции
double volume; // объем операции
string symbol; // по какому символу была сделка
////--- установим начальную и конечную дату для запроса истории сделок
// datetime from_date=0; // с самого начала
// datetime to_date=TimeCurrent();// по текущий момент
//--- запросим историрю сделок в указанном интервале
HistorySelect(from_date,to_date);
//--- общее количество в списке сделок
int deals=HistoryDealsTotal();
//--- теперь обработаем каждую сделку
for(int i=0;i<deals;i++)
{
deal_ticket=HistoryDealGetTicket(i);
volume=HistoryDealGetDouble(deal_ticket,DEAL_VOLUME);
transaction_time=(datetime)HistoryDealGetInteger(deal_ticket,DEAL_TIME);
order_ticket=HistoryDealGetInteger(deal_ticket,DEAL_ORDER);
deal_type=HistoryDealGetInteger(deal_ticket,DEAL_TYPE);
deal_entry=HistoryDealGetInteger(deal_ticket,DEAL_ENTRY);
symbol=HistoryDealGetString(deal_ticket,DEAL_SYMBOL);
position_ID=HistoryDealGetInteger(deal_ticket,DEAL_POSITION_ID);
deal_description=GetDealDescription(deal_entry,deal_type,volume,symbol,order_ticket,position_ID);
//--- сделаем красивое форматирование для номера сделки
string print_index=StringFormat("% 3d",i);
//--- выведем информацию по сделке
Print(print_index+": deal #",deal_ticket," at ",transaction_time,deal_description);
}
}
//+------------------------------------------------------------------+
//| Возвращает строковое описание операции |
//+------------------------------------------------------------------+
string GetDealDescription(long deal_entry,long deal_type,double volume,string symbol,long ticket,long pos_ID)
{
string descr;
//---
switch(deal_entry)
{
case DEAL_ENTRY_IN: descr="Вход в рынок, "; break;
case DEAL_ENTRY_OUT: descr="Выход из рынка, "; break;
case DEAL_ENTRY_INOUT: descr="Разворот, "; break;
case DEAL_ENTRY_OUT_BY: descr="Закрытие встречной позицией, "; break;
}
//---
switch(deal_type)
{
case DEAL_TYPE_BALANCE: return ("balance");
case DEAL_TYPE_CREDIT: return ("credit");
case DEAL_TYPE_CHARGE: return ("charge");
case DEAL_TYPE_CORRECTION: return ("correction");
case DEAL_TYPE_BUY: descr+="buy"; break;
case DEAL_TYPE_SELL: descr+="sell"; break;
case DEAL_TYPE_BONUS: return ("bonus");
case DEAL_TYPE_COMMISSION: return ("additional commission");
case DEAL_TYPE_COMMISSION_DAILY: return ("daily commission");
case DEAL_TYPE_COMMISSION_MONTHLY: return ("monthly commission");
case DEAL_TYPE_COMMISSION_AGENT_DAILY: return ("daily agent commission");
case DEAL_TYPE_COMMISSION_AGENT_MONTHLY: return ("monthly agent commission");
case DEAL_TYPE_INTEREST: return ("interest rate");
case DEAL_TYPE_BUY_CANCELED: descr+="cancelled buy deal"; break;
case DEAL_TYPE_SELL_CANCELED: descr+="cancelled sell deal"; break;
}
descr=StringFormat("%s %G %s (order #%d, position ID %d)",
descr, // текущее описание
volume, // объем сделки
symbol, // инструмент сделки
ticket, // тикет ордера,вызвавшего сделку
pos_ID // ID позиции, в которой участвовала сделка
);
return(descr);
//---
}
//+------------------------------------------------------------------+
Qui utilise les mandats de nos jours ? Il est préférable d'analyser les transactions. Voici un exemple de demande de transactions dans l'histoire :
Merci, mais je dois passer à la mql4. Je ne veux pas encore passer à mql5. Je me suis en quelque sorte habitué à MT4.
Pour les paresseux et ceux qui sont étrangers au progrès :MQL4 et MetaTrader 4
ahaha... Merci. Il y a encore beaucoup de gens qui restent sur MT4. Ce que tout le monde aime... Je ne discute pas, il y a des fonctionnalités utiles sur MT5, mais je n'aime pas le fait que vous ne pouvez pas ouvrir deux positions différentes dans des directions différentes avec des tickets différents sur le même symbole.
D'où vient ce nihilisme ? Vous devez ouvrir un terminal MetaTrader 5 avant de pouvoir parler :). Le terminal MetaTrader 5 propose depuis longtemps DEUX types de comptes de trading : le netting et le hedging (le hedging étant "deux positions différentes dans des directions différentes avec des ticks différents sur le même symbole").
D'où vient ce nihilisme ? Vous devez ouvrir un terminal MetaTrader 5 avant de pouvoir parler :). Le terminal MetaTrader 5 propose depuis longtemps DEUX types de comptes de trading : le netting et le hedging (le hedging étant "deux positions différentes dans des directions différentes avec des ticks différents sur le même symbole").
Je ne savais pas pour la haie. Merci. (gloussements) Je vais jeter un coup d'oeil maintenant.
Comment ouvrir des comptes de couverture :système de comptabilisation des positions de couverture,
pas de case à cocher "Utiliser la couverture" disponible ...( Peut-être un ancien terminal ?