Questions des débutants MQL5 MT5 MetaTrader 5 - page 1124

Nouveau commentaire
 
macleta:
Merci,ndd c'est quoi?

Je n'ai pas suivi, je n'ai pas tout remplacé. C'est une macro.

#define  ndd(A) NormalizeDouble(A, _Digits)
 
Alexey Viktorov:

Je n'ai pas gardé de trace, je n'ai pas tout remplacé. C'est une macro.

Merci. (gloussements)
 
Pouvez-vous me dire comment connaître la dernière position ouverte par son numéro magique, peut-être existe-t-il une fonction qui renvoie la valeur du lot de la dernière position ouverte ? J'en ai besoin sur mql5
 
astrologer Аполонов:
Veuillez me conseiller sur la façon de trouver la dernière position ouverte par numéro magique, peut-être existe-t-il une fonction qui renvoie la valeur du lot de la dernière position ouverte ? J'en ai besoin sur mql5

Il y a plusieurs façons de procéder, alors veuillez préciser : Le compte de trading est-il de type hedge ou netting, auquel cas vous avez besoin de connaître la position : le conseiller ouvre-t-il une position et a-t-il besoin de connaître les paramètres de sa dernière position ouverte ?

 
astrologer Аполонов:
Pouvez-vous me dire comment connaître la dernière position ouverte par numéro magique, peut-être existe-t-il une fonction qui renvoie la valeur du lot de la dernière position ouverte ? J'en ai besoin sur mql5

Exemple n° 1 :

//+------------------------------------------------------------------+
//|                                             Trading engine 3.mq5 |
//|                              Copyright © 2019, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2019, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.000"
/*
   barabashkakvn Trading engine 3.042
*/
#include <Trade\SymbolInfo.mqh>
//---
CSymbolInfo    m_symbol;                     // object of CSymbolInfo class
//--- input parameters
input ulong    InpMagic             = 200;         // Magic number
//---
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   if(!m_symbol.Name(Symbol())) // sets symbol name
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");
      return(INIT_FAILED);
     }
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---

  }
//+------------------------------------------------------------------+
//| TradeTransaction function                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- get transaction type as enumeration value
   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//--- if transaction is result of addition of the transaction in history
   if(type==TRADE_TRANSACTION_DEAL_ADD)
     {
      long     deal_ticket       =0;
      long     deal_order        =0;
      long     deal_time         =0;
      long     deal_time_msc     =0;
      long     deal_type         =-1;
      long     deal_entry        =-1;
      long     deal_magic        =0;
      long     deal_reason       =-1;
      long     deal_position_id  =0;
      double   deal_volume       =0.0;
      double   deal_price        =0.0;
      double   deal_commission   =0.0;
      double   deal_swap         =0.0;
      double   deal_profit       =0.0;
      string   deal_symbol       ="";
      string   deal_comment      ="";
      string   deal_external_id  ="";
      if(HistoryDealSelect(trans.deal))
        {
         deal_ticket       =HistoryDealGetInteger(trans.deal,DEAL_TICKET);
         deal_order        =HistoryDealGetInteger(trans.deal,DEAL_ORDER);
         deal_time         =HistoryDealGetInteger(trans.deal,DEAL_TIME);
         deal_time_msc     =HistoryDealGetInteger(trans.deal,DEAL_TIME_MSC);
         deal_type         =HistoryDealGetInteger(trans.deal,DEAL_TYPE);
         deal_entry        =HistoryDealGetInteger(trans.deal,DEAL_ENTRY);
         deal_magic        =HistoryDealGetInteger(trans.deal,DEAL_MAGIC);
         deal_reason       =HistoryDealGetInteger(trans.deal,DEAL_REASON);
         deal_position_id  =HistoryDealGetInteger(trans.deal,DEAL_POSITION_ID);

         deal_volume       =HistoryDealGetDouble(trans.deal,DEAL_VOLUME);
         deal_price        =HistoryDealGetDouble(trans.deal,DEAL_PRICE);
         deal_commission   =HistoryDealGetDouble(trans.deal,DEAL_COMMISSION);
         deal_swap         =HistoryDealGetDouble(trans.deal,DEAL_SWAP);
         deal_profit       =HistoryDealGetDouble(trans.deal,DEAL_PROFIT);

         deal_symbol       =HistoryDealGetString(trans.deal,DEAL_SYMBOL);
         deal_comment      =HistoryDealGetString(trans.deal,DEAL_COMMENT);
         deal_external_id  =HistoryDealGetString(trans.deal,DEAL_EXTERNAL_ID);
        }
      else
         return;
      ENUM_DEAL_ENTRY enum_deal_entry=(ENUM_DEAL_ENTRY)deal_entry;
      if(deal_symbol==m_symbol.Name() && deal_magic==InpMagic)
        {
         if(deal_type==DEAL_TYPE_BUY || deal_type==DEAL_TYPE_SELL)
           {
            if(deal_entry==DEAL_ENTRY_IN)
              {
               Print("Last DEAL IN volume: ",DoubleToString(deal_volume,2));
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+

Dans OnTradeTransaction nous attrapons une transaction avec le type

TRANSACTION_COMMERCIALE_ADDITIONNELLE

Ajouter la transaction à l'historique. Cela se fait à la suite de l'exécution d'un ordre ou de transactions sur le solde du compte.

 
   if(type==TRADE_TRANSACTION_DEAL_ADD)


s'assurer que c'est notre symbole et notre magie :

      if(deal_symbol==m_symbol.Name() && deal_magic==InpMagic)


Recherchez une transaction d'achat ou de vente:

         if(deal_type==DEAL_TYPE_BUY || deal_type==DEAL_TYPE_SELL)


s'assurer que ce commerce est

DEAL_ENTRY_IN.

Entrée sur le marché

 
            if(deal_entry==DEAL_ENTRY_IN)
Dossiers :
Test.mq5  10 kb
 
astrologer Аполонов:
Veuillez me conseiller sur la façon de trouver la dernière position ouverte par numéro magique, peut-être existe-t-il une fonction qui renvoie la valeur du lot de la dernière position ouverte ? J'en ai besoin sur mql5

Option n° 2 - contourner la liste des articles :

//+------------------------------------------------------------------+
//|                                             Trading engine 3.mq5 |
//|                              Copyright © 2019, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2019, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.000"
/*
   barabashkakvn Trading engine 3.042
*/
#include <Trade\PositionInfo.mqh>
#include <Trade\SymbolInfo.mqh>
//---
CPositionInfo  m_position;                   // object of CPositionInfo class
CSymbolInfo    m_symbol;                     // object of CSymbolInfo class
//--- input parameters
input ulong    InpMagic             = 200;         // Magic number
//---
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   if(!m_symbol.Name(Symbol())) // sets symbol name
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");
      return(INIT_FAILED);
     }
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   ulong    last_time   = 0;
   double   last_volume = 0.0;

   for(int i=PositionsTotal()-1; i>=0; i--)
      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)
           {
            if(m_position.TimeMsc()>last_time)
              {
               last_time=m_position.TimeMsc();
               last_volume=m_position.Volume();
              }
           }
   if(last_volume>0.0)
      Print("Last POSITIONS volume: ",DoubleToString(last_volume,2));
  }
//+------------------------------------------------------------------+
//| TradeTransaction function                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {

//---
  }
//+------------------------------------------------------------------+


Parcourez la liste des postes

   for(int i=PositionsTotal()-1; i>=0; i--)


recherche le temps d'ouverture de la position la plus longue en millisecondes

TempsMsc

Obtient letemps d'ouverture d'une position en millisecondes depuis le 01.01.1970

 
            if(m_position.TimeMsc()>last_time)
              {
               last_time=m_position.TimeMsc();
               last_volume=m_position.Volume();
              }


vérifier - si le volume est supérieur à "0.0" - la position a été trouvée :

   if(last_volume>0.0)
      Print("Last POSITIONS volume: ",DoubleToString(last_volume,2));
Dossiers :
Test.mq5  6 kb
 
Alexey Viktorov:

Pour la taille de la perte, voici la fonction

Il suffit de remplacer SL par TP

Apparemment, il y a un double risque en pourcentage des fonds disponibles. Comment puis-je définir un montant spécifique de profit en argent, par exemple 1,5 ?
double RiskLots(double risk, int TP)
{
  double RiskMony, Lot;
  double tickValue = SymbolInfoDouble(_Symbol, SYMBOL_TRADE_TICK_VALUE);
  double margin = SymbolInfoDouble(_Symbol, SYMBOL_MARGIN_INITIAL);
  double FreeMargin = AccountInfoDouble(ACCOUNT_MARGIN_FREE);
    long accountLeverage = AccountInfoInteger(ACCOUNT_LEVERAGE);
    RiskMony = floor(FreeMargin*risk/100);
     Lot = NormalizeDouble(RiskMony*_Point/NormalizeDouble(TP*_Point*tickValue, _Digits), 2);
     //
  return(Lot);
}
 
Благодарю Vladimir Karputov:

Exemple n° 1 :

Dans OnTradeTransaction nous attrapons une transaction avec le type

TRANSACTION_COMMERCIALE_ADDITIONNELLE

Ajouter la transaction à l'historique. Cela se fait à la suite de l'exécution d'un ordre ou de transactions sur le solde du compte.


s'assurer que c'est notre symbole et notre magie :


regardez s'il s'agit d'une transaction d'ACHAT ou de VENTE:


s'assurer que ce commerce est

DEAL_ENTRY_IN.

l'entrée sur le marché
 
macleta:
Apparemment, il s'agit d'un double risque en pourcentage des fonds disponibles. Comment puis-je définir un montant spécifique de profit en argent, par exemple 1,5 ?

Eh bien, voici la ligne

    RiskMony = floor(FreeMargin*risk/100);
Il suffit de mettre un nombre au lieu d'une formule et ...
 

Comment convertir, la position de la souris, pendant, mais sans lancer ?

ChartTimeOnDropped
1...111711181119112011211122112311241125112611271128112911301131...1503
Nouveau commentaire