Caractéristiques du langage mql5, subtilités et techniques - page 196

Nouveau commentaire
 
fxsaber:

Aucune suggestion quant à l'origine de l'heure (idem pour moi). Peut-être cela dépend-il du fuseau horaire.


Ce n'est plus intéressant.

Aucune idée. J'ai Moscou. Avec GMT pas une heure... Pas d'autres pensées.

 

Andrey Khatimlianskii:

Forum sur le trading, les systèmes de trading automatisé et les tests de stratégies de trading

Comment utiliser le contrôle automatique des erreurs dans le terminal ?

Renat Fatkhullin, 2021.01.22 16:12

Il existe un moyen non documenté de réinitialiser de force les journaux sur le disque via Print(NULL).

Cool !

 
Andrey Khatimlianskii:

Dans ma hâte de partager sans vérifier.


Que se passe-t-il si la chaîne est d'abord mise à zéro et ensuite imprimée ?
 

Option pour afficher (ne pas activer) le graphique (MT5 seulement)

// Показывает (не активирует) данный чарт.
bool ChartShow( const long Chart )
{
  const bool IsDocked = ChartGetInteger(Chart, CHART_IS_DOCKED);
  
  return(ChartSetInteger(Chart, CHART_IS_DOCKED, !IsDocked) && 
         ChartSetInteger(Chart, CHART_IS_DOCKED, IsDocked) &&
         ChartGetInteger(Chart, CHART_WINDOW_HANDLE));  
}


Exemple d'utilisation.

// Переключает чарты клавишами клавиатуры '<'/'>'.

#define  KEY_LEFT2 188  // '<'
#define  KEY_RIGHT2 190 // '>'

int GetExpertCharts( long &Charts[], const string ExpertName = NULL )
{
  int Amount = 0;
  
  for (long Chart = ChartFirst(); Chart != -1; Chart = ChartNext(Chart))
    if ((ExpertName == NULL ) || (ChartGetString(Chart, CHART_EXPERT_NAME) == ExpertName))
    {
      Amount = ArrayResize(Charts, Amount + 1, 10);
      
      Charts[Amount - 1] = Chart;
    }
    
  return(ArrayResize(Charts, Amount));
}

long ChartNextShow( const long Chart, const int Step = 1 )
{
  long ResChart = Chart;
  
  long Charts[];  
  const int Size = GetExpertCharts(Charts);
  
  if ((Size > 1) && (bool)(Step % Size))
    for (int i = 0; i < Size; i++)  
      if (Charts[i] == Chart)
      {
        ResChart = Charts[(i + ((Step > 0) ? Step : (Size - ((-Step) % Size)))) % Size];
        
        ChartShow(ResChart); // https://www.mql5.com/ru/forum/170952/page196#comment_20841674
        
        break;
      }

  return(ResChart);  
}

void OnChartEvent( const int id, const long &lparam, const double&, const string& ) 
{         
  static long Chart = ChartID();
  
  if (id == CHARTEVENT_KEYDOWN) 
    switch ((int)lparam)
    {
    case KEY_LEFT2:
      Chart = ChartNextShow(Chart, -1); // Показали чарт слева
      break;

    case KEY_RIGHT2:
      Chart = ChartNextShow(Chart); // Показали чарт справа
      break;
    }
}

Malheureusement, aucune variante d'activation de carte n'a pu être trouvée. Afficher seulement.

 
Solution à un vieux problème. 
/*
// https://www.mql5.com/ru/forum/1111/page2863#comment_18591240
#define VALUE 10

#define MACROS

#ifdef MACROS
  // Нужно VALUE увеличить в два раза.
#endif
*/

// https://www.mql5.com/ru/forum/1111/page2965#comment_20841725
#define  MACRO(  x, y, z )       enum nn##z { y = x };
#define  MACRO2( x, y )          MACRO( x, y, __LINE__ )

// https://www.mql5.com/ru/forum/1111/page2866#comment_18603128
#define  VALUE 10

MACRO2(VALUE, VALUE_TMP) // VALUE_TMP - поле enum, поэтому имя не должно повторяться.
#undef  VALUE
#define  VALUE (VALUE_TMP * 2)

void OnStart()
{
  Print(VALUE);
}

Cette option est meilleure que celle-là.

#define  MACRO3(x, y)            const int y = x;

MACRO3(VALUE, VALUE_TMP)

Il n'a pas besoin de variable. Toutes les valeurs sont définies au moment de la compilation. Merci @A100!

 
fxsaber:

Malheureusement, aucune option d'activation des cartes n'a pu être trouvée. Seulement l'affichage.

Je ne comprends pas......... c'est de ça que tu parles ? C'est un scénario.


ps ; Et qu'est-ce que c'est

  const bool IsDocked = ChartGetInteger(Chart, CHART_IS_DOCKED);

Je ne le trouve pas dans la documentation...

Dossiers :
200.mq5  2 kb
 
Alexey Viktorov:

ps ; Qu'est-ce que c'est

Je ne le trouve pas dans la documentation...

C'est ALT+D sur la carte.

 
Alexey Viktorov:

Je ne comprends pas......... vous parlez de ça ? C'est un scénario.

Merci, j'en ai trop fait. Bien sûr, au-dessus, il y a la gestion des graphiques qui ne pouvait pas être réalisée auparavant. Mais mon objectif était différent.

// Активирует данный чарт.
bool ChartActivate( const long Chart )
{
  return(ChartSetInteger(Chart, CHART_BRING_TO_TOP, true) && ChartGetInteger(Chart, CHART_WINDOW_HANDLE));
}


Exemple d'utilisation.

// Переключает чарты с одним и тем же советником клавишами клавиатуры '<'/'>'.

void ChartNextActivate( const int Step = 1, const bool Expert = true )
{
  long Charts[];  
  // https://www.mql5.com/ru/forum/170952/page196#comment_20841674
  const int Size = GetExpertCharts(Charts, Expert ? ChartGetString(0, CHART_EXPERT_NAME) : NULL);
  const long Chart = ChartID();
  
  if ((Size > 1) && (bool)(Step % Size))
    for (int i = 0; i < Size; i++)  
      if (Charts[i] == Chart)
      {
        // https://www.mql5.com/ru/forum/170952/page197#comment_20845067
        ChartActivate(Charts[(i + ((Step > 0) ? Step : (Size - ((-Step) % Size)))) % Size]);
        
        break;
      }

  return;  
}

void OnChartEvent( const int id, const long &lparam, const double&, const string& ) 
{         
  if (id == CHARTEVENT_KEYDOWN) 
    switch ((int)lparam)
    {
    case KEY_LEFT2:
      ChartNextActivate(-1);
      break;

    case KEY_RIGHT2:
      ChartNextActivate();      
      break;
    }
}
1...189190191192193194195196197198199200201202203...247
Nouveau commentaire