//--- paramètres de ressources graphiques
string ExtResName="Resource";
int ExtResWidth=100;
int ExtResHeight=100;
uint ExtResData[];
int ExtResSize=ExtResWidth*ExtResHeight;
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
ResetLastError();
//--- définit la taille du tableau de pixels
if(ArrayResize(ExtResData,ExtResSize)!=ExtResSize)
{
Print("ArrayResize() failed. Error code: ",GetLastError());
return;
}
//--- remplit le tableau de pixels avec une couleur transparente et crée une ressource graphique basée sur celle-ci
ArrayInitialize(ExtResData,0x00FFFFFF);
if(!ResourceCreate(ExtResName,ExtResData,ExtResWidth,ExtResHeight,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE))
{
Print("ResourceCreate() failed. Error code: ",GetLastError());
return;
}
Print("Size of created recource array: ",ExtResData.Size());
//--- vérifie la ressource graphique créée.
//--- récupère l'heure et le prix de la barre actuelle
MqlTick tick={};
if(!SymbolInfoTick(Symbol(),tick))
{
Print("SymbolInfoTick() failed. Error code: ",GetLastError());
return;
}
//--- Crée l'objet Bitmap en utilisant les coordonnées du dernier prix et de l'heure du tick
string obj_name="Bitmap";
if(!ObjectCreate(0,obj_name,OBJ_BITMAP,0,tick.time,tick.bid))
{
Print("ObjectCreate() failed. Error code: ",GetLastError());
return;
}
//--- définit la largeur et la hauteur de l'objet bitmap créé égales à la largeur et à la hauteur de la ressource graphique.
//--- définit le point d'ancrage de l'objet en son centre.
ObjectSetInteger(0,obj_name,OBJPROP_XSIZE,ExtResWidth);
ObjectSetInteger(0,obj_name,OBJPROP_YSIZE,ExtResHeight);
ObjectSetInteger(0,obj_name,OBJPROP_ANCHOR,ANCHOR_CENTER);
//--- spécifie la ressource graphique créée précédemment pour l'objet bitmap en tant que fichier image
//--- dans ce cas, afin d'indiquer le nom de la ressource graphique utilisée, il faut ajouter "::" avant son nom
ObjectSetString(0,obj_name,OBJPROP_BMPFILE,"::"+ExtResName);
//--- définit la couleur GreenYellow avec une transparence de 200
uint clr=ColorToARGB(clrGreenYellow,200);
//--- remplit tout le tableau de pixels de la ressource graphique avec la couleur définie
ArrayInitialize(ExtResData,clr);
//--- dessine la grille en utilisant la couleur DodgerBlue
for(int x=0;x<ExtResWidth;x+=9)
LineVertical(x,0,ExtResHeight,ColorToARGB(clrDodgerBlue,200));
for(int y=0;y<ExtResHeight;y+=9)
LineHorizontal(0,ExtResWidth,y,ColorToARGB(clrDodgerBlue,200));
//--- met à jour les données de la ressource graphique
Update(ExtResName,ExtResData,ExtResWidth,ExtResHeight,true);
//--- attente de 3 secondes avant de supprimer la ressource et l'objet graphique
Print("Wait 3 seconds before deleting the resource and graphic object");
Sleep(3000);
//--- enregistre la ressource dans le fichier
ResetLastError();
if(!ResourceSave("::"+ExtResName,"ResourceSave\\"+ExtResName+".bmp"))
{
Print("ResourceSave() failed. Error code: ",GetLastError());
return;
}
//--- supprime la ressource et l'image de l'objet graphique
if(!ResourceFree("::"+ExtResName))
{
Print("ResourceFree() failed. Error code: ",GetLastError());
return;
}
if(!ObjectDelete(0,obj_name))
{
Print("ObjectDelete() failed. Error code: ",GetLastError());
return;
}
//--- crée maintenant l'objet "Étiquette graphique" en utilisant les coordonnées du prix et de l'heure du dernier tick décalées vers la gauche de la largeur de l'image
//--- obtient les coordonnées de l'écran en utilisant le prix et l'heure du dernier tick précédemment reçus
int x=0,y=0;
if(!ChartTimePriceToXY(0,0,tick.time,tick.bid,x,y))
{
Print("ChartTimePriceToXY() failed. Error code: ",GetLastError());
return;
}
obj_name="BitmapLabel";
if(!ObjectCreate(0,obj_name,OBJ_BITMAP_LABEL,0,0,0))
{
Print("ObjectCreate() failed. Error code: ",GetLastError());
return;
}
//--- définit le point d'ancrage de l'objet en son centre.
ObjectSetInteger(0,obj_name,OBJPROP_ANCHOR,ANCHOR_CENTER);
//--- fixe les coordonnées du prix et de l'heure du dernier tick, décalées vers la gauche de la largeur de l'image, sur l'objet étiquette graphique
ObjectSetInteger(0,obj_name,OBJPROP_XDISTANCE,x-ExtResWidth);
ObjectSetInteger(0,obj_name,OBJPROP_YDISTANCE,y);
//--- spécifie la ressource, préalablement enregistrée sous forme d'image BMP, pour l'objet d'étiquette graphique sous forme de fichier image
ObjectSetString(0,obj_name,OBJPROP_BMPFILE,"\\Files\\ResourceSave\\"+ExtResName+".bmp");
//--- met à jour le graphique
ChartRedraw();
//--- attente de 3 secondes avant de supprimer l'objet étiquette graphique
Print("Wait 3 seconds before deleting the new graphic object");
Sleep(3000);
if(!ObjectDelete(0,obj_name))
Print("ObjectDelete() failed. Error code: ",GetLastError());
}
//+------------------------------------------------------------------+
//| Met à jour les données des ressources graphiques |
//+------------------------------------------------------------------+
void Update(const string res_name,const uint &pixel_data[],const uint width,const uint height,const bool redraw)
{
//--- laisser si aucune dimension n'est passée
if(width==0 || height==0)
return;
//--- met à jour les données des ressources et redessine le graphique
if(ResourceCreate(res_name,pixel_data,width,height,0,0,0,COLOR_FORMAT_ARGB_NORMALIZE) && redraw)
ChartRedraw();
}
//+------------------------------------------------------------------+
//| Dessine une ligne verticale |
//+------------------------------------------------------------------+
void LineVertical(int x,int y1,int y2,const uint clr)
{
int tmp;
//--- tri sur Y
if(y1>y2)
{
tmp=y1;
y1 =y2;
y2 =tmp;
}
//--- ligne en dehors des limites de l'image
if(y2<0 || y1>=ExtResHeight || x<0 || x>=ExtResWidth)
return;
//--- reste dans les limites de l'image
if(y1<0)
y1=0;
if(y2>=ExtResHeight)
y2=ExtResHeight-1;
//--- dessine la ligne
int index=y1*ExtResWidth+x;
for(int i=y1; i<=y2; i++,index+=ExtResWidth)
ExtResData[index]=clr;
}
//+------------------------------------------------------------------+
//| Dessine une ligne horizontale |
//+------------------------------------------------------------------+
void LineHorizontal(int x1,int x2,int y,const uint clr)
{
int tmp;
//--- tri sur X
if(x1>x2)
{
tmp=x1;
x1 =x2;
x2 =tmp;
}
//--- ligne en dehors des limites de l'image
if(x2<0 || x1>=ExtResWidth || y<0 || y>=ExtResHeight)
return;
//--- reste dans les limites de l'image
if(x1<0)
x1=0;
if(x2>=ExtResWidth)
x2=ExtResWidth-1;
//--- dessine la ligne
ArrayFill(ExtResData,y*ExtResWidth+x1,(x2-x1)+1,clr);
}
|