DocumentaciónSecciones
Manual de referencia de MQL5Funciones de cadenas de caracteresStringAdd 

StringAdd

La función añade una subcadena especificada al final de una cadena en el lugar.

bool  StringAdd(
   string&  string_var,        // cadena a la que añadimos
   string   add_substring      // cadena que se añade
   );

Parámetros

string_var

[in][out]  Cadena que va a ser completada con otra.

add_substring

[in]  Cadena que va a ser añadida al final de la cadena fuente.

Valor devuelto

En caso de éxito devuelve true, de lo contrario devuelve false. Para obtener el código de error hay que llamar a la función GetLastError().

Ejemplo:

void OnStart()
  {
   long length=1000000;
   string a="a",b="b",c;
//--- primer método
   uint start=GetTickCount(),stop;
   long i;
   for(i=0;i<length;i++)
     {
      c=a+b;
     }
   stop=GetTickCount();
   Print("time for 'c = a + b' = ",(stop-start)," milliseconds, i = ",i);
 
//--- segundo método
   start=GetTickCount();
   for(i=0;i<length;i++)
     {
      StringAdd(a,b);
     }
   stop=GetTickCount();
   Print("time for 'StringAdd(a,b)' = ",(stop-start)," milliseconds, i = ",i);
 
//--- tercer método
   start=GetTickCount();
   a="a"; // volvemos a inicializar la variable a
   for(i=0;i<length;i++)
     {
      StringConcatenate(c,a,b);
     }
   stop=GetTickCount();
   Print("time for 'StringConcatenate(c,a,b)' = ",(stop-start),"milliseconds, i = ",i);
  }

Véase también

StringConcatenate, StringSplit, StringSubstr