DocumentaciónSecciones
Manual de referencia de MQL5Obtención de información de mercadoSymbolInfoTick 

SymbolInfoTick

Devuelve precios corrientes para un símbolo especificado en una variable del tipo MqlTick.

bool  SymbolInfoTick(
   string    symbol,     // símbolo
   MqlTick&  tick        // referencia a una estructura
   );

Parámetros

symbol

[in]  Nombre del símbolo.

tick

[out]  Referencia a una estructura del tipo MqlTick, en la que serán colocados los precios corrientes y la hora de la última renovación de precios.

Valor devuelto

Devuelve true en caso de éxito, de lo contrario devuelve false.

Ejemplo:

#define SYMBOL_NAME "EURUSD"
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- declaramos un array con una estructura tipo MqlTick de dimensionalidad 1
   MqlTick tick[1]={};
   
//--- obtenemos los precios más recientes para el símbolo SYMBOL_NAME en la estructura MqlTick
   if(!SymbolInfoTick(SYMBOL_NAME, tick[0]))
     {
      Print("SymbolInfoTick() failed. Error ", GetLastError());
      return;
     }
 
//--- mostramos los datos obtenidos en el diario de registro
   PrintFormat("Latest price data for the '%s' symbol:", SYMBOL_NAME);
   ArrayPrint(tick);
   /*
   resultado:
   Latest price data for the 'EURUSD' symbol:
                    [time]   [bid]   [ask] [last] [volume]    [time_msc] [flags] [volume_real]
   [0] 2024.05.17 23:58:54 1.08685 1.08695 0.0000        0 1715990334319       6       0.00000
   */
  }