//--- descripción
#property description "El script crea el objeto gráfico \"Etiqueta de texto\"."
//--- mostramos la ventana de los parámetros de entrada durante el arranque del script
#property script_show_inputs
//--- los parámetros de entrada del script
input string InpName="Label"; // Nombre de la etiqueta
input int InpX=150; // Distancia por el eje X
input int InpY=150; // Distancia por el eje Y
input string InpFont="Arial"; // Fuente
input int InpFontSize=14; // Tamaño de la fuente
input color InpColor=clrRed; // Color
input double InpAngle=0.0; // Ángulo de inclinación en grados
input ENUM_ANCHOR_POINT InpAnchor=ANCHOR_CENTER; // Modo de anclaje
input bool InpBack=false; // Objeto al fondo
input bool InpSelection=true; // Seleccionar para mover
input bool InpHidden=true; // Ocultar en la lista de objetos
input long InpZOrder=0; // Prioridad para el clic del ratón
//+------------------------------------------------------------------+
//| Crea la etiqueta de texto |
//+------------------------------------------------------------------+
bool LabelCreate(const long chart_ID=0, // ID del gráfico
const string name="Label", // nombre de la etiqueta
const int sub_window=0, // número de subventana
const int x=0, // coordenada por el eje X
const int y=0, // coordenada por el eje Y
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER, // esquina del gráfico para el enlace
const string text="Label", // texto
const string font="Arial", // fuente
const int font_size=10, // tamaño de la fuente
const color clr=clrRed, // color
const double angle=0.0, // inclinación del texto
const ENUM_ANCHOR_POINT anchor=ANCHOR_LEFT_UPPER, // modo de anclaje
const bool back=false, // al fondo
const bool selection=false, // seleccionar para mover
const bool hidden=true, // ocultar en la lista de objetos
const long z_order=0) //prioridad para el clic del ratón
{
//--- anulamos el valor del error
ResetLastError();
//--- creamos la etiqueta de texto
if(!ObjectCreate(chart_ID,name,OBJ_LABEL,sub_window,0,0))
{
Print(__FUNCTION__,
": ¡Fallo al crear la etiqueta de texto! Código del error = ",GetLastError());
return(false);
}
//--- establecemos las coordenadas de la etiqueta
ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x);
ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y);
//--- establecemos la esquina del gráfico respecto a la cual van a determinarse las coordenadas del punto
ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner);
//--- ponemos el texto
ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);
//--- establecemos la fuente del texto
ObjectSetString(chart_ID,name,OBJPROP_FONT,font);
//--- establecemos el tamaño del texto
ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size);
//--- establecemos el ángulo de inclinación del texto
ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);
//--- establecemos el modo de anclaje
ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor);
//--- establecemos el color
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- mostramos en el primer plano (false) o al fondo (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- activar (true) o desactivar (false) el modo de desplazamiento de la etiqueta con ratón
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- ocultamos (true) o mostramos (false) el nombre del objeto gráfico en la lista de objetos
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- establecemos la prioridad para obtener el evento de cliquear sobre el gráfico
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Mueve la etiqueta de texto |
//+------------------------------------------------------------------+
bool LabelMove(const long chart_ID=0, // ID del gráfico
const string name="Label", // nombre de la etiqueta
const int x=0, // coordenada por el eje X
const int y=0) // coordenada por el eje Y
{
//--- anulamos el valor del error
ResetLastError();
//--- movemos la etiqueta de texto
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x))
{
Print(__FUNCTION__,
": ¡Fallo al mover la coordenada X de la etiqueta! Código del error = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y))
{
Print(__FUNCTION__,
": ¡Fallo al mover la coordenada Y de la etiqueta! Código del error = ",GetLastError());
return(false);
}
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Cambia la esquina del gráfico para el enlace de la etiqueta |
//+------------------------------------------------------------------+
bool LabelChangeCorner(const long chart_ID=0, // ID del gráfico
const string name="Label", // nombre de la etiqueta
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER) // esquina del gráfico para el enlace
{
//--- anulamos el valor del error
ResetLastError();
//--- cambiamos la esquina de anclaje
if(!ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner))
{
Print(__FUNCTION__,
": ¡Fallo al cambiar la esquina de anclaje! Código del error = ",GetLastError());
return(false);
}
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Cambia el texto del objeto |
//+------------------------------------------------------------------+
bool LabelTextChange(const long chart_ID=0, // ID del gráfico
const string name="Label", // nombre del objeto
const string text="Text") // texto
{
//--- anulamos el valor del error
ResetLastError();
//--- cambiamos el texto del objeto
if(!ObjectSetString(chart_ID,name,OBJPROP_TEXT,text))
{
Print(__FUNCTION__,
": ¡Fallo al cambiar el texto! Código del error = ",GetLastError());
return(false);
}
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Elimina la etiqueta de texto |
//+------------------------------------------------------------------+
bool LabelDelete(const long chart_ID=0, // ID del gráfico
const string name="Label") // nombre de la etiqueta
{
//--- anulamos el valor del error
ResetLastError();
//--- eliminamos la etiqueta
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": ¡Fallo al eliminar la etiqueta de texto! Código del error = ",GetLastError());
return(false);
}
//--- ejecución con éxito
return(true);
}
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- recordamos las coordenadas de la etiqueta en las variables locales
int x=InpX;
int y=InpY;
//--- tamaño de la ventana del gráfico
long x_distance;
long y_distance;
//--- definimos las dimensiones de la ventana
if(!ChartGetInteger(0,CHART_WIDTH_IN_PIXELS,0,x_distance))
{
Print("¡Fallo al obtener el ancho del gráfico! Código del error = ",GetLastError());
return;
}
if(!ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,0,y_distance))
{
Print("¡Fallo al obtener el alto del gráfico! Código del error = ",GetLastError());
return;
}
//--- comprobamos si los parámetros de entrada son correctos
if(InpX<0 || InpX>x_distance-1 || InpY<0 || InpY>y_distance-1)
{
Print("¡Error. Los parámetros de entrada no son correctos!");
return;
}
//--- preparamos el texto inicial para la etiqueta
string text;
StringConcatenate(text,"La esquina superior izquierda: ",x,",",y);
//--- creamos la etiqueta de texto en el gráfico
if(!LabelCreate(0,InpName,0,InpX,InpY,CORNER_LEFT_UPPER,text,InpFont,InpFontSize,
InpColor,InpAngle,InpAnchor,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- redibujamos el gráfico y esperamos medio segundo
ChartRedraw();
Sleep(500);
//--- vamos a mover la etiqueta y a la vez cambiar su texto
//--- número de iteraciones por ejes
int h_steps=(int)(x_distance/2-InpX);
int v_steps=(int)(y_distance/2-InpY);
//--- movemos la etiqueta abajo
for(int i=0;i<v_steps;i++)
{
//--- cambiamos la coordenada
y+=2;
//--- movemos la etiqueta y cambiamos su texto
MoveAndTextChange(x,y,"La esquina superior izquierda: ");
}
//--- retardo de medio segundo
Sleep(500);
//--- movemos la etiqueta a la derecha
for(int i=0;i<h_steps;i++)
{
//--- cambiamos la coordenada
x+=2;
//--- movemos la etiqueta y cambiamos su texto
MoveAndTextChange(x,y,"La esquina superior izquierda: ");
}
//--- retardo de medio segundo
Sleep(500);
//--- movemos la etiqueta para arriba
for(int i=0;i<v_steps;i++)
{
//--- cambiamos la coordenada
y-=2;
//--- movemos la etiqueta y cambiamos su texto
MoveAndTextChange(x,y,"La esquina superior izquierda: ");
}
//--- retardo de medio segundo
Sleep(500);
//--- movemos la etiqueta a la izquierda
for(int i=0;i<h_steps;i++)
{
//--- cambiamos la coordenada
x-=2;
//--- movemos la etiqueta y cambiamos su texto
MoveAndTextChange(x,y,"La esquina superior izquierda: ");
}
//--- retardo de medio segundo
Sleep(500);
//--- ahora movemos el punto mediante el cambio de la esquina de enlace
//--- movemos a la esquina inferior izquierda
if(!LabelChangeCorner(0,InpName,CORNER_LEFT_LOWER))
return;
//--- cambiamos el texto de la etiqueta
StringConcatenate(text,"La esquina inferior izquierda: ",x,",",y);
if(!LabelTextChange(0,InpName,text))
return;
//--- redibujamos el gráfico y esperamos dos segundos
ChartRedraw();
Sleep(2000);
//--- movemos a la esquina inferior derecha
if(!LabelChangeCorner(0,InpName,CORNER_RIGHT_LOWER))
return;
//--- cambiamos el texto de la etiqueta
StringConcatenate(text,"La esquina inferior derecha: ",x,",",y);
if(!LabelTextChange(0,InpName,text))
return;
//--- redibujamos el gráfico y esperamos dos segundos
ChartRedraw();
Sleep(2000);
//--- movemos a la esquina superior derecha
if(!LabelChangeCorner(0,InpName,CORNER_RIGHT_UPPER))
return;
//--- cambiamos el texto de la etiqueta
StringConcatenate(text,"La esquina superior derecha: ",x,",",y);
if(!LabelTextChange(0,InpName,text))
return;
//--- redibujamos el gráfico y esperamos dos segundos
ChartRedraw();
Sleep(2000);
//--- movemos a la esquina superior izquierda
if(!LabelChangeCorner(0,InpName,CORNER_LEFT_UPPER))
return;
//--- cambiamos el texto de la etiqueta
StringConcatenate(text,"La esquina superior izquierda: ",x,",",y);
if(!LabelTextChange(0,InpName,text))
return;
//--- redibujamos el gráfico y esperamos dos segundos
ChartRedraw();
Sleep(2000);
//--- eliminamos la etiqueta
LabelDelete(0,InpName);
//--- redibujamos el gráfico y esperamos medio segundo
ChartRedraw();
Sleep(500);
//---
}
//+------------------------------------------------------------------+
//| La función mueve el objeto y cambia su texto |
//+------------------------------------------------------------------+
bool MoveAndTextChange(const int x,const int y,string text)
{
//--- movemos la etiqueta
if(!LabelMove(0,InpName,x,y))
return(false);
//--- cambiamos el texto de la etiqueta
StringConcatenate(text,text,x,",",y);
if(!LabelTextChange(0,InpName,text))
return(false);
//--- comprobamos si el trabajo del script ha sido finalizado forzosamente
if(IsStopped())
return(false);
//--- redibujamos el gráfico
ChartRedraw();
// retardo de 0,01 segundo
Sleep(10);
//--- salida de la función
return(true);
}
|