Twin Range Filter by colinmck

To get access to MT4 version please click here.

• - This is the exact conversion from TradingView: "Twin Range Filter" by "colinmck".
• - This is a light-load processing and non-repaint indicator.
• - All input options are available. 
• - Buffers are available for processing in EAs.
• - You can message in private chat for further changes you need.

Here is the code a sample EA that operated based on signals coming from the indicator:

#include <Trade\Trade.mqh>
CTrade trade;
int handle_twr=0;

input group "EA Setting"
input int magic_number=123456; //magic number
input double fixed_lot_size=0.01; // select fixed lot size

input group "TWR setting"
input ENUM_APPLIED_PRICE src = PRICE_CLOSE; //Source
input int per1 = 27; //Fast period
input double mult1 = 1.6; //Fast range
input int per2 = 55; //Slow period
input double mult2 = 2; //Slow range
input bool showAlerts=true; //use Alerts


int OnInit()
  {
   trade.SetExpertMagicNumber(magic_number);
   handle_twr=iCustom(_Symbol, PERIOD_CURRENT, "Market/Twin Range Filter by colinmck", src, per1, mult1, per2, mult2, showAlerts);
   if(handle_twr==INVALID_HANDLE) 
   {
      Print("Indicator not found!");
      return INIT_FAILED;
   }
   return(INIT_SUCCEEDED);
  }

void OnDeinit(const int reason)
  {
   IndicatorRelease(handle_twr);
  }

void OnTick()
  {
   if(!isNewBar()) return;
   ///////////////////////////////////////////////////////////////////
   bool buy_condition=true;
   buy_condition &= (BuyCount()==0);
   buy_condition &= (IsTWRBuy(1));
   if(buy_condition) 
   {
      CloseSell();
      Buy();
   }
      
   bool sell_condition=true;
   sell_condition &= (SellCount()==0);
   sell_condition &= (IsTWRSell(1));
   if(sell_condition) 
   {
      CloseBuy();
      Sell();
   }
  }

bool IsTWRBuy(int i)
{
   double array[];
   ArraySetAsSeries(array, true);
   CopyBuffer(handle_twr, 12, i, 1, array);
   return array[0]!=EMPTY_VALUE;
}

bool IsTWRSell(int i)
{
   double array[];
   ArraySetAsSeries(array, true);
   CopyBuffer(handle_twr, 13, i, 1, array);
   return array[0]!=EMPTY_VALUE;
}

int BuyCount()
{
   int buy=0;
   for(int i=0;i<PositionsTotal();i++)
   {
      ulong ticket=PositionGetTicket(i);
      if(ticket==0) continue;
      if(PositionGetInteger(POSITION_TYPE) != POSITION_TYPE_BUY) continue;
      if(PositionGetInteger(POSITION_MAGIC) != magic_number) continue;
      buy++;
   }  
   return buy;
}

int SellCount()
{
   int sell=0;
   for(int i=0;i<PositionsTotal();i++)
   {
      ulong ticket=PositionGetTicket(i);
      if(ticket==0) continue;
      if(PositionGetInteger(POSITION_TYPE) != POSITION_TYPE_SELL) continue;
      if(PositionGetInteger(POSITION_MAGIC) != magic_number) continue;
      sell++;
   }  
   return sell;
}


void Buy()
{
   double Ask=SymbolInfoDouble(_Symbol, SYMBOL_ASK);
   if(!trade.Buy(fixed_lot_size, _Symbol, Ask, 0, 0, ""))
   {
      Print("Error executing order: ", GetLastError());
      //ExpertRemove();
   }
}

void Sell()
{
   double Bid=SymbolInfoDouble(_Symbol, SYMBOL_BID);
   if(!trade.Sell(fixed_lot_size, _Symbol, Bid, 0, 0, ""))
   {
      Print("Error executing order: ", GetLastError());
      //ExpertRemove();
   }
}


void CloseBuy()
{
   for(int i=PositionsTotal()-1;i>=0;i--)
   {
      ulong ticket=PositionGetTicket(i);
      if(ticket==0) continue;
      if(PositionGetInteger(POSITION_TYPE) != POSITION_TYPE_BUY) continue;
      if(PositionGetInteger(POSITION_MAGIC) != magic_number) continue;
      if(trade.PositionClose(ticket)==false)
      {
         Print("Error closing position: ", GetLastError());
         //ExpertRemove();
      }
   }  
}

void CloseSell()
{
   for(int i=PositionsTotal()-1;i>=0;i--)
   {
      ulong ticket=PositionGetTicket(i);
      if(ticket==0) continue;
      if(PositionGetInteger(POSITION_TYPE) != POSITION_TYPE_SELL) continue;
      if(PositionGetInteger(POSITION_MAGIC) != magic_number) continue;
      if(trade.PositionClose(ticket)==false)
      {
         Print("Error closing position: ", GetLastError());
         //ExpertRemove();
      }
   }  
}

datetime timer=NULL;
bool isNewBar()
{
   datetime candle_start_time= (int)(TimeCurrent()/(PeriodSeconds()))*PeriodSeconds();
   if(timer==NULL) {}
   else if(timer==candle_start_time) return false;
   timer=candle_start_time;
   return true;
}