MQL5 ReferansıStandart KütüphaneMathematicsBulanık mantıkÜyelik fonksiyonlarıCTriangularMembershipFunction

CTriangularMembershipFunction

X1, X2 ve X3 parametrelerine sahip üçgen üyelik fonksiyonlarıyla çalışmak için tasarlanmıştır.

Açıklama

Fonksiyon, bir üyelik fonksiyonunu üçgen biçiminde ayarlar. Bu en basit olan ve en sık uygulanan üyelik fonksiyonu biçimidir.

fuzzy_triangular_functions

Çizelge çizmek için oluşturulmuş bir örnek kod aşağıda verilmiştir.

Bildirim

class CTriangularMembershipFuncion : public IMembershipFunction

Başlık

#include <Math\Fuzzy\membershipfunction.mqh>

Kalıtım hiyerarşisi

CObject

IMembershipFunction

CTriangularMembershipFunction

Sınıf yöntemleri

Sınıf yöntemi	Açıklama
X1	İlk noktanın X eksenindeki değerini alır.
X2	İkinci noktanın X eksenindeki değerini alır.
X3	Üçüncü noktanın X eksenindeki değerini alır.
ToNormalMF	Bir üçgen üyelik fonksiyonunu Gaussyen fonksiyona dönüştürür.
GetValue	Üyelik fonksiyonunun değerini belli bir argümana göre hesaplar.

Sınıftan türetilen yöntemler CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Örnek

//+------------------------------------------------------------------+
//|                                 TriangularMembershipFunction.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Üyelik fonksiyonlarını oluştur
CTriangularMembershipFunction func1(0,2,5);
CTriangularMembershipFunction func2(0,5,10);
CTriangularMembershipFunction func3(8,8,10);
//--- üyelik fonksiyonları için örtüler oluştur
double TriangularMembershipFunction1(double x) { return(func1.GetValue(x)); }
double TriangularMembershipFunction2(double x) { return(func2.GetValue(x)); }
double TriangularMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- grafiği oluştur
   CGraphic graphic;
   if(!graphic.Create(0,"TriangularMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"TriangularMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("TriangularMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- eğri oluştur
   graphic.CurveAdd(TriangularMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[0, 2, 5]");
   graphic.CurveAdd(TriangularMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[0, 5, 10]");
   graphic.CurveAdd(TriangularMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[8, 8, 10]");
//--- X-ekseninin özelliklerini ayarla
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- Y-ekseninin özelliklerini ayarla
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- çiz
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue