//+------------------------------------------------------------------+
//| Demo_iVIDyA.mq5 |
//| Copyright 2000-2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "Gösterge, iVolumes teknik göstergesi için tamponlardan"
#property description "nasıl veri alınacağını göstermektedir."
#property description "Göstergenin hesaplanmasında kullanılacak sembol ve periyot,"
#property description "symbol ve period parametreleri ile ayarlanır."
#property description "İşleyicinin oluşturulması yöntemi 'type' parametresi ile ayarlanır (fonksiyon tipi)."
#property description "Diğer tüm parametreler standart Variable Index Dynamic Average göstergesindeki gibidir."
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots 1
//--- iVIDyA grafiği
#property indicator_label1 "iVIDyA"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrBlue
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//+------------------------------------------------------------------+
//| İşleyici oluşturma yöntemleri için bir sayım |
//+------------------------------------------------------------------+
enum Creation
{
Call_iVIDyA, // iVIDyA kullan
Call_IndicatorCreate // IndicatorCreate kullan
};
//--- giriş parametreleri
input Creation type=Call_iVIDyA; // fonksiyon tipi
input int cmo_period=15; // Chande Momentum periyodu
input int ema_period=12; // düzleştirme faktörünün periyodu
input int ma_shift=0; // kaydırma değeri
input ENUM_APPLIED_PRICE applied_price=PRICE_CLOSE; // fiyat tipi
input string symbol=" "; // sembol
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // zaman aralığı
//--- gösterge tamponu
double iVIDyABuffer[];
//--- iVIDyA göstergesinin tanıtıcı değerini saklamak için bir değişken
int handle;
//--- kayıt için değişken
string name=symbol;
//--- çizelge üzerindeki gösterge ismi
string short_name;
//--- Variable Index Dynamic Average göstergesindeki değerlerin sayısını koruyacağız
int bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- dizilerin gösterge tamponlarına atanması
SetIndexBuffer(0,iVIDyABuffer,INDICATOR_DATA);
//--- kaydırma değerini ayarla
PlotIndexSetInteger(0,PLOT_SHIFT,ma_shift);
//--- göstergenin çizileceği sembolü ayarla
name=symbol;
//--- sağa ve sola doğru olan boşlukları sil
StringTrimRight(name);
StringTrimLeft(name);
//--- sonuçta 'name' dizgisi sıfır uzunluğa sahipse
if(StringLen(name)==0)
{
//--- göstergenin tutturulduğu çizelge sembolünü al
name=_Symbol;
}
//--- göstergenin tanıtıcı değerini oluştur
if(type==Call_iVIDyA)
handle=iVIDyA(name,period,cmo_period,ema_period,ma_shift,applied_price);
else
{
//--- yapıyı gösterge parametreleriyle doldur
MqlParam pars[4];
//--- Chande Momentum periyodu
pars[0].type=TYPE_INT;
pars[0].integer_value=cmo_period;
//--- düzleştirme faktörünün periyodu
pars[1].type=TYPE_INT;
pars[1].integer_value=ema_period;
//--- kaydırma değeri
pars[2].type=TYPE_INT;
pars[2].integer_value=ma_shift;
//--- fiyat tipi
pars[3].type=TYPE_INT;
pars[3].integer_value=applied_price;
handle=IndicatorCreate(name,period,IND_VIDYA,4,pars);
}
//--- işleyici oluşturulmadıysa
if(handle==INVALID_HANDLE)
{
//--- hatayı belirt ve hata kodunu al
PrintFormat("iVIDyA göstergesinin tanıtıcı değeri, %s/%s sembolü için oluşturulamadı, hata kodu %d",
name,
EnumToString(period),
GetLastError());
//--- gösterge erken durduruldu
return(INIT_FAILED);
}
//--- Variable Index Dynamic Average göstergesinin hesaplandığı sembol ve zaman aralığı değerlerini göster
short_name=StringFormat("iVIDyA(%s/%s, %d, %d, %d, %s)",name,EnumToString(period),
cmo_period,ema_period,ma_shift,EnumToString(applied_price));
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- göstergenin normal yolla başlatılması
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- iVIDyA göstergesinden kopyalanan değerlerin sayısı
int values_to_copy;
//--- göstergede hesaplanan değerlerin sayısını belirle
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() %d dönüşü yaptı, hata kodu %d",calculated,GetLastError());
return(0);
}
//--- bu, gösterge değerlerinin ilk hesaplanması ise veya iVIDyA göstergesinin değerleri değiştiyse
//--- veya göstergeyi iki veya daha fazla çubuk için hesaplamak gerekiyorsa (yani fiyat geçmişi değiştiyse)
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- verilen sembol ve periyot için iVIDyABuffer dizisinin büyüklüğü iVIDyA göstergesinin değerlerinden fazlaysa, her şeyi kopyalamayacağız
//--- Aksi durumda, gösterge tamponlarının büyüklüklerinden daha az kopyalama yaparız
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- Bu, gösterge değerlerinin daha önce hesaplandığı anlamına geliyor OnCalculate() fonksiyonu daha önce çağrılmış)
//--- hesaplama için bir çubuktan fazlası eklenmeyecek
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- diziyi Variable Index Dynamic Average göstergesinin değerleriyle doldur
//--- FillArraysFromBuffer fonksiyonu false dönüşü yaparsa, bilgi henüz kullanılabilir değildir, çık
if(!FillArrayFromBuffer(iVIDyABuffer,ma_shift,handle,values_to_copy)) return(0);
//--- mesajı oluştur
string comm=StringFormat("%s ==> göstergedeki gncellenen değer %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- servis mesajını çizelgede göster
Comment(comm);
//--- Variable Index Dynamic Average indicator
bars_calculated=calculated;
//--- bir sonraki çağrı için prev_calculated değerine dönüş yap
return(rates_total);
}
//+------------------------------------------------------------------+
//| iVIDyA göstergesi ile, gösterge tamponlarının doldurulması |
//+------------------------------------------------------------------+
bool FillArrayFromBuffer(double &vidya_buffer[],// Variable Index Dynamic Average değerleri için gösterge tamponu
int v_shift, // kaydırma değeri
int ind_handle, // iVIDyA göstergesi
int amount // kopyalanan değerlerin sayısı
)
{
//--- hata kodunu sıfırla
ResetLastError();
//--- iVIDyABuffer dizisinin bir kısmını 0 indisli tamponun değerleriyle doldur
if(CopyBuffer(ind_handle,0,-v_shift,amount,vidya_buffer)<0)
{
//--- kopyalama başarısız ise hata kodu al
PrintFormat("iVIDyA göstergesinin verileri kopyalanamadı, hata kodu %d",GetLastError());
//--- sıfır sonuç ile çık - gösterge hesaplanmamış sayılacak
return(false);
}
//--- herşey yolunda
return(true);
}
//+------------------------------------------------------------------+
//| Indicator deinitialization function |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- göstergeyi sildikten sonra çizelgeyi temizle
Comment("");
}
|