MQL5 Sihirbazı - RSI Göstergesiyle Onaylı Olarak Çekiç / Asılı Adam Mum Modellerine Dayalı Ticaret Sinyalleri - MetaTrader 5 için Uzman Danışman

MQL5 Sihirbazı, müşteri terminali ile birlikte sağlanan Standart Kütüphane sınıflarına dayanan hazır Uzman Danışmanlar oluşturmaya olanak sağlar (ayrıntılar için bkz. MQL5 Sihirbazında Hazır Uzman Danışmanlar Oluşturma). Ticaret fikirlerinizi hızlı bir şekilde test etmenize olanak tanır, tek ihtiyacınız olan kendi ticaret sinyalleri sınıfınızı oluşturmaktır. Bu sınıfın yapısı ve örneği, MQL5 Sihirbazı: Ticaret Sinyali Modülü Nasıl Oluşturulur? makalesinde bulunur.

Ana fikir şudur: ticaret sinyalleri sınıfı CExpertSignal'dan türer, sizin LongCondition() ve ShortCondition() sanal metotlarına kendi yöntemlerinizi uygulamanız gerekir.

"Стратегии Лучших Трейдеров Мира" (Dünyanın En İyi Yatırımcılarının Stratejileri) adlı kitapta (Rusça), incelenen birçok ticaret stratejisi vardır ve çoğunluklu olarak Stochastic, CCI, MFI ve RSI osilatörleriyle onaylı terse dönüş mum modellerine odaklanır.

En iyi yol, mum modellerinin oluşumunu kontrol etmek için CExpertSignal'dan türeyen ayrı bir sınıf oluşturmaktır. Mum modelleri tarafından oluşturulan ticaret sinyallerinin onayı için CCandlePattern'dan türeyen sınıf yazmak ve gerekli özellikleri (örneğin, osilatörler tarafından onay) oraya eklemek yeterlidir.

Bu bölümde RSI göstergesiyle onaylı olarak çekiç / asılı adam terse dönüş mum modellerini temel alan strateji ele alınacak. Ticaret sinyali modülü CCandlePattern sınıfına dayanır, mum modelleriyle ticaret sinyalleri oluşturmak için kullanımının basit bir örneğidir.

1. Çekiç ve asılı adam terse dönüş mum modelleri

1.1. Çekiç

Çekiç modeli, düşüş trendi sırasında, küçük gövdeye ve uzun alt gölgeye sahip mum izlendiğinde meydana gelir. Çekiçin ortaya çıkması, ayı piyasasının egemenliğinin sona erdiğinin güçlü bir işaretidir.

Mum gövdesinin tipi önemli değildir, ancak boğa tipi çekiç, daha güçlü terse dönüş potansiyeline işaret eder. Genellikle çekiç önceki mumun düşük seviyesinin yakınında oluşur. Alt gölge ne kadar büyük, gövde ve üst gölge de ne kadar küçük olursa, terse dönüş potansiyeli o kadar yüksek olur.

Şekil 1. Çekiç mum modeli

Çekiç modelinin tanınması, CCandlePattern sınıfının CheckPatternHammer() metodunda yer alır:

//+------------------------------------------------------------------+
//| çekiç mum modelinin oluşumunu kontrol et                         |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternHammer()
  {
//--- çekiç
   if((MidPoint(1)<CloseAvg(2))                                 && // düşüş trendi
      (MathMin(Open(1),Close(1))>(High(1)-(High(1)-Low(1))/3.0)) && // gövdenin mumun üst 1/3'lük bölümünde olması
      (Close(1)<Close(2)) && (Open(1)<Open(2)))                    // gövde gapi
      return(true);
//---
   return(false);
  }

1.2. Asılı adam

Asılı adam modeli, yükseliş trendi sırasında, küçük gövdeye ve uzun üst gölgeye sahip mum izlendiğinde meydana gelir. Asılı adamın ortaya çıkması, boğa piyasasının egemenliğinin sona erdiğinin güçlü bir işaretidir.

Mum gövdesinin tipi önemli değildir, ancak ayı tipi çekiç, daha güçlü terse dönüş potansiyeline işaret eder. Genellikle asılı adam önceki mumun yüksek seviyesinin yakınında oluşur. Alt gölge ne kadar büyük, gövde ve üst gölge de ne kadar küçük olursa, terse dönüş potansiyeli o kadar yüksek olur.

Şekil 2. Asılı adam mum modeli

Asılı adam modelinin tanınması, CCandlePattern sınıfının CheckPatternHangingMan() metodunda yer alır:

//+------------------------------------------------------------------+
//| asılı adam mum modelinin oluşumunu kontrol et                    |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternHangingMan()
  {
//--- asılı adam
   if((MidPoint(1)>CloseAvg(2))                                && // yüskeliş trendi
      (MathMin(Open(1),Close(1)>(High(1)-(High(1)-Low(1))/3.0)) && // gövdenin mumun üst 1/3'lük bölümünde olması
      (Close(1)>Close(2)) && (Open(1)>Open(2))))                  // gövde gapi
      return(true);
//---
   return(false);
  }

2. RSI göstergesi tarafından onaylanan ticaret sinyalleri

Alış veya satış pozisyonu açma için ticaret sinyalleri RSI göstergesi tarafından onaylanmalıdır. Bunun için RSI'ın değeri alış pozisyonu için 40'den düşük ve satış pozisyonu için 60'den yüksek olmalıdır.

Pozisyonun kapanması da RSI değerlerine bağlıdır. 2 durumda gerçekleşir:

1. RSI karşı kritik seviyeye (alış pozisyonu için 70 ve satış pozisyonu için 30) ulaştığında
2. terse dönüş sinyali onaylanmazsa (RSI şu seviyelere ulaştığında: alış pozisyonu için 30 ve satış pozisyonu için 70)

Şekil 3. RSI göstergesiyle onaylanan çekiç mum modeli

• int CH_HM_RSI::LongCondition() - alış pozisyonu açma (80 geri döndürür) ve satış pozisyonunu kapatma (40 geri döndürür) için koşulları kontrol eder;
  
• int CH_HM_RSI::ShortCondition() - satış pozisyonu açma (80 geri döndürür) ve alış pozisyonunu kapatma (40 geri döndürür) için koşulları kontrol eder.

2.1. Alış pozisyonu açma/Satış pozisyonunu kapatma

1. Alış pozisyonu açma sinyali, çekiç mum modelinin oluşması ve oluşan modelin RSI göstergesiyle onaylanmasıyla (RSI(1)<40 (son tamamlanmış çubuğun RSI değeri 40'dan daha düşük olmalıdır)) oluşur.

2. Satış pozisyonunu kapatma sinyali, RSI'ın 70 veya 30 seviyesini yukarı doğru çaprazlamasıyla oluşur.

//+------------------------------------------------------------------+
//| piyasaya giriş ve çıkış koşullarını kontrol et                   |
//| 1) piyasaya giriş (alış pozisyonu açma, result=80)               |
//| 2) piyasadan çıkış (satış pozisyonunu kapatma, result=40)        |
//+------------------------------------------------------------------+
int CH_HM_RSI::LongCondition()
  {
   int result=0;
//--- idx, Uzman Danışmanın çalışma modunu belirlemek için kullanılabilir
//--- idx=0 - bu durumda Uzman Danışman, ticaret koşullarını her tikte kontrol eder
//--- idx=1 - bu durumda Uzman Danışman, ticaret koşullarını yalnızca yeni mumlarda kontrol eder
   int idx   =StartIndex();
//--- alış pozisyonu açma için koşulların kontrolü
//--- çekiç modeli ve RSI<30
  if(CheckCandlestickPattern(CANDLE_PATTERN_HAMMER) && (RSI(1)<40))
     result=80;
//--- satış pozisyonunu kapatma için koşulların kontrolü
//--- sinyal çizgisinin aşırı alış / aşırı satış seviyelerini çaprazlaması (70 veya 30'u yukarı doğru)
  if(((RSI(1)>30) && (RSI(2)<30)) || ((RSI(1)>70) && (RSI(2)<70)))
     result=40;
//--- sonucu geri döndür
   return(result);
  }

2.2. Satış pozisyonu açma/Alış pozisyonunu kapatma

1. Satış pozisyonu açma sinyali, asılı adam mum modelinin oluşması ve oluşan modelin RSI göstergesiyle onaylanmasıyla (RSI(1)>60 (son tamamlanmış çubuğun RSI değeri 60'dan daha yüksek olmalıdır)) oluşur.

2. Alış pozisyonunu kapatma sinyali, RSI'ın 70 veya 30 seviyesini aşağı doğru çaprazlamasıyla oluşur.

//+------------------------------------------------------------------+
//| piyasaya giriş ve çıkış koşullarını kontrol et                   |
//| 1) piyasaya giriş (satış pozisyonu açma, result=80)              |
//| 2) piyasadan çıkış (alış pozisyonunu kapatma, result=40)         |
//+------------------------------------------------------------------+
int CH_HM_RSI::ShortCondition()
  {
   int result=0;
//--- idx, Uzman Danışmanın çalışma modunu belirlemek için kullanılabilir
//--- idx=0 - bu durumda Uzman Danışman, ticaret koşullarını her tikte kontrol eder
//--- idx=1 - bu durumda Uzman Danışman, ticaret koşullarını yalnızca yeni mumlarda kontrol eder
   int idx   =StartIndex();
//--- satış pozisyonu açma için koşulların kontrolü
//--- asılı adam modeli ve RSI>60
  if(CheckCandlestickPattern(CANDLE_PATTERN_HANGING_MAN) && (RSI(1)>60))
     result=80;
//--- alış pozisyonunu kapatma için koşulların kontrolü
//--- sinyal çizgisinin aşırı alış / aşırı satış seviyelerini çaprazlaması (70 veya 30'u aşağı doğru)
   if(((RSI(1)<70) && (RSI(2)>70)) || ((RSI(1)<30) && (RSI(2)>30)))
     result=40;
//--- sonucu geri döndür
   return(result);
  }

2.3. MQL5 Sihirbazını kullanarak Uzman Danışman oluşturma

Uzman Danışman oluşturmak için MQL5 Sihirbazını başlatın:

Şekil 4. MQL5 Sihirbazını kullanarak Uzman Danışman oluşturma

Uzman Danışmanın adını belirtin:

Şekil 5. Uzman Danışmanın genel özellikleri

Ardından, kullanılan ticaret sinyali modüllerini seçmeniz gerekir.

Şekil 6. Uzman Danışmanın sinyal özellikleri

Bizim durumumuzda yalnızca bir ticaret sinyali modülü kullanılacağız.

"Signals based on Hammer/Hanging Man confirmed by RSI" ticaret sinyali modülünün eklenmesi:

Şekil 7. Uzman Danışmanın sinyal özellikleri

Ticaret sinyali modülü eklendi:

Şekil 8. Uzman Danışmanın sinyal özellikleri

Ardından, takip eden durdurucu modülünü seçebilirsiniz, biz onu kullanmayacağız, bu yüzden "Trailing Stop not used" seçeneğini seçtik:

Şekil 9. Uzman Danışmanın takip eden durdurucu özelliği

Şimdi ise bir para yönetimi modülü seçilmesi gerekiyor, biz burada "Trading with fixed trade volume" (Sabit işlem hacmi ile ticaret) kullanacağız:

Şekil 10. Uzman Danışmanın para yönetimi özelliği

"Tamam" düğmesine basarak, oluşturulan Uzman Danışman kodunu elde edeceğiz - kod, expert_AH_HM_RSI.mq5 dosyasına kaydedilir ve bu dosya da terminal_veri_klasörü\MQL5\Experts\ klasörüne yerleştirilir.

Oluşturulan Uzman Danışmanın varsayılan girdi parametreleri:

//--- ana sinyal için girdiler
input int            Signal_ThresholdOpen   =10;     // pozisyon açma için sinyal eşik değeri [0...100]
input int            Signal_ThresholdClose  =10;     // pozisyonu kapatma için sinyal eşik değeri [0...100]
input double         Signal_PriceLevel      =0.0;    // işlemi gerçekleştirmek için fiyat seviyesi
input double         Signal_StopLevel       =50.0;   // Zararı Durdur seviyesi (puan cinsinden)
input double         Signal_TakeLevel       =50.0;   // Kârı Al seviyesi (puan cinsinden)

şu şekilde değiştirilmelidir:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // pozisyon açma için sinyal eşik değeri [0...100]
input int            Signal_ThresholdClose  =20;     // pozisyonu kapatma için sinyal eşik değeri [0...100]
input double         Signal_PriceLevel      =0.0;    // işlemi gerçekleştirmek için fiyat seviyesi
input double         Signal_StopLevel       =0.0;    // Zararı Durdur seviyesi (puan cinsinden)
input double         Signal_TakeLevel       =0.0;    // Kârı Al seviyesi (puan cinsinden)

Signal_ThresholdOpen/Signal_ThresholdClose girdi parametreleri, pozisyonların açılması ve kapanması için eşik seviyelerin belirlenmesine olanak tanır.

Ticaret sinyali modülünün LongCondition() ve ShortCondition() metotlarının kodunda, sabit eşik değerleri şu şekildedir:

• Alış pozisyonu: 80;
• Satış pozisyonu: 40.
  

Signal_StopLevel ve Signal_TakeLevel girdi parametrelerinin değerleri 0 olarak ayarlanmıştır, bu, pozisyonların yalnızca kapanış koşulları mevcut olduğunda kapatılacağı anlamına gelir.

2.4. Geçmiş verileri üzerinde test sonuçları

Uzman Danışmanın geçmiş verileri üzerinde geriye dönük testini ele alalım (EURUSD H1, test aralığı: 2010.01.01-2011.03.03, PeriodRSI=33, MA_period=2).

Uzman Danışman oluşturulurken 0.1 lotluk sabit işlem hacmi kullanıldı (Trading Fixed Lot), Takip Eden Durdurucu algoritması kullanılmadı (Trailing not used).

Şekil 11. RSI göstergesiyle onaylı olarak çekiç / asılı adam mum modellerine dayalı Uzman Danışmanın geçmişe dönük test sonuçları

En iyi girdi parametreleri kümesi, MetaTrader 5 müşteri terminalinin Strateji Sınayıcısı kullanılarak bulunabilir.

MQL5 Sihirbazı tarafından oluşturulan Uzman Danışman kodu, expert_ah_hm_rsi.mq5 dosyasına eklenir.