Библиотеки: TypeToBytes - Статьи и техническая библиотека по автоматическому трейдингу

fxsaber 2016.09.15 05:34 #1

Короткий пример применения библиотеки

Форум по трейдингу, автоматическим торговым системам и тестированию торговых стратегий

Два соседних BookEvent могут дублировать стакан

fxsaber, 2016.09.14 16:29

Советник показывает, когда два соседних стакана являются копиями друг друга

#include <TypeToBytes.mqh> // https://www.mql5.com/ru/code/16280

template <typename T>
bool ArrayEqual( const T &Array1[], const T &Array2[] )
{
  const int Amount = ArraySize(Array1);
  bool Res = (Amount == ArraySize(Array2));

  if (Res)
    for (int i = 0; i < Amount; i++)
      if (_R(Array1[i]) != Array2[i]) // https://www.mql5.com/ru/code/16280
      {
        Res = false;

        break;
      }

  return(Res);
}

template <typename T>
bool ArrayClone( const T &Source[], T &Target[] )
{
  ArrayFree(Target);

  return(ArrayCopy(Target, Source) >= 0);
}

void OnInit( void )
{
  MarketBookAdd(_Symbol);
}

void OnDeinit( const int Reason )
{
  MarketBookRelease(_Symbol);
}

void OnBookEvent( const string &symbol )
{
  static MqlBookInfo PrevBook[];
  MqlBookInfo Book[];

  if ((symbol == _Symbol) && MarketBookGet(symbol, Book))
  {
    if (ArrayEqual(Book, PrevBook))
    {
      if (ArraySize(PrevBook) > 0)
        Alert("Book == PrevBook");
    }
    else
      ArrayClone(Book, PrevBook);
  }
}

Результат

2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:30.896 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:29.406 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:23.151 Test2 (Si-9.16,M1)      Book == PrevBook
2016.09.14 17:24:23.151 Test2 (Si-9.16,M1)      Book == PrevBook

Причин таких ситуаций может быть много: от пропуска MT5 некоторых стаканов, до генерацией самой биржей дубль-стаканов.

Два соседних BookEvent могут Обсуждение статьи "Популяционные алгоритмы Получить начальную и конечную

fxsaber 2016.09.15 08:11 #2

Еще пример

Форум по трейдингу, автоматическим торговым системам и тестированию торговых стратегий

Тестируем 'CopyTicks'

fxsaber, 2016.09.15 10:07

Как другие пользуются CopyTicks - ума не приложу. Нет доверия, к сожалению. Очень сыро.

Советник

#include <TypeToBytes.mqh> // https://www.mql5.com/ru/code/16280

void OnTick( void )
{
  static MqlTick PrevTick;  
  static int Amount = 0;
  
  MqlTick Ticks[];
  
  if (Amount > 0)
  {
    Amount = CopyTicks(_Symbol, Ticks, COPY_TICKS_ALL, PrevTick.time_msc);
    
    int i;
    
    for (i = 0; i < Amount; i++)
      if (_R(Ticks[i]) == PrevTick) // https://www.mql5.com/ru/code/16280
        break;
        
    if (i == Amount)
      Print("В истории (length = " + (string)Amount + ") нет тика, что был на предыдущем Event.");
  }
  else
    Amount = CopyTicks(_Symbol, Ticks, COPY_TICKS_ALL, TimeCurrent() * 1000);
    
  if (Amount > 0)
    PrevTick = Ticks[Amount - 1];  
}

Результат

2016.09.15 11:04:02.810 Test2 (RTS-9.16,M1)     В истории (length = 2) нет тика, что был на предыдущем Event.
2016.09.15 11:03:59.312 Test2 (RTS-9.16,M1)     В истории (length = 13) нет тика, что был на предыдущем Event.
2016.09.15 11:03:59.290 Test2 (RTS-9.16,M1)     В истории (length = 1) нет тика, что был на предыдущем Event.

Тик, что был в истории, на следующем Tick-событии уже отсутствует в истории!

Уважаемые разработчики, доведите до рабочего состояния CopyTicks. Даже простые тесты проваливаются.

Тестируем 'CopyTicks' Получение значений открытого интереса Как работать с тиками

fxsaber 2016.09.20 13:15 #3

Нашел лазейку, позволяющую вместо таких громоздких записей

_W(Tick, Offset, (double)1.23456);     // Записали по найденному смещению значение (double)1.23456
_W(CloneTick, 0, Tick);                // Записали в CloneTick по нулевому смещению значение структурного объекта Tick
_W(Color, 2, (uchar)230);              // Записали по смещению 2 значение (uchar)230.

делать привычные

_W(Tick)[Offset] = 1.23456;             // Записали по найденному смещению значение (double)1.23456
_W(CloneTick)[0] = Tick;                // Записали в CloneTick по нулевому смещению значение структурного объекта Tick
_W(Color)[2] = (uchar)230;              // Записали по смещению 2 значение (uchar)230.

Т.е. существует реальная возможность работать со стандартными типами и простыми структурами, как с массивом, не только в режиме чтения, но и записи!

fxsaber 2016.09.21 19:25 #4

fxsaber:

Нашел лазейку, позволяющую вместо таких громоздких записей

делать привычные

Т.е. существует реальная возможность работать со стандартными типами и простыми структурами, как с массивом, не только в режиме чтения, но и записи!

Опубликован. Теперь для любой переменной (структура или стандартный тип) работает не только чтение, как с массивом, но и ЗАПИСЬ:

_W(AnyVariable)[Pos] = AnyValue; // Записывает по байтовому смещению Pos значение AnyValue в переменную AnyVariable

Догадаться до реализации было непросто - наверное, получился неплохой тест на среднее владение ООП: мне известна только классика для классов.

Если кто знает нечто похожее, поделитесь ссылкой для образования.

Ошибки, баги, вопросы Вопросы по ООП в Вопросы от начинающих MQL5

fxsaber 2016.10.02 17:27 #5

Пример показа байтового содержимого переменной

#include <TypeToBytes.mqh>

#define TOSTRING(A) " " + #A + " = " + (string)A

string BytesToString( const uchar &Bytes[] )
{  
  string Str = "";

  const int Amount = ArraySize(Bytes);
  
  for (int i = 0; i < Amount; i++)
    Str += TOSTRING(i) + "," + TOSTRING(Bytes[i]) + "\n";
    
  return(Str);
}

#define VALUETOSTRING(A) typename(A) + TOSTRING(A) + ":\n" + BytesToString(_R(A).Bytes)

void OnStart()
{
  int Tmp = 1;  
  Print(VALUETOSTRING(Tmp));
  
  Tmp = -1;
  Print(VALUETOSTRING(Tmp));
}

Результат

2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 3, Bytes[i] = 255
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 2, Bytes[i] = 255
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 1, Bytes[i] = 255
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 0, Bytes[i] = 255
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)     int Tmp = -1:
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)     
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 3, Bytes[i] = 0
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 2, Bytes[i] = 0
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 1, Bytes[i] = 0
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)      i = 0, Bytes[i] = 1
2016.10.02 20:26:52.383 Test (RTS-12.16,M1)     int Tmp = 1:

fxsaber 2016.10.11 11:09 #6

Лаконичное сравнения not-a-number double

Форум по трейдингу, автоматическим торговым системам и тестированию торговых стратегий

Как быстро сравнить double и QNaN ?

fxsaber, 2016.10.11 11:14

Прикольно, не знал! Ну тогда так

#include <TypeToBytes.mqh>

double Nan(long bit_value)
  {
   struct L { long   x; } l; l.x=bit_value;
   struct D { double x; } d=(D)l;
   return(d.x);
  }

double QNaN   =Nan(0x7FF7000000000000);  

void OnStart()
{
   if (_R(QNaN)==QNaN) {
      Alert("QNaN is QNaN");
   } else {
      Alert("Ooops");
   }   
}

Ошибки, баги, вопросы Бета-версия платформы MetaTrader 5 Как правильно работать в

fxsaber 2016.10.14 11:34 #7

Пример создания not-a-number double

#include <TypeToBytes.mqh>

void OnStart()
{
  double QNaN = 0;

  _W(QNaN) = 0x7FF7000000000000;

  Print(QNaN);
}

fxsaber 2016.11.10 10:12 #8

Пример новой возможности не касается напрямую библиотеки, но косвенно задевает - на тему структур

Форум по трейдингу, автоматическим торговым системам и тестированию торговых стратегий

MetaEditor build 1463

fxsaber, 2016.11.10 10:42

class PRINTCLASS
{
public:
  template <typename T>
  static void MyPrint( const T &Value )
  {
    T Array[1];

    Array[0] = Value;

    ::ArrayPrint(Array);
  }

  template <typename T>
  static void MyPrint( const T Value )
  {
    ::Print(Value);
  }
};

#define Print(A) PRINTCLASS::MyPrint(A)

void OnStart()
{
  MqlTick Tick;

  SymbolInfoTick(_Symbol, Tick);

  Print(Tick);

  int i = 5;

  Print(i);
}

Print теперь может распечатывать и простые структуры.

Интернет трейдинг на Форексе Как стать брокером

fxsaber 2017.02.10 10:26 #9

fxsaber:
Пример создания not-a-number double

#include <TypeToBytes.mqh>

void OnStart()
{
  double QNaN = 0;

  _W(QNaN) = 0x7FF7000000000000;

  Print(QNaN);
}

Теперь можно иначе

#include <TypeToBytes.mqh>

void OnStart()
{
  double Number = (double)"01.23_example";
  double Nan = (double)"nan";

  Print(Number);
  Print(Nan);

  ArrayPrint(_R(Nan).Bytes); // Распечатали байты

  ulong Num = 0;

  _W(Num) = Nan; // Побайтово скопировали Nan в Num

  PrintFormat("%I64X", Num);
}

Результат

1.23
nan
255 255 255 255 255 255 255 127
7FFFFFFFFFFFFFFF

Требуется решение (специализация шаблонной Математическое округление. Почему я не могу

Rashid Umarov 2017.02.10 19:22 #10

fxsaber:

Теперь можно иначе

#include <TypeToBytes.mqh>

void OnStart()
{
  double Number = (double)"01.23_example";
  double Nan = (double)"nan";

  Print(Number);
  Print(Nan);

  ArrayPrint(_R(Nan).Bytes); // Распечатали байты

  ulong Num = 0;

  _W(Num) = Nan; // Побайтово скопировали Nan в Num

  PrintFormat("%I64X", Num);
}

Результат

1.23
nan
255 255 255 255 255 255 255 127
7FFFFFFFFFFFFFFF

Исходники обновили в публикации?