Вам не нужно знать направление массива. Поймите, что время скопированных в массив свечей поменялось местами - Эксперты Форекс, торговые роботы и советники

Andrey Koldorkin 2016.05.12 19:21 #5771

Artyom Trishkin:

dataCandles - это структура. Массив, куда мы пишем сами свечи из истории - array[]. Вот его и нужно сделать как таймсерию чтобы его индексация совпадала с индексацией свечей на графике. Т.е., Нулевая ячейка массива array[] соответствовала бы ближайшим свечам к текущей дате.

Т.е., 1. копируем в массив array[] свечи, 2. делаем его таймсерией, потом считываем с него значения в структуру.

Можно было бы обойтись и без массива array[] - сразу писать данные прямо с графика в структуру, но я так предложил для совместимости с пятёркой - в ней можно так копировать напрямую только в индикаторе, используя high[i], low[i] и прочие данные, но в скрипте, или советнике, нам всё равно придётся сначала скопировать нужный отрезок истории в массив, что я сразу и сделал.

bool series=ArrayIsSeries(array);

Alert (series);

ArraySetAsSeries (array, true);

bool series=ArrayIsSeries(array);

Alert (series);

вот так?

все равно оба алерта выдают false

Artyom Trishkin 2016.05.12 19:46 #5772

Andrey Koldorkin:

bool series=ArrayIsSeries(array);

Alert (series);

ArraySetAsSeries (array, true);

bool series=ArrayIsSeries(array);

Alert (series);

вот так?

все равно оба алерта выдают false

Значит это баг, о котором следует сообщить в "Ошибки, баги, вопросы".

Вот проверочный скрипт, он показывает время скопированных свечей в нулевой и последней ячейках массива array[]:

//+------------------------------------------------------------------+
//|                                                     TestCopy.mq4 |
//|              Copyright 2016, Artem A. Trishkin, Skype artmedia70 |
//|                       https://login.mql5.com/ru/users/artmedia70 |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, Artem A. Trishkin, Skype artmedia70"
#property link      "https://login.mql5.com/ru/users/artmedia70"
#property version   "1.00"
#property strict
#property script_show_inputs

enum enumYN
  {
   enYes=1, // Да
   enNo=0,  // Нет
  };

//--- input parameters
input int Search_Period=10;   // Количество копируемых свечей
int searchPeriod=(Search_Period<1)?1:Search_Period;
input int Delta=2;            // Количество пунктов допуска
int delta=(Delta<0)?0:Delta;
input enumYN AsSeries=enYes;  // Массив array как таймсерия
MqlRates array[];             // Массив структур для копирования Open, High, Low, Close, Time
  
struct DataCandle             // Структура для хранения всех совпадений
  {
   int number_matched;           // Количество совпадений
   MqlRates reference_candle;    // Данные эталонной свечи
   MqlRates matched_candles[];   // Массив свечей, совпадающих с эталонной по нужному критерию 
  };
  DataCandle dataCandle[];    // Массив структур данных свечей и их совпадений
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//---
   int copy_bars=(int)fmin(Search_Period,Bars(Symbol(),Period()));   // количество копируемых свечей
   int copied=CopyRates(Symbol(),PERIOD_CURRENT,1,copy_bars,array);  // копируем данные
   if(copied>0) {                                                    // если скопировали
      ArraySetAsSeries(array,AsSeries);                              // задаём массив как таймсерию или нет
      ArrayResize(dataCandle,copied);                                // задаём размер структуры равным числу скопированных данных
      ZeroMemory(dataCandle);                                        // Обнуляем данные в структуре
      //--- основной цикл по "эталонным" свечам в массиве array. Их параметры будем искать в доп. цикле
      for(int i=0; i<copy_bars-1; i++) {                             // цикл по скопированным данным от начала до "на один меньше размера массива"
         dataCandle[i].reference_candle.high=array[i].high;          // ищем этот high
         dataCandle[i].reference_candle.low=array[i].low;            // запомнили low для сравнения
         dataCandle[i].reference_candle.time=array[i].time;          // запомнили time для вывода в журнал
         //--- поиск совпадений с эталонной свечой, индексируемой индексом основного цикла i
         int size=0;                                                 // размер массива совпадающих свечей
         ArrayResize(dataCandle[i].matched_candles,size);            // Размер массива совпадений в ноль
         dataCandle[i].number_matched=size;                          // Инициализируем количество совпадений нулём
         //--- теперь ищем совпадения по high свечей в цикле j с high эталонной свечи с индексом i
         for(int j=0; j<copy_bars; j++) {                            // в цикле от i+1 до copy_bars
            if(j==i) continue;                                       // пропустим свечу "саму себя"
            //--- если совпадают high эталонной свечи (i) и свечи с индексом j (с допуском на величину Point)
            if(NormalizeDouble(delta*Point()-fabs(array[i].high-array[j].high),Digits())>=0) {
               size++;                                               
               ArrayResize(dataCandle[i].matched_candles,size);            // увеличим размер массива совпадающих свечей
               dataCandle[i].number_matched=size;                          // запишем количество совпадений
               dataCandle[i].matched_candles[size-1].high=array[j].high;   // запишем в массив high совпадающей свечи
               dataCandle[i].matched_candles[size-1].low=array[j].low;     // запишем в массив low совпадающей свечи
               dataCandle[i].matched_candles[size-1].time=array[j].time;   // запишем в массив время совпадающей свечи
               //Print("Время свечи ",i," :",TimeToString(dataCandle[i].reference_candle.time=array[i].time),", high=",DoubleToString(dataCandle[i].reference_candle.high=array[i].high,Digits()),". Совпадение со свечой ",TimeToString(dataCandle[i].matched_candles[size-1].time=array[j].time),", её high ",DoubleToString(dataCandle[i].matched_candles[size-1].high=array[j].high,Digits()),". Совпадений: ",(string)dataCandle[i].number_matched);
               }
            }
         }
      }

   //--- Посмотрим чего понаписали в массивы
   Alert("Array is series: ",ArrayIsSeries(array),
         "\ntime array[0]: ",TimeToString(array[0].time,TIME_DATE|TIME_MINUTES),
         "\ntime array[",string(searchPeriod-1),"]: ",TimeToString(array[ArraySize(array)-1].time,TIME_DATE|TIME_MINUTES));
   for(int i=0; i<ArraySize(dataCandle)-1; i++) {
      string refs_txt="";
      string matched_txt="";
      refs_txt="Свеча "+IntegerToString(i,2,'0')+": время "+TimeToString(dataCandle[i].reference_candle.time)+", high: "+DoubleToString(dataCandle[i].reference_candle.high,Digits())+" имеет совпадений: "+(string)dataCandle[i].number_matched+" шт. ";
      if(dataCandle[i].number_matched>0) {
         for(int j=0; j<ArraySize(dataCandle[i].matched_candles); j++) {
            matched_txt="Совпадение "+IntegerToString(j+1)+": "+TimeToString(dataCandle[i].matched_candles[j].time)+", high: "+DoubleToString(dataCandle[i].matched_candles[j].high,Digits());
            }
         }
      Print(refs_txt,matched_txt);
      }
  }
//+------------------------------------------------------------------+

Andrey Koldorkin 2016.05.12 19:52 #5773

Artyom Trishkin:

Значит это баг, о котором следует сообщить в "Ошибки, баги, вопросы".

Вот проверочный скрипт, он показывает время скопированных свечей в нулевой и последней ячейках массива array[]:

Выдает вот это:

Array is series: false

time array[0]: 2016.05.12 21:00

time array[9]: 2016.05.12 12:00

Artyom Trishkin 2016.05.12 19:58 #5774

Andrey Koldorkin:

Выдает вот это:

Array is series: false

time array[0]: 2016.05.12 21:00

time array[9]: 2016.05.12 12:00

Я проверял что выдаёт - всегда false, но время-то пишет верно: если при запуске скрипта выбрать Массив array как таймсерия "Да", то:

Array is series: false
time array[0]: 2016.05.12 21:00
time array[9]: 2016.05.12 12:00

Если же выбрать "Нет", то:

Array is series: false
time array[0]: 2016.05.12 12:00
time array[9]: 2016.05.12 21:00

время записанных в массив свечей поменялось местами, а значит ArraySetAsSeriess() работает верно, а вот ArrayIsSeries() - нет, всегда выдаёт false, о чём я уже отписался в вышеназванную ветку с багами.

Разница между ArrayIsSeries и Как правильно выяснить, что File Mapping, как сделать

Vasiliy Sokolov 2016.05.12 20:08 #5775

Andrey Koldorkin:

Ох уж это программирование. Чем дальше в лес....

Поймите, Вам не нужно знать направление массива. Алгоритм ищет повторы. Поэтому все равно в какой последовательности будут обработаны бары.

Andrey Koldorkin 2016.05.12 20:23 #5776

Vasiliy Sokolov:
Поймите, Вам не нужно знать направление массива. Алгоритм ищет повторы. Поэтому все равно в какой последовательности будут обработаны бары.

нужно. Ведь мне потом нужно узнать какие именно свечи образовали совпадение и с самой ближайшей к текущей цене взять цену Low.

Artyom Trishkin 2016.05.12 20:32 #5777

Andrey Koldorkin:
нужно. Ведь мне потом нужно узнать какие именно свечи образовали совпадение и с самой ближайшей к текущей цене взять цену Low.

Для этого в структуре есть время свечи, по которому можно найти ближайшую свечу к любому нужному вам времени.

А номера свечей вам не нужно выводить - они не совпадают с реальными номерами баров. Ведь мы заполняем массив, и индексы в массиве принадлежат лишь номеру свечи в массиве, а не на графике.

Любые вопросы новичков по Помогите вставить функцию!!! Вопрос программистам.

Andrey Koldorkin 2016.05.12 20:33 #5778

Artyom Trishkin:

Я проверял что выдаёт - всегда false, но время-то пишет верно: если при запуске скрипта выбрать Массив array как таймсерия "Да", то:

Если же выбрать "Нет", то:

время записанных в массив свечей поменялось местами, а значит ArraySetAsSeriess() работает верно, а вот ArrayIsSeries() - нет, всегда выдаёт false, о чём я уже отписался в вышеназванную ветку с багами.

Я чуть изменил код:

ArraySetAsSeries(array,true); //тут просто true поставил

и дальше добавил чтобы писал номера свечек для самопроверки:

Alert("Array is series: ",ArrayIsSeries(array),

"\nСвеча "+IntegerToString(0,2,'0')+" time array[0]: ",TimeToString(array[0].time,TIME_DATE|TIME_MINUTES),

"\nСвеча "+IntegerToString(searchperiod-1,2,'0')+" time array[",string(searchperiod-1),"]: ",TimeToString(array[ArraySize(array)-1].time,TIME_DATE|TIME_MINUTES));

Выдает следующее:

Array is series: false

Свеча 00 time array[0]: 2016.05.12 22:00

Свеча 09 time array[9]: 2016.05.12 13:00

Помощь в кодировании Индикатор Разные вопросы "Old tick" при тестировании

Andrey Koldorkin 2016.05.12 20:34 #5779

Artyom Trishkin:
Для этого в структуре есть время свечи, по которому можно найти ближайшую свечу к любому нужному вам времени.

ну все равно. получается, что направление меняется одной строкой кода. это не усложнит процесс. Зато пока я только пытаюсь понять как что происходит, у меня хотя бы свечки в голове и машине будут в одном и том же порядке ))

Вопрос по массиву Парный трейдинг и мультивалютный Нужна ли независимая проверка

Artyom Trishkin 2016.05.12 20:37 #5780

Andrey Koldorkin:

Я чуть изменил код:

ArraySetAsSeries(array,true); //тут просто true поставил

и дальше добавил чтобы писал номера свечек для самопроверки:

Alert("Array is series: ",ArrayIsSeries(array),

"\nСвеча "+IntegerToString(0,2,'0')+" time array[0]: ",TimeToString(array[0].time,TIME_DATE|TIME_MINUTES),

"\nСвеча "+IntegerToString(searchperiod-1,2,'0')+" time array[",string(searchperiod-1),"]: ",TimeToString(array[ArraySize(array)-1].time,TIME_DATE|TIME_MINUTES));

Выдает следующее:

Array is series: false

Свеча 00 time array[0]: 2016.05.12 22:00

Свеча 09 time array[9]: 2016.05.12 13:00

Вы mql4 используете? Если да, то номер свечи узнавайте по её времени, которое записано в структуре. iBarShift() вам в помощь.

Вопросы от начинающих MQL5 MT5 MetaTrader 5 - страница 578