Для больших проектов нужно сравнивать простые функции - MQL4 и MetaTrader 4

Rashid Umarov 2008.02.19 13:36 #31

Поскольку мы говорим о скорости вычисления, а не о разнице в работе алгоритмов, то сравнивать нужно простые функции. Приложенные индикаторы являются все-таки индикаторами, о правльности расчетов которых тут идет спор. Нужно взять простую функцию и реализовать ее двумя способами - как пользовательский индикатор и как вызываемую в коде функцию. Подобную проверку я уже делал и писал о ней -О скорости вычисления индикаторов в MQL4

Вот индикатор test.mq4

//+------------------------------------------------------------------+
//|                                                         Test.mq4 |
//|                      Copyright © 2007, MetaQuotes Software Corp. |
//|                                        http://www.metaquotes.net/ru/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2007, MetaQuotes Software Corp."
#property link      "http://www.metaquotes.net/ru/"
 
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_color1 Red
 
extern int val=5;
//---- buffers
double ExtMapBuffer1[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
//---- indicators
   SetIndexStyle(0,DRAW_LINE);
   SetIndexBuffer(0,ExtMapBuffer1);
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
//----
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
   int    counted_bars=IndicatorCounted();
//----
   int    res_int=0,i;
   double res_double=0;
//----
   for(i=0;i<=10000000;i++)
     {
      res_int+=i*i;
      res_int++;
      res_double+=i*i;
      res_double++;
     }
   ExtMapBuffer1[0]=res_double;      
//----
   return(0);
  }
//+------------------------------------------------------------------+

и вот скрипт, который замеряет скорость вычисления тестового алгоритма

//+------------------------------------------------------------------+
//|                                             CheckCustomSpeed.mq4 |
//|                      Copyright © 2007, MetaQuotes Software Corp. |
//|                                        https://www.metaquotes.net/ru/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2007, MetaQuotes Software Corp."
#property link      "https://www.metaquotes.net/ru/"
 
#property show_inputs
 
 
//+------------------------------------------------------------------+
//|  implemented Test functiom                                       |
//+------------------------------------------------------------------+
double test()
   {
   int    res_int=0,i;
   double res_double=0;
//----
   for(i=0;i<=10000000;i++)
     {
      res_int+=i*i;
      res_int++;
      res_double+=i*i;
      res_double++;
     }
   return(res_double);
   }
 
//+------------------------------------------------------------------+
//| script program start function                                    |
//+------------------------------------------------------------------+
int start()
  {
  double Impl=test();
  double Custom=iCustom(NULL,0,"Test",5,0,0);
//----
   Print("Implemented retuns ",Impl,",   iCustom returns ",Custom,", diiff=",Impl-Custom);
   
//----
   int i,start,stop;
   //Measuring time for test function
   start=GetTickCount();
   for (i=0;i<100;i++) test();
   stop=GetTickCount();
   int testTime=(stop-start)/1000.0;
 
   //Measuring time for Custom function
   start=GetTickCount();
   for (i=0;i<100;i++) Custom=iCustom(NULL,0,"Test",i,0,0);
   stop=GetTickCount();
   int customTime=(stop-start)/1000.0;
   string text=StringConcatenate("Time for implemented function test() is ",testTime,"  seconds");
   text=StringConcatenate(text,"\n Time for custom function iCustom(\"test\") is ",customTime,"  seconds");
   Comment(text);
 
//----
   return(0);
  }
//+------------------------------------------------------------------+

через iCustom() и через вызов test().

В одном индикаторе появилась Функция ICustom Элитные показатели :)

Candid 2008.02.19 13:46 #32

Я вижу в примерах две разницы: test вызывается как функция(а не вставлен прямо в код) и содержание test беднее (нет работы с массивами). То есть ответ на вопрос о целесообразности применения iCustom продолжает выглядеть зависящим от конкретной ситуации.
P.S. В моём примере не такая уж существенная разница в числе операций для двух вариантов - "обслуживающий код" ведь работает один раз, а циклы одни и те же.

Вопросы от начинающих MQL4 Любые вопросы новичков по Как избежать дублирования кода?

Rashid Umarov 2008.02.19 13:54 #33

1. Процедурный стиль программирования уступает по эффективности только модульному и объектно-ориентированному. Так что вынос алгоритма вычислений в отдельную фуекцию является закономерным.

2. А зачем работать с массивами во встроенной функции? Мы же ведем речь о разнице в стоимости вызова встроенной в код пользовательской функции и о вызове внешней функции через iCustom().

Как удалить элемент из Вопрос знатокам ООП. Чего не хватает для

Candid 2008.02.19 14:14 #34

Rosh:
1. Процедурный стиль программирования уступает по эффективности только модульному и объектно-ориентированному. Так что вынос алгоритма вычислений в отдельную фуекцию является закономерным.

2. А зачем работать с массивами во встроенной функции? Мы же ведем речь о разнице в стоимости вызова встроенной в код пользовательской функции и о вызове внешней функции через iCustom().

1. Это именно итоговая эффективность, для больших проектов. По скорости как раз уступает.
2. Аналогично. Меня-то интересует именно итоговая эффективность. В случае MQL это обычно время на разработку плюс время на испытание в тестере. Хотя лишние секунды ожидания при загрузке терминала с реальным счётом тоже могут дорогого стоить. В смысле нервов, не у всех же правильные взгляды на торговлю :)

Даже обезьяна способна выиграть Может ли в МТ4 Случайное блуждание :

Rashid Umarov 2008.02.19 16:15 #35

Вот скрипт для проверки разницы.

//+------------------------------------------------------------------+
//|                                        CheckCalculationSpeed.mq4 |
//|                      Copyright © 2007, MetaQuotes Software Corp. |
//|                                        http://www.metaquotes.net/ru/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2007, MetaQuotes Software Corp."
#property link      "http://www.metaquotes.net/ru/"
 
#property show_inputs
 
 
//+------------------------------------------------------------------+
//|  implemented Test functiom                                       |
//+------------------------------------------------------------------+
double test()
   {
   int    res_int=0,i;
   double res_double=0;
//----
   for(i=0;i<=10000000;i++)
     {
      res_int+=i*i;
      res_int++;
      res_double+=i*i;
      res_double++;
     }
   return(res_double);
   }
 
//+------------------------------------------------------------------+
//| script program start function                                    |
//+------------------------------------------------------------------+
int start()
  {
  double Impl=test();
  double Custom=iCustom(NULL,0,"Test",5,0,0);
//----
   Print("Implemented retuns ",Impl,",   iCustom returns ",Custom,", diiff=",Impl-Custom);
   
//----
   int i,start,stop;
   //Measuring time for test function
   start=GetTickCount();
   for (i=0;i<100;i++) test();
   stop=GetTickCount();
   int testTime=(stop-start)/1000.0;
 
   //Measuring time for direct calculation
   int    res_int=0,j;
   double res_double=0;
 
   start=GetTickCount();
   for (j=0;j<100;j++) 
      {
      for(i=0;i<=10000000;i++)
        {
         res_int+=i*i;
         res_int++;
         res_double+=i*i;
         res_double++;
        }
     }     
   stop=GetTickCount();
   int customTime=(stop-start)/1000.0;
   string text=StringConcatenate("Time for implemented function test() is ",testTime,"  seconds");
   text=StringConcatenate(text,"\n Time for direct Calculation block  is ",customTime,"  seconds");
   Comment(text);
 
//----
   return(0);
  }
//+------------------------------------------------------------------+

А вот результаты работы скрипта.

Как видите, использование отдельной функции вполне оправдано - разница по времени для цикла в миллиард проходов всего одна секунда. Зато насколько проще разрабатывать код!

Rashid Umarov 2008.02.22 09:14 #36

Вот еще на тему нахождения параметров линейной регрессии. Взято отсюда - Linear Regression Channel

Voltaire 2008.02.29 14:03 #37

Rosh:
Вот еще на тему нахождения параметров линейной регрессии. Взято отсюда - Linear Regression Channel

А вот функция, которая реализует описанный алгоритм (может кому пригодится):

void fLinearRegr(int nX[], double dY[], int nN, double& dA, double& dB)
{ //*************************************************************************
  //  Аппроксимация до прямой:
  //
  //  dY[nI] = dA + dB * nX[nI] - общая формула прямой
  //  
  //  dB = (nN*dSumXY - dSumX*dSumY) / (nN*dSumX2 - dSumX*dSumX)
  //
  //  dA = (dSumY - dB*dSumX) / nN
  //
  //  dSumXY = nX[0]*dY[0] + nX[1]*dY[1] + ... + nX[nN-1]*dY[nN-1]
  //
  //  dSumX  = nX[0] + nX[1] + ... + nX[nN-1]
  //  
  //  dSumY  = dY[0] + dY[1] + ... + dY[nN-1]  
  //  
  //  dSumX2 = nX[0]*nX[0] + nX[1]*nX[1] + ... + nX[nN-1]*nX[nN-1]
  //    
  //  Функция  вычисляет  коэффициенты  аппроксимирующей прямой.     
  //  
  //  Входные параметры:
  //      nX  -   массив  целых чисел с нумерацией элементов от 0 до N-1.
  //              Содержит набор абсцисс, в которых известны значения функции.
  //      dY   -  массив  вещественных  чисел с нумерацией элементов от 0 до N-1.
  //              Содержит набор значений функции.
  //      nN   -  число точек. N>=1
  //                                  
  //  Выходные параметры:
  //      dA, dB - коэффициенты аппроксимирующей прямой y=a+b*x
  //
  //  Реализация функции: Volt ( voltair@inbox.ru ) 
  //*************************************************************************/
  double dSumXY=0.0, dSumX=0.0, dSumY=0.0, dSumX2=0.0;
  for (int nI=0; nI<nN; nI++)
  { // вычисляем dSumXY
    dSumXY = dSumXY + nX[nI]*dY[nI];
    // вычисляем dSumX
    dSumX  = dSumX  + nX[nI];
    // вычисляем dSumY
    dSumY  = dSumY  + dY[nI];
    // вычисляем dSumX2
    dSumX2 = dSumX2 + nX[nI]*nX[nI];
  }
  // вычисляем dB
  dB = (nN*dSumXY - dSumX*dSumY) / (nN*dSumX2 - dSumX*dSumX);
  // вычисляем dA
  dA = (dSumY - dB*dSumX) / nN;
}

Функция вызывается примерно так:

  int nX[5];
  double dY[5];
  // . . .
  nX[0] = nBar;
  dY[0] = High[nBar]; 
  // . . .
  nX[4] = nBar+4;
  dY[4] = High[nBar+4]; 
  // . . .
  fLinearRegr(nX, dY, 5, dA, dB);

Учтите, что если nX[nI] это номера баров, то инкремент nI ведет в прошлое! :)

Regards,

Volt

Prival 2008.07.23 13:56 #38

Что то не то в Датском королевстве.

Предыдущий свой пост пришлось удалить. В алгоритме есть ошибка.

Я знаю что многие используют эту процедуру но ….не могу найти причину ошибки ПОМОГИТЕ.

Вот скрипт. Дважды вычисляться коэффициенты А и B.

//+------------------------------------------------------------------+
//|                                                       LinReg.mq4 |
//|                                                    Привалов С.В. |
//|                                             Skype -> privalov-sv |
//+------------------------------------------------------------------+
#property copyright "Привалов С.В."
#property link      "Skype -> privalov-sv"

//+------------------------------------------------------------------+
//| script program start function                                    |
//+------------------------------------------------------------------+
int start()
  {
//----
   int      N=6;                 // Размер массива
   double   Y[],X[],A=0,B=0;
   
  ArrayResize(X,N);
  ArrayResize(Y,N);
      
    for ( int i = 0; i < N; i ++ )
    {
    // массивы Y и X для проверки работоспособности
    // intercept = -3.33333333 slope = 5.00000000

    X[i]=i;
    Y[i]=i*i;
    }
  LinearRegr(X, Y, N, A, B);
  
  Print("intercept = ", DoubleToStr(A,8)," slope = ",DoubleToStr(B,8));
// вторая проверка
    X[0]=1216640160;
    X[1]=1216640100;
    X[2]=1216640040;
    X[3]=1216639980;
    X[4]=1216639920;
    X[5]=1216639860;
    
    Y[0]=1.9971;
    Y[1]=1.9970;    
    Y[2]=1.9967;
    Y[3]=1.9969;    
    Y[4]=1.9968;    
    Y[5]=1.9968;
    
    A=0;
    B=0;
    
  LinearRegr(X, Y, N, A, B);
  
  Print("intercept = ", DoubleToStr(A,8)," slope = ",DoubleToStr(B,8));
           
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| y(x)=A+B*x                                                       |
//| используються формулы https://forum.mql4.com/ru/10780/page4&nbsp;      |
//+------------------------------------------------------------------+

void LinearRegr(double X[], double Y[], int N, double& A, double& B)
{
      double sumY = 0.0, sumX = 0.0, sumXY = 0.0, sumX2 = 0.0;
      
    for ( int i = 0; i < N; i ++ )
    {
        sumY   +=Y[i];
        sumXY  +=X[i]*Y[i];
        sumX   +=X[i];
        sumX2  +=X[i]*X[i];
    }
   B=(sumXY*N-sumX*sumY)/(sumX2*N-sumX*sumX);
   A=(sumY-sumX*B)/N;
}

Вот результат

intercept = -3.33333333 slope = 5.00000000

intercept = -1102.16914108 slope = 0.00000091

А вот тоже, но рассчитанное в MathCad. Синим - результаты совпадают, красным нет (.

В маткаде это встроенные функции, так что скорее всего ошибка в МТ4, но вот где ?

Файлы:

scripts.rar 15 kb

Матстат Эконометрика Матан Не работает MarketInfo в Биткоин и все с

Rashid Umarov 2008.07.23 14:16 #39

Prival писал (а) >>

Что то не то в Датском королевстве.

Предыдущий свой пост пришлось удалить. В алгоритме есть ошибка.

Я знаю что многие используют эту процедуру но ….не могу найти причину ошибки ПОМОГИТЕ.

Вот скрипт. Дважды вычисляться коэффициенты А и B.

Вот результат

intercept = -3.33333333 slope = 5.00000000

intercept = -1102.16914108 slope = 0.00000091

А вот тоже, но рассчитанное в MathCad. Синим - результаты совпадают, красным нет (.

В маткаде это встроенные функции, так что скорее всего ошибка в МТ4, но вот где ?

А вот что выдает Excel 2007

Так что, проверять, возможно, нужно Маткад.

Evgeniy Gutorov 2008.07.23 14:33 #40

Одна из реализаций линейной регресии степень полинома 20, задается кол-во точек расчета и смещение начальной точки..

вывод осуществляется с использованием канала глубина задается в пунктах..при глубине 0 выводиться лишь сама кривая регресии

Файлы:

geregresion_nl.mq4 7 kb

Как обозначить операцию вычисления В чем отличия (если торговая стратегия на базе

Помогите написать линейную регрессию - страница 4