「KimIVの便利な機能」のみ。

Iurii Tokman 2011.02.18 08:09 #21

GetIndexByTicket()関数です。

この関数は、チケットによるオーダーまたはポジションのインデックスを返します。検索対象となるオーダーやポジションをより正確に選択するために、外部パラメータで指定します。

ti- チケットの順番、位置。このパラメータの値は、空またはゼロであってはならない。
sy- 市場商品の名前。このパラメータを設定すると、指定した楽器の位置のみを考慮するようになります。初期値「」は、あらゆる市場商品を意味する。NULLは 現在の楽器を意味します。
op-取引操作、注文、またはポジションの種類。有効な値：OP_BUY、OP_SELL、OP_BUYLIMIT、OP_SELLLIMIT、OP_BUYSTOP、OP_SELLSTOP、または-1 です。初期値の- 1は任意の位置を意味する。
mn- 位置の識別子，MagicNumber．デフォルトの値である- 1は、任意の識別子を意味する。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает индекс ордера или позиции по тикету.                |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    ti - тикет ордера, позиции                                              |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
int GetIndexByTicket(int ti, string sy="", int op=-1, int mn=-1) {
  int i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if ((mn<0 || OrderMagicNumber()==mn) && OrderTicket()==ti) return(i);
      }
    }
  }
  return(-1);
}

KimIVの便利な機能 [ARCHIVE!] フォーラムを散らかさないように、どんなルーキーの質問でも。プロフェッショナルは、通り過ぎないでください。あなたなしではどこにも行けない - 4. MQL4、MQL5に関する初心者からの質問、アルゴリズムやコードに関するヘルプ、ディスカッションなど。

Iurii Tokman 2011.02.18 08:10 #22

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 10.05.2008                                                     |
//|  Описание : Возвращает корреляцию двух рядов.                              |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    x - массив значений первого ряда                                        |
//|    y - массив значений второго ряда                                        |
//+----------------------------------------------------------------------------+
double Correlation(double& x[], double& y[]) {
  double co=0, sa=0, sb=0, sc=0, xs=0, ys=0;
  int    i, k=MathMin(ArraySize(x), ArraySize(y));

  if (k>0) {
    for (i=0; i<k; i++) {
      xs+=x[i]; ys+=y[i];
    }
    xs/=k; ys/=k;
    for (i=0; i<k; i++) {
      sa+=(x[i]-xs)*(y[i]-ys);
      sb+=(x[i]-xs)*(x[i]-xs);
      sc+=(y[i]-ys)*(y[i]-ys);
    }
    sb=MathSqrt(sb*sc);
    if (sb!=0) co=sa/sb;
  }
  return(co);
}

GetIndexLastPos()関数。

この関数は、最後のオープンポジションのインデックスまたは-1を 返します。チェックする位置をより正確に選択するために、外部パラメータで定義します。

sy- 市場商品の名前。このパラメータを設定すると、この関数は指定された楽器の位置だけを考慮するようになります。初期値「」は、あらゆる市場商品を意味する。NULLは 現在の楽器を意味します。
op-貿易業務、ポジションタイプ。有効な値：OP_BUY、OP_SELL、または-1。初期値-1 は任意の位置を意味する。
mn- 位置の識別子，MagicNumber．デフォルト値-1 は、任意の識別子を意味する。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает индекс последней открытой позиции или -1            |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
int GetIndexLastPos(string sy="", int op=-1, int mn=-1) {
  datetime o;
  int      i, k=OrdersTotal(), r=-1;

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (o<OrderOpenTime()) {
                o=OrderOpenTime();
                r=i;
              }
            }
          }
        }
      }
    }
  }
  return(r);
}

Iurii Tokman 2011.02.18 08:11 #23

GetLotLastPos()関数です。

この関数は、直近のオープンポジションのロットサイズまたは-1を 返します。チェックする位置をより正確に選択するために、外部パラメータで定義します。

sy- 市場商品の名前。このパラメータを設定すると、指定した楽器の位置のみを考慮するようになります。初期値「」は、あらゆる市場商品を意味する。NULLは 現在の楽器を意味します。
op-貿易業務、ポジションタイプ。有効な値：OP_BUY、OP_SELL、または-1。初期値-1 は任意の位置を意味する。
mn- 位置の識別子，MagicNumber．デフォルト値-1 は、任意の識別子を意味する。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает размер лота последней открытой позиции или -1       |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double GetLotLastPos(string sy="", int op=-1, int mn=-1) {
  datetime o;
  double   l=-1;
  int      i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (o<OrderOpenTime()) {
                o=OrderOpenTime();
                l=OrderLots();
              }
            }
          }
        }
      }
    }
  }
  return(l);
}

Iurii Tokman 2011.02.18 08:11 #24

GetMaxLotFromOpenPos()関数。

この関数は、オープンポジションの数から最大ロットサイズを返します。チェックする位置をより正確に選択するために、外部パラメータで指定します。

sy- 市場商品の名前。このパラメータを設定すると、指定されたシンボルの位置のみを考慮するようになります。初期値「」は、あらゆる市場商品を意味する。NULLは 現在の楽器を意味します。
op-貿易業務、ポジションタイプ。有効な値：OP_BUY、OP_SELL、または-1。初期値-1 は任意の位置を意味する。
mn- 位置の識別子，MagicNumber．デフォルト値-1 は、任意の識別子を意味する。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает максимальный размер лота из открытых позиций        |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double GetMaxLotFromOpenPos(string sy="", int op=-1, int mn=-1) {
  double l=0;
  int    i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (l<OrderLots()) l=OrderLots();
            }
          }
        }
      }
    }
  }
  return(l);
}

Iurii Tokman 2011.02.18 08:11 #25

GetMinLotFromOpenPos()関数。

この関数は、オープンポジションの数から最小ロットサイズを返します。チェックする位置をより正確に選択するために、外部パラメータで指定します。

sy- 市場商品の名前。このパラメータを設定すると、指定されたシンボルの位置のみを考慮するようになります。初期値「」は、あらゆる市場商品を意味する。NULLは 現在の楽器を意味します。
op-貿易業務、ポジションタイプ。有効な値：OP_BUY、OP_SELL、または-1。初期値-1 は任意の位置を意味する。
mn- 位置の識別子，MagicNumber．デフォルト値-1 は、任意の識別子を意味する。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает минимальный размер лота из открытых позиций         |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double GetMinLotFromOpenPos(string sy="", int op=-1, int mn=-1) {
  double l=0;
  int    i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (l==0 || l>OrderLots()) l=OrderLots();
            }
          }
        }
      }
    }
  }
  return(l);
}

Iurii Tokman 2011.02.18 08:12 #26

NumberOfPositions()関数です。

この関数は、現在オープンしているポジションの数を返します。より正確なカウント位置の選択は、外部パラメータで指定します。

sy- 市場商品の名前。このパラメータが設定されている場合、この関数は指定された楽器の位置のみを考慮します。初期値「」は、あらゆる市場商品を意味する。NULLは 現在の楽器を意味します。
op-貿易業務、ポジションタイプ。有効な値：OP_BUY、OP_SELL、または-1。初期値-1 は任意の位置を意味する。
mn- 位置の識別子，MagicNumber．デフォルト値-1 は、任意の識別子を意味する。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает количество позиций.                                 |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
int NumberOfPositions(string sy="", int op=-1, int mn=-1) {
  int i, k=OrdersTotal(), kp=0;

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) kp++;
          }
        }
      }
    }
  }
  return(kp);
}

Iurii Tokman 2011.02.18 08:12 #27

GetProfitFromDateInCurrency()関数を使用します。

この関数は、ある日付以降に決済されたポジションの通貨建ての利益の合計を返します。考慮すべき位置をより正確に選択するために、外部パラメータを使用して指定します。

sy- 市場商品の名前。このパラメータを指定すると、この関数はこの楽器の位置だけを考慮します。初期値「」は、あらゆる市場商品を意味する。NULLは 現在の楽器を意味します。
op-貿易業務、ポジションタイプ。有効な値：OP_BUY、OP_SELL、または-1。初期値-1 は任意の位置を意味する。
mn- 位置の識別子，MagicNumber．デフォルト値-1 は、任意の識別子を意味する。
dt- 1970年からの秒単位で表される日付と時刻．デフォルト値-0は、履歴で利用可能なすべてのポジションが考慮されることを意味します。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает суммарный профит в валюте депозита                  |
//|             закрытых с определённой даты позиций                           |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента             (""   - любой символ,         |
//|                                               NULL - текущий символ)       |
//|    op - операция                             (-1   - любая позиция)        |
//|    mn - MagicNumber                          (-1   - любой магик)          |
//|    dt - Дата и время в секундах с 1970 года  ( 0   - с начала истории)     |
//+----------------------------------------------------------------------------+
double GetProfitFromDateInCurrency(string sy="", int op=-1, int mn=-1, datetime dt=0)
{
  double p=0;
  int    i, k=OrdersHistoryTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_HISTORY)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (mn<0 || OrderMagicNumber()==mn) {
            if (dt<OrderCloseTime()) {
              p+=OrderProfit()+OrderCommission()+OrderSwap();
            }
          }
        }
      }
    }
  }
  return(p);
}

KimIVの便利な機能 [ARCHIVE!] フォーラムを散らかさないように、どんなルーキーの質問でも。プロフェッショナルは、通り過ぎないでください。あなたなしではどこにも行けない - 4. そして、それを「漫画」にしよう（多通貨化）

Iurii Tokman 2011.02.18 08:13 #28

GetProfitOpenPosInCurrency()関数を使用します。

この関数は、現在開いているポジションの総利益を返します。利益は預け入れ通貨単位で還元されます。考慮すべき位置をより正確に選択するために、外部パラメータを使用して指定します。

sy- 市場商品の名前。このパラメータを指定すると、この関数はこの楽器の位置だけを考慮します。初期値「」は、あらゆる市場商品を意味する。NULLは 現在の楽器を意味します。
op-貿易業務、ポジションタイプ。有効な値：OP_BUY、OP_SELL、または-1。初期値-1 は任意の位置を意味する。
mn- 位置の識別子，MagicNumber．デフォルト値-1 は、任意の識別子を意味する。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает суммарный профит открытых позиций в валюте депозита |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double GetProfitOpenPosInCurrency(string sy="", int op=-1, int mn=-1) {
  double p=0;
  int    i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (mn<0 || OrderMagicNumber()==mn) {
            p+=OrderProfit()+OrderCommission()+OrderSwap();
          }
        }
      }
    }
  }
  return(p);
}

Iurii Tokman 2011.02.18 08:14 #29

GetProfitOpenPosInPoint()関数を使用します。

この関数は、現在開いているポジションの総利益を返します。利益はポイントで還元されます。考慮すべき位置をより正確に選択するために、外部パラメータで指定します。

sy- 市場商品の名前。このパラメータを指定すると、この機能はこの楽器の位置のみを考慮します。初期値「」は、あらゆる市場商品を意味する。NULLは 現在の楽器を意味します。
op-貿易業務、ポジションタイプ。有効な値：OP_BUY、OP_SELL、または-1。初期値-1 は任意の位置を意味する。
mn- 位置の識別子，MagicNumber．デフォルト値-1 は、任意の識別子を意味する。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает суммарный профит открытых позиций в пунктах         |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
int GetProfitOpenPosInPoint(string sy="", int op=-1, int mn=-1) {
  double p;
  int    i, k=OrdersTotal(), pr=0;

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (mn<0 || OrderMagicNumber()==mn) {
          p=MarketInfo(OrderSymbol(), MODE_POINT);
          if (p==0) if (StringFind(OrderSymbol(), "JPY")<0) p=0.0001; else p=0.01;
          if (OrderType()==OP_BUY) {
            pr+=(MarketInfo(OrderSymbol(), MODE_BID)-OrderOpenPrice())/p;
          }
          if (OrderType()==OP_SELL) {
            pr+=(OrderOpenPrice()-MarketInfo(OrderSymbol(), MODE_ASK))/p;
          }
        }
      }
    }
  }
  return(pr);
}

Iurii Tokman 2011.02.18 08:14 #30

GetTicketLastPos()関数。

この関数は、最後のオープンポジションのチケットまたは-1を返します。考慮すべき位置をより正確に選択するために、外部パラメータで指定します。

sy- 市場商品の名前。このパラメータを指定すると、この機能はこの楽器の位置のみを考慮します。初期値「」は、あらゆる市場商品を意味する。NULLは 現在の楽器を意味します。
op-貿易業務、ポジションタイプ。有効な値：OP_BUY、OP_SELL、または-1。初期値-1 は任意の位置を意味する。
mn- 位置の識別子，MagicNumber．デフォルト値-1 は、任意の識別子を意味する。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает тикет последней открытой позиции или -1             |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
int GetTicketLastPos(string sy="", int op=-1, int mn=-1) {
  datetime o;
  int      i, k=OrdersTotal(), r=-1;

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (o<OrderOpenTime()) {
                o=OrderOpenTime();
                r=OrderTicket();
              }
            }
          }
        }
      }
    }
  }
  return(r);
}

「KimIVの便利な機能」のみ。 - ページ 3