Domande dai principianti MQL5 MT5 MetaTrader 5 - pagina 1225

[[Eliminato]]

Vitaly Muzichenko:

Per tutti. Più precisamente, visualizza nella finestra del grafico il numero di barre specificato nell'impostazione, e non dipende dal timeframe

P.S. Non ho mai cambiato questo valore, ma l'ho appena controllato e ho visto che non può essere impostato meno di 1000.

Quindi devi controllare coniBars()?

[SEM]

Buon pomeriggio. Lo script non funziona per qualche motivo.

Qual è il problema?

//+------------------------------------------------------------------+
//|                                                         test.mq5 |
//|                        Copyright 2020, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2020, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   
   if(!ChartSetInteger(0,CHART_IS_MAXIMIZED,true))
     {
      //--- выведем сообщение об ошибке в журнал "Эксперты"
      Print(__FUNCTION__+", Error Code = ",GetLastError());
      //return(false);
     };


  }
//+------------------------------------------------------------------+

[Vladimir Karputov]

I commenti non relativi a questo argomento sono stati spostati in "Domande dai principianti di MQL4 MT4 MetaTrader 4".

[Vladimir Voronin]

Ciao amici!

Domande:

1. Gli ordini Sell Stop Limit sono piazzati sul lato del broker o sul lato del terminale?

2. Quando chiudo il programma, l'ordine scatta quando le condizioni sono soddisfatte?

Trading sul mercato azionario MICEX. Grazie in anticipo!

[Alexey Belyakov]

Buon pomeriggio, cari programmatori. Domanda su MQL5

Come implementare il controllo della posizione in MetaTrader 5? Voglio avere solo una posizione aperta su una barra, cioè la posizione dovrebbe essere chiusa non importa dove - su quale barra, ma l'apertura dovrebbe essere solo su una barra.

Questo codice è completamente ignorato, qual è l'errore?

if (OrderSelect(HistoryDealsTotal()-1))

{
datetime Cu=PositionsTotal();
int hd=iBarShift(Symbol(),_Period,Cu);
if (hd<=1)
{
return;
}
}

[Aleksey Vyazmikin]

Alexey Belyakov:

Buon pomeriggio, cari programmatori. Domanda su MQL5

Come implementare il controllo della posizione in MetaTrader 5? In modo che su una barra ci sia solo una posizione aperta. Significa che la posizione è chiusa non importa dove - su quale barra, ma l'apertura dovrebbe essere su una sola barra.

Il modo più semplice è quello di salvare il tempo di apertura della barra, su cui la posizione è aperta nella variabile globale e poi, quando si apre una nuova posizione, controllare il tempo di apertura della barra se il valore è superiore al valore salvato, quindi aprire una posizione.

[Vladimir Karputov]

Alexey Belyakov:

Buon pomeriggio, cari programmatori. Domanda su MQL5

Come implementare il controllo della posizione in MetaTrader 5? Voglio avere solo una posizione aperta su una barra, cioè la posizione dovrebbe essere chiusa non importa dove - su quale barra, ma l'apertura dovrebbe essere solo su una barra.

Questo codice è completamente ignorato, qual è l'errore?

Errore: avete confuso le mosche e le cotolette - avete confuso gli ORDINI REMOTI e le POSIZIONI.

Per evitare confusione, si prega di leggere il riferimento:Principi generali

Il modo semplice di cui sopra è quello di ricordare il tempo di apertura della barra corrente quando si apre una posizione. Poi, se volete aprire una nuova posizione, controllate il tempo salvato e il tempo aperto della barra corrente.

Memorizzare il tempo di apertura di una posizione è conveniente inOnTradeTransaction:

//+------------------------------------------------------------------+
//| TradeTransaction function                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- get transaction type as enumeration value
   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//--- if transaction is result of addition of the transaction in history
   if(type==TRADE_TRANSACTION_DEAL_ADD)
     {
      if(HistoryDealSelect(trans.deal))
         m_deal.Ticket(trans.deal);
      else
         return;
      if(m_deal.Symbol()==m_symbol.Name() && m_deal.Magic()==InpMagic)
        {
         if(m_deal.DealType()==DEAL_TYPE_BUY || m_deal.DealType()==DEAL_TYPE_SELL)
           {
            if(m_deal.Entry()==DEAL_ENTRY_IN || m_deal.Entry()==DEAL_ENTRY_INOUT)
               m_last_deal_in=iTime(m_symbol.Name(),InpTimeFrame,0);
            int size_need_position=ArraySize(SPosition);
            if(size_need_position>0)
              {
               for(int i=0; i<size_need_position; i++)
                 {
                  if(SPosition[i].waiting_transaction)
                     if(SPosition[i].waiting_order_ticket==m_deal.Order())
                       {
                        Print(__FUNCTION__," Transaction confirmed");
                        SPosition[i].transaction_confirmed=true;
                        break;
                       }
                 }
              }
           }
        }
     }
  }

e riconciliare il tempo in cui il segnale viene attivato:

//+------------------------------------------------------------------+
//| Search trading signals                                           |
//+------------------------------------------------------------------+
bool SearchTradingSignals(void)
  {
   if(m_prev_bars==m_last_deal_in) // on one bar - only one deal
      return(true);

Esempio tratto dal codiceOHLC Check 2

[Alexey Belyakov]

È un po' ingannevole.... in qualche modo. Nessun problema nella prima fase "ricorda il tempo di apertura del bar attuale"

Ecco fatto:

if (PositionsTotal()==1)  // Здесь проверяю, что открыта одна позиция
{
datetime Cu=iTime(NULL,_Period,0);        // Здесь в переменную - время открытия бара при открытой позиции

Ma qui " si controlla il tempo salvato e il tempo di apertura della barra corrente".

Ho fatto più o meno la stessa cosa, guarda qui:

if (PositionsTotal()==1)  // Здесь проверяю, что открыта одна позиция (или была открыта, неважно, любое торговое действие)
{
datetime Cu=iTime(NULL,_Period,0);        // Здесь в переменную - время открытия бара при открытой позиции
int hd=+iBarShift(Symbol(),_Period,Cu)+1;    // Здесь в переменную - бар на котором произошло открытие позиции 
if (hd>=1)                                //Здесь проверяем - если этих баров, больше чем один, то.......   
{
return; //....то зацикливанием программу, НО проблема только в return
}
}

Tutto quello che devo fare qui è fare unciclo come "return(-1)" Ma non posso assegnare un'espressione al ritorno a causa del vuoto, come posso aggirare questo? Come fare il loop ma non il ritorno?

[Alexey Belyakov]

datetime PR=iTime(NULL,_Period,0);  // проверяю время открытие бара
if (PositionsTotal()==1)  
{
datetime TK=iTime(NULL,_Period,0);  // время открытия бара при открытой позиции                        
if (PR==TK)                         // сравниваю
{
return(true);  // НЕ катит true - ошибка 
}
}

Neanche questo ha funzionato.

[Vladimir Karputov]

Alexey Belyakov:

È un po' ingannevole.... in qualche modo. Nessun problema nella prima fase "ricorda il tempo di apertura del bar attuale"

Ecco fatto:

Ma qui " si controlla il tempo salvato e il tempo di apertura della barra corrente".

Ho fatto più o meno la stessa cosa, guarda qui:

Tutto quello che devo fare qui è fare unciclo come "return(-1)" Ma non posso assegnare un'espressione al ritorno a causa del vuoto, come posso aggirare questo? Come fare il loop ma non il ritorno?

Il trattamento per i programmi di looping è tagliare le loro braccia intorno al collo. In modo da non doverlo rifare in futuro.

Ecco quello che ti serve - l'intero corpo del programma, devi solo formalizzare la ricezione del segnale:

//+------------------------------------------------------------------+
//|                              Example One position on one bar.mq5 |
//|                        Copyright 2020, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2020, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//---
#include <Trade\PositionInfo.mqh>
#include <Trade\Trade.mqh>
#include <Trade\SymbolInfo.mqh>
#include <Trade\DealInfo.mqh>
//---
CPositionInfo  m_position;                   // object of CPositionInfo class
CTrade         m_trade;                      // object of CTrade class
CSymbolInfo    m_symbol;                     // object of CSymbolInfo class
CDealInfo      m_deal;                       // object of CDealInfo class
//--- input parameters
input ulong    InpMagic             = 200;      // Magic number
//---
datetime m_prev_bars                = 0;        // "0" -> D'1970.01.01 00:00';
datetime m_last_deal_in             = 0;        // "0" -> D'1970.01.01 00:00';
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   if(!m_symbol.Name(Symbol())) // sets symbol name
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");
      return(INIT_FAILED);
     }
   RefreshRates();
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//--- we work only at the time of the birth of new bar
   datetime time_0=iTime(m_symbol.Name(),Period(),0);
   if(time_0==m_prev_bars)
      return;
   m_prev_bars=time_0;
   if(!RefreshRates())
     {
      m_prev_bars=0;
      return;
     }
//--- search for trading signals
   if(!SearchTradingSignals())
     {
      m_prev_bars=0;
      return;
     }
  }
//+------------------------------------------------------------------+
//| TradeTransaction function                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- get transaction type as enumeration value
   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//--- if transaction is result of addition of the transaction in history
   if(type==TRADE_TRANSACTION_DEAL_ADD)
     {
      if(HistoryDealSelect(trans.deal))
         m_deal.Ticket(trans.deal);
      else
         return;
      if(m_deal.Symbol()==m_symbol.Name() && m_deal.Magic()==InpMagic)
        {
         if(m_deal.DealType()==DEAL_TYPE_BUY || m_deal.DealType()==DEAL_TYPE_SELL)
           {
            if(m_deal.Entry()==DEAL_ENTRY_IN || m_deal.Entry()==DEAL_ENTRY_INOUT)
               m_last_deal_in=iTime(m_symbol.Name(),Period(),0);
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Search trading signals                                           |
//+------------------------------------------------------------------+
bool SearchTradingSignals(void)
  {
   if(m_prev_bars==m_last_deal_in) // on one bar - only one deal
      return(true);
//--- signal
//---
   return(false);
  }
//+------------------------------------------------------------------+
//| Refreshes the symbol quotes data                                 |
//+------------------------------------------------------------------+
bool RefreshRates()
  {
//--- refresh rates
   if(!m_symbol.RefreshRates())
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: ","RefreshRates error");
      return(false);
     }
//--- protection against the return value of "zero"
   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: ","Ask == 0.0 OR Bid == 0.0");
      return(false);
     }
//---
   return(true);
  }
//+------------------------------------------------------------------+

La variabile'm_prev_bars' memorizza il tempo aperto della barra corrente e la variabile'm_last_deal_in' memorizza il tempo aperto della barra in cui la posizione è stata aperta.

Queste due variabili sono confrontate nel blocco per ottenere i segnali'SearchTradingSignals'.